[gentoo-commits] repo/gentoo:master commit in: dev-db/qt5-sqlcipher/

["Ulrich Müller" <ulm@gentoo.org>]

commit:     9048832d9d744034063b1ff6538f39db8f565c41
Author:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 27 09:57:08 2022 +0000
Commit:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Sun Feb 27 10:00:27 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9048832d

dev-db/qt5-sqlcipher: Migrate to cmake.eclass

Closes: https://bugs.gentoo.org/834119
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>

 .../qt5-sqlcipher/qt5-sqlcipher-1.0.11-r1.ebuild   | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-db/qt5-sqlcipher/qt5-sqlcipher-1.0.11-r1.ebuild b/dev-db/qt5-sqlcipher/qt5-sqlcipher-1.0.11-r1.ebuild
new file mode 100644
index 000000000000..57ef6aa14443
--- /dev/null
+++ b/dev-db/qt5-sqlcipher/qt5-sqlcipher-1.0.11-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Qt SQL driver plugin for SQLCipher"
+HOMEPAGE="https://github.com/blizzard4591/qt5-sqlcipher"
+SRC_URI="https://github.com/blizzard4591/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1" # version 2.1 only
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND=">=dev-db/sqlcipher-3.4.1
+	>=dev-qt/qtcore-5.12.3:5=
+	>=dev-qt/qtsql-5.12.3:5=[sqlite] <dev-qt/qtsql-5.16:5=[sqlite]"
+DEPEND="${RDEPEND}"
+
+DOCS=(README.md)
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-1.0.10-install-path.patch
+	sed -i -e "s/@LIBDIR@/$(get_libdir)/" CMakeLists.txt || die
+
+	local v=$(best_version dev-qt/qtsql:5)
+	v=$(ver_cut 1-3 ${v#*/qtsql-})
+	[[ -n ${v} ]] || die "could not determine qtsql version"
+	if ! [[ -d qt-file-cache/${v} ]]; then
+		local vc
+		case $(ver_cut 1-2 ${v}) in
+			5.12) vc=5.12.5 ;;
+			5.13) vc=5.13.2 ;;
+			5.14) vc=5.14.2 ;;
+			5.15) vc=5.15.0 ;;
+			*) die "qtsql-${v} not supported" ;;
+		esac
+		elog "qtsql-${v} not in cache, using ${vc} instead"
+		cp -R qt-file-cache/${vc} qt-file-cache/${v} || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_test() {
+	cd "${BUILD_DIR}" || die
+	./qsqlcipher-test || die
+}