[gentoo-commits] repo/gentoo:master commit in: dev-python/pyilmbase/

["Sam James" <sam@gentoo.org>]

commit:     e5b3baff61c2779f590b6974d2527237ad119346
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 18 22:47:14 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Feb 18 22:48:07 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e5b3baff

dev-python/pyilmbase: block dev-libs/imath[python] in ~arch

Bug: https://bugs.gentoo.org/833624
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/pyilmbase/pyilmbase-2.5.7-r1.ebuild | 56 ++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/dev-python/pyilmbase/pyilmbase-2.5.7-r1.ebuild b/dev-python/pyilmbase/pyilmbase-2.5.7-r1.ebuild
new file mode 100644
index 000000000000..5e34432e6d8a
--- /dev/null
+++ b/dev-python/pyilmbase/pyilmbase-2.5.7-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit cmake python-single-r1
+
+DESCRIPTION="IlmBase Python bindings"
+HOMEPAGE="https://www.openexr.com"
+SRC_URI="https://github.com/AcademySoftwareFoundation/openexr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/openexr-${PV}/PyIlmBase"
+
+LICENSE="BSD"
+SLOT="0/25"
+KEYWORDS="~amd64 ~x86"
+IUSE="exceptions test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	!dev-libs/imath[python]
+	~media-libs/openexr-${PV}:=
+	sys-libs/zlib
+	$(python_gen_cond_dep '
+		>=dev-libs/boost-1.62.0-r1:=[python,${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.10.4[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-0001-disable-py2-for-boost.patch
+	"${FILESDIR}"/${P}-0002-install-imathnumpy.so.patch
+	"${FILESDIR}"/${P}-0003-fix-pkgconfig-file.patch
+)
+
+DOCS=( README.md )
+
+src_configure() {
+	local mycmakeargs=(
+		# starting with boost-1.76.0 we ship the cmake config files
+		-DBoost_NO_BOOST_CMAKE=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_Python2=ON
+		-DPYILMBASE_INSTALL_PKG_CONFIG=ON
+		-DPYIMATH_ENABLE_EXCEPTIONS=$(usex exceptions)
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	cmake_src_configure
+}