[gentoo-commits] repo/gentoo:master commit in: app-cdr/xcdroast/

["Sam James" <sam@gentoo.org>]

commit:     0538aa8d2c1c0f6b4517b0294e2a414abee9645e
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 19 00:09:02 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Feb 19 00:10:15 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0538aa8d

app-cdr/xcdroast: misc QA fixes

- Fix pkg_* (gnome2 icons bits aren't exported/available in EAPI 8; use xdg.eclass)
- Drop unrecognised configure args
- Drop unnecessary phase definitions
- Fix dependencies
- Use do/newicon from desktop.eclass

Closes: https://bugs.gentoo.org/833636
Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-cdr/xcdroast/xcdroast-1.19-r1.ebuild | 38 ++++++++++++++++++++
 app-cdr/xcdroast/xcdroast-1.19.ebuild    | 61 --------------------------------
 2 files changed, 38 insertions(+), 61 deletions(-)

diff --git a/app-cdr/xcdroast/xcdroast-1.19-r1.ebuild b/app-cdr/xcdroast/xcdroast-1.19-r1.ebuild
new file mode 100644
index 000000000000..17994dcb4dfb
--- /dev/null
+++ b/app-cdr/xcdroast/xcdroast-1.19-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop xdg
+
+DESCRIPTION="Lightweight cdrtools front-end for CD and DVD writing"
+HOMEPAGE="http://www.xcdroast.org/"
+SRC_URI="mirror://sourceforge/xcdroast/${P/_/}.tar.gz"
+S="${WORKDIR}"/${P/_/}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="nls suid"
+
+RDEPEND=">=app-cdr/cdrtools-3.02_alpha09
+	media-libs/alsa-lib
+	>=x11-libs/gtk+-2:2"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	econf \
+		$(use_enable nls) \
+		$(use_enable suid user-host-mode)
+}
+
+src_install() {
+	default
+
+	dodoc -r AUTHORS ChangeLog README doc/*
+
+	newicon -s 48 xpms/ico_cdwriter.xpm xcdroast.xpm
+	make_desktop_entry xcdroast "X-CD-Roast" xcdroast "AudioVideo;DiscBurning"
+}

diff --git a/app-cdr/xcdroast/xcdroast-1.19.ebuild b/app-cdr/xcdroast/xcdroast-1.19.ebuild
deleted file mode 100644
index 9db140ff8536..000000000000
--- a/app-cdr/xcdroast/xcdroast-1.19.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-inherit desktop gnome2-utils
-
-DESCRIPTION="Lightweight cdrtools front-end for CD and DVD writing"
-HOMEPAGE="http://www.xcdroast.org/"
-SRC_URI="mirror://sourceforge/xcdroast/${P/_/}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~sparc ~x86"
-IUSE="nls suid"
-
-RDEPEND=">=x11-libs/gtk+-2:2
-	>=app-cdr/cdrtools-3.02_alpha09"
-DEPEND="${RDEPEND}
-	sys-devel/gettext
-	virtual/pkgconfig"
-
-S=${WORKDIR}/${P/_/}
-
-src_prepare() {
-	default
-}
-
-src_configure() {
-	econf \
-		$(use_enable nls) \
-		$(use_enable suid nonrootmode) \
-		--enable-gtk2 \
-		--mandir=/usr/share/man \
-		--sysconfdir=/etc
-}
-
-src_compile() {
-	emake PREFIX=/usr
-}
-
-src_install() {
-	emake PREFIX=/usr DESTDIR="${D}" install
-	dodoc -r AUTHORS ChangeLog README doc/*
-
-	insinto /usr/share/icons/hicolor/48x48/apps
-	newins xpms/ico_cdwriter.xpm xcdroast.xpm
-
-	make_desktop_entry xcdroast "X-CD-Roast" xcdroast "AudioVideo;DiscBurning"
-}
-
-pkg_preinst() {
-	gnome2_icon_savelist
-}
-
-pkg_postinst() {
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
-}