[gentoo-commits] repo/gentoo:master commit in: dev-java/c3p0/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     04604b4ba7bc5de3f5945d5ef609a080eb991812
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Mon Dec 27 15:42:58 2021 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Tue Feb 22 07:51:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=04604b4b

dev-java/c3p0: Switch to log4j-12-api:2

Closes: https://bugs.gentoo.org/830920
Lift log4j dependency to slot 2, log4j-12-api

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/24106/commits/72935ffc87d006df9a124f01056655bdb66d9a4d
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-java/c3p0/c3p0-0.9.5.5-r1.ebuild | 57 ++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/dev-java/c3p0/c3p0-0.9.5.5-r1.ebuild b/dev-java/c3p0/c3p0-0.9.5.5-r1.ebuild
new file mode 100644
index 000000000000..daecaa205752
--- /dev/null
+++ b/dev-java/c3p0/c3p0-0.9.5.5-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Tests require an existing running SQL server and 'junit.jar.file' property
+JAVA_PKG_IUSE="doc examples source"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="JDBC drivers with JNDI-bindable DataSources"
+HOMEPAGE="https://www.mchange.com/projects/c3p0/"
+
+SRC_URI="mirror://sourceforge/${PN}/${P}.src.tgz"
+LICENSE="|| ( EPL-1.0 LGPL-2.1 )"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+CP_DEPEND="
+	dev-java/log4j-12-api:2
+	dev-java/mchange-commons:0
+"
+
+DEPEND="
+	>=virtual/jdk-1.8:*
+	${CP_DEPEND}
+"
+
+RDEPEND="
+	>=virtual/jre-1.8:*
+	${CP_DEPEND}
+"
+
+S="${WORKDIR}/${P}.src"
+
+JAVA_ANT_REWRITE_CLASSPATH="yes"
+
+src_prepare() {
+	java-pkg_clean
+	java-pkg-2_src_prepare
+	java-pkg_jar-from --into lib/ log4j-12-api-2
+	java-pkg_jar-from --into lib/ mchange-commons
+
+	# Test sources interfere with Javadoc generation on JDK 11
+	# Remove since the tests will never be run
+	rm -r src/java/com/mchange/v2/c3p0/test ||
+		die "Failed to remove unused test sources"
+}
+
+src_install() {
+	java-pkg_newjar "build/${P}.jar"
+	einstalldocs
+
+	use doc && java-pkg_dojavadoc build/apidocs
+	use examples && java-pkg_doexamples src/java/com/mchange/v2/c3p0/example
+	use source && java-pkg_dosrc src/java/com/mchange/v2
+}