[gentoo-commits] repo/gentoo:master commit in: dev-python/oauth2client/

["Michał Górny" <mgorny@gentoo.org>]

commit:     311a4625c0cdce9239a6b7242ced8cd5647f6e67
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 24 08:47:18 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Feb 24 08:52:01 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=311a4625

dev-python/oauth2client: Bump to EAPI 8 / PEP517

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 .../oauth2client/oauth2client-4.1.3-r2.ebuild      | 52 ++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/dev-python/oauth2client/oauth2client-4.1.3-r2.ebuild b/dev-python/oauth2client/oauth2client-4.1.3-r2.ebuild
new file mode 100644
index 000000000000..29d0198dbeb8
--- /dev/null
+++ b/dev-python/oauth2client/oauth2client-4.1.3-r2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Library for accessing resources protected by OAuth 2.0"
+HOMEPAGE="https://github.com/googleapis/oauth2client"
+SRC_URI="https://github.com/googleapis/oauth2client/archive/v${PV/_p/-post}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/${P/_p/-post}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/httplib2-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.0.5[${PYTHON_USEDEP}]
+	>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+	>=dev-python/six-1.6.1[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+	!<=dev-python/google-api-python-client-1.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests nose
+
+PATCHES=(
+	"${FILESDIR}/oauth2client-4.1.3-py38.patch"
+)
+
+python_test() {
+	nosetests -v \
+		-e appengine \
+		-e django_util \
+		-e test_multiprocess_file_storage \
+		-e test_bad_positional || die "tests fail with ${EPYTHON}"
+	# appengine - requires appengine
+	# django_util - requires django
+	# test_multiprocess_file_storage - requires fasteners
+	# test_bad_positional - expects TypeError, gets ValueError
+}