[gentoo-commits] repo/proj/guru:dev commit in: net-misc/giara/

["Anna Vyalkova" <cyber+gentoo@sysrq.in>]

commit:     da2e517a33a7b367bf5fee366a78163d24c54b5d
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Sun Feb 20 19:00:07 2022 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Sun Feb 20 19:01:49 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=da2e517a

net-misc/giara: initial import

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 net-misc/giara/giara-9999.ebuild | 75 ++++++++++++++++++++++++++++++++++++++++
 net-misc/giara/metadata.xml      | 15 ++++++++
 2 files changed, 90 insertions(+)

diff --git a/net-misc/giara/giara-9999.ebuild b/net-misc/giara/giara-9999.ebuild
new file mode 100644
index 000000000..0604cd182
--- /dev/null
+++ b/net-misc/giara/giara-9999.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..10} )
+inherit gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="An app for Reddit"
+HOMEPAGE="https://giara.gabmus.org https://gitlab.gnome.org/World/giara"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/World/${PN}.git"
+else
+	SRC_URI="https://gitlab.gnome.org/World/${PN}/-/archive/${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/glib:2
+	dev-libs/gobject-introspection[${PYTHON_SINGLE_USEDEP}]
+	gui-libs/gtk:4[introspection(+)]
+	gui-libs/gtksourceview:5[introspection(+)]
+	gui-libs/libadwaita:1[introspection(+)]
+	$(python_gen_cond_dep '
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/mistune[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/praw[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/blueprint-compiler
+	sys-devel/gettext
+"
+
+src_prepare() {
+	default
+
+	# fix broken shebang
+	sed "s|py_installation.full_path()|'${PYTHON}'|" -i bin/meson.build || die
+}
+
+# skip AppStream test
+src_test() {
+:
+}
+
+src_install() {
+	meson_src_install
+	python_optimize
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}

diff --git a/net-misc/giara/metadata.xml b/net-misc/giara/metadata.xml
new file mode 100644
index 000000000..1bce80172
--- /dev/null
+++ b/net-misc/giara/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<name>Gabriele Musco</name>
+			<email>gabmus@disroot.org</email>
+		</maintainer>
+		<bugs-to>https://gitlab.gnome.org/World/giara/-/issues</bugs-to>
+	</upstream>
+</pkgmetadata>