[gentoo-commits] repo/gentoo:master commit in: media-video/wireplumber/

["Sam James" <sam@gentoo.org>]

commit:     1d6d41556a8fdca27b2702e7561caf1ced80f22c
Author:     Niklāvs Koļesņikovs <89q1r14hd <AT> relay <DOT> firefox <DOT> com>
AuthorDate: Tue Feb 22 19:06:16 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Feb 22 20:55:46 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1d6d4155

media-video/wireplumber: clean up 0.4.8-r1

WirePlumber 0.4.8 (no longer present in tree) and 0.4.8-r1 may under
some circumstances crash on non-x86/amd64 architectures e.g. arm64.

The fix for the issue is present in 0.4.8-r2, so all that Gentoo needs
to do is to clean up the known affected ebuild.

Bug: https://gitlab.freedesktop.org/pipewire/wireplumber/-/issues/206

Signed-off-by: Niklāvs Koļesņikovs <89q1r14hd <AT> relay.firefox.com>
Closes: https://github.com/gentoo/gentoo/pull/24320
Signed-off-by: Sam James <sam <AT> gentoo.org>

 .../wireplumber/wireplumber-0.4.8-r1.ebuild        | 120 ---------------------
 1 file changed, 120 deletions(-)

diff --git a/media-video/wireplumber/wireplumber-0.4.8-r1.ebuild b/media-video/wireplumber/wireplumber-0.4.8-r1.ebuild
deleted file mode 100644
index 6348d11b2485..000000000000
--- a/media-video/wireplumber/wireplumber-0.4.8-r1.ebuild
+++ /dev/null
@@ -1,120 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-{3,4} )
-
-inherit lua-single meson systemd
-
-if [[ ${PV} == 9999 ]]; then
-	EGIT_REPO_URI="https://gitlab.freedesktop.org/pipewire/${PN}.git"
-	EGIT_BRANCH="master"
-	inherit git-r3
-else
-	SRC_URI="https://gitlab.freedesktop.org/pipewire/${PN}/-/archive/${PV}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
-fi
-
-DESCRIPTION="Replacement for pipewire-media-session"
-HOMEPAGE="https://gitlab.freedesktop.org/pipewire/wireplumber"
-
-LICENSE="MIT"
-SLOT="0/0.4"
-IUSE="elogind system-service systemd test"
-
-REQUIRED_USE="
-	${LUA_REQUIRED_USE}
-	?? ( elogind systemd )
-	system-service? ( systemd )
-"
-
-RESTRICT="!test? ( test )"
-
-# introspection? ( dev-libs/gobject-introspection ) is valid but likely only used for doc building
-BDEPEND="
-	dev-libs/glib
-	dev-util/gdbus-codegen
-	dev-util/glib-utils
-"
-
-DEPEND="
-	${LUA_DEPS}
-	>=dev-libs/glib-2.62
-	>=media-video/pipewire-0.3.45:=
-	virtual/libc
-	elogind? ( sys-auth/elogind )
-	systemd? ( sys-apps/systemd )
-"
-
-# Any dev-lua/* deps get declared like this inside RDEPEND:
-#	$(lua_gen_cond_dep '
-#		dev-lua/<NAME>[${LUA_USEDEP}]
-#	')
-RDEPEND="${DEPEND}
-	system-service? (
-		acct-user/pipewire
-		acct-group/pipewire
-	)
-"
-
-DOCS=( {NEWS,README}.rst )
-
-PATCHES=(
-	"${FILESDIR}"/${P}-restore-stream-do-not-crash-if-config.properties-is-.patch
-)
-
-src_configure() {
-	local emesonargs=(
-		-Ddoc=disabled # Ebuild not wired up yet (Sphinx, Doxygen?)
-		-Dintrospection=disabled # Only used for Sphinx doc generation
-		-Dsystem-lua=true # We always unbundle everything we can
-		-Dsystem-lua-version=$(ver_cut 1-2 $(lua_get_version))
-		$(meson_feature elogind)
-		$(meson_feature systemd)
-		$(meson_use system-service systemd-system-service)
-		$(meson_use systemd systemd-user-service)
-		-Dsystemd-system-unit-dir=$(systemd_get_systemunitdir)
-		-Dsystemd-user-unit-dir=$(systemd_get_userunitdir)
-		$(meson_use test tests)
-	)
-
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-
-	# We copy the default config, so that Gentoo tools can pick up on any
-	# updates and /etc does not end up with stale overrides.
-	# If a reflinking CoW filesystem is used (e.g. Btrfs), then the files
-	# will not actually get stored twice until modified.
-	insinto /etc
-	doins -r ${ED}/usr/share/wireplumber
-}
-
-pkg_postinst() {
-	if systemd_is_booted ; then
-		ewarn "pipewire-media-session.service is no longer installed. You must switch"
-		ewarn "to wireplumber.service user unit before your next logout/reboot:"
-		ewarn "systemctl --user disable pipewire-media-session.service"
-		ewarn "systemctl --user --force enable wireplumber.service"
-	else
-		ewarn "Switch to WirePlumber will happen the next time gentoo-pipewire-launcher"
-		ewarn "is started (a replacement for directly calling pipewire binary)."
-		ewarn
-		ewarn "Please ensure that ${EROOT}/etc/pipewire/pipewire.conf either does not exist"
-		ewarn "or, if it does exist, that any reference to"
-		ewarn "${EROOT}/usr/bin/pipewire-media-session is commented out (begins with a #)."
-	fi
-	if use system-service; then
-		ewarn
-		ewarn "WARNING: you have enabled the system-service USE flag, which installs"
-		ewarn "the system-wide systemd units that enable WirePlumber to run as a system"
-		ewarn "service. This is more than likely NOT what you want. You are strongly"
-		ewarn "advised not to enable this mode and instead stick with systemd user"
-		ewarn "units. The default configuration files will likely not work out of"
-		ewarn "box, and you are on your own with configuration."
-		ewarn
-	fi
-}