From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1368073-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id A56A715808B
for <garchives@archives.gentoo.org>; Wed, 16 Feb 2022 16:57:06 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id E226EE07E0;
Wed, 16 Feb 2022 16:57:05 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id BFCC5E07E0
for <gentoo-commits@lists.gentoo.org>; Wed, 16 Feb 2022 16:57:05 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 85102343196
for <gentoo-commits@lists.gentoo.org>; Wed, 16 Feb 2022 16:57:04 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id E37482D3
for <gentoo-commits@lists.gentoo.org>; Wed, 16 Feb 2022 16:57:02 +0000 (UTC)
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Andreas Sturmlechner" <asturm@gentoo.org>
Message-ID: <1645030615.ba8149d415f37044f3fa13c65d0fd9ca21927846.asturm@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-util/cmake/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-util/cmake/Manifest dev-util/cmake/cmake-3.22.1.ebuild
X-VCS-Directories: dev-util/cmake/
X-VCS-Committer: asturm
X-VCS-Committer-Name: Andreas Sturmlechner
X-VCS-Revision: ba8149d415f37044f3fa13c65d0fd9ca21927846
X-VCS-Branch: master
Date: Wed, 16 Feb 2022 16:57:02 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 60d0d460-57fe-4199-a440-d8e9c4968d2d
X-Archives-Hash: fcbd8d4f6fbad1b29955bc1c4ad599dd
commit: ba8149d415f37044f3fa13c65d0fd9ca21927846
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Feb 16 16:56:35 2022 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Feb 16 16:56:55 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ba8149d4
dev-util/cmake: Drop 3.22.1
Overshadowed by stable 3.22.2.
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
dev-util/cmake/Manifest | 1 -
dev-util/cmake/cmake-3.22.1.ebuild | 232 -------------------------------------
2 files changed, 233 deletions(-)
diff --git a/dev-util/cmake/Manifest b/dev-util/cmake/Manifest
index 7ed140a37278..cf695f225f19 100644
--- a/dev-util/cmake/Manifest
+++ b/dev-util/cmake/Manifest
@@ -1,5 +1,4 @@
DIST cmake-3.20.5.tar.gz 9441947 BLAKE2B f073d7c3968c714be315f5014076c785790ed47e9a746f2d16bc59769fb6862009f67c2e118038c6c9d8390b709f2b4ed4a4dfc41a93996fedd9d7d77111b84a SHA512 4ad7f194353be291e76d86d95928633daea653a0bd8d35369ac6ee2bb3f811c3a1aabe6a2bd51c6d5b07af2c6edc7e38d8b347ded32ab1ddcf331dbfce40c008
DIST cmake-3.21.4.tar.gz 9630991 BLAKE2B ca6b6c50d984cc6713f3e88e1a6438c360d80c34927e60a20cc006ba47df2b91a290f1578d556f58d2d40711848a9b9caf36f65a043df892b81c1d48e3edb0d8 SHA512 0262a666f6da106576c26215580c40b54497bcdac400e847e1799716c31c71068293e719416338132a7da6122826c08ff50ac23dfed2711ab42631e96303f544
-DIST cmake-3.22.1.tar.gz 9778031 BLAKE2B 8c91e9e666ece94e0cfb5868ad257b1de824206b6f5420a5f516f684e4fd655e634918c59955f41a3f27b604b76946d86ab51cf975de7052c067a9dc4f952400 SHA512 b1e900fe573cd1cc76d26386f2298d7722737c9ff67930ee108994972b4561ef69caeb537177c9b95b7f17b755e20e034825d3807ea0d2dd4c391310b03adc11
DIST cmake-3.22.2.tar.gz 9779456 BLAKE2B 5f1c76344fe2d6fba012b0d745dc990ec1ed4bf32c99beac1e538f4b83c1d695aee757d2780e635b67c0a185935a6a70b344a733259e3a91d01c4b83e94e2730 SHA512 86e95f9ce773bcc7513a1c3901561a1b09d06830936b8b1d44e075fe3bac55cfa636eccdedfa94a9939f5e12eb965224559fac30a17c64314ee023acb2a3e53f
DIST cmake-3.23.0-rc1.tar.gz 9974071 BLAKE2B d4f3c6003ac36fb899a13a75c1ba8b25ecf233e939bcf88c4a63ae89837a5d3260e3c3458bea30cc59f64bf26742a15f2b6a27a3f98fc6339f137e0d1fa37a1b SHA512 c476ec038f5f2241765d7fd2f9afb5a0ff5969901b12cba43cf4b7ad507535c968833022ce1f293e3fab692e04b664809b5d66edc7d76e76a843c9634b3d86c6
diff --git a/dev-util/cmake/cmake-3.22.1.ebuild b/dev-util/cmake/cmake-3.22.1.ebuild
deleted file mode 100644
index a9b3de7323d6..000000000000
--- a/dev-util/cmake/cmake-3.22.1.ebuild
+++ /dev/null
@@ -1,232 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-CMAKE_MAKEFILE_GENERATOR="emake" # TODO RunCMake.LinkWhatYouUse fails consistently w/ ninja
-CMAKE_REMOVE_MODULES_LIST=( none )
-inherit bash-completion-r1 cmake elisp-common flag-o-matic multiprocessing \
- toolchain-funcs virtualx xdg-utils
-
-MY_P="${P/_/-}"
-
-DESCRIPTION="Cross platform Make"
-HOMEPAGE="https://cmake.org/"
-SRC_URI="https://cmake.org/files/v$(ver_cut 1-2)/${MY_P}.tar.gz"
-
-LICENSE="CMake"
-SLOT="0"
-[[ "${PV}" = *_rc* ]] || \
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-IUSE="doc emacs ncurses qt5 test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
- >=app-arch/libarchive-3.3.3:=
- app-crypt/rhash
- >=dev-libs/expat-2.0.1
- >=dev-libs/jsoncpp-1.9.2-r2:0=
- >=dev-libs/libuv-1.10.0:=
- >=net-misc/curl-7.21.5[ssl]
- sys-libs/zlib
- virtual/pkgconfig
- emacs? ( >=app-editors/emacs-23.1:* )
- ncurses? ( sys-libs/ncurses:0= )
- qt5? (
- dev-qt/qtcore:5
- dev-qt/qtgui:5
- dev-qt/qtwidgets:5
- )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
- doc? (
- dev-python/requests
- dev-python/sphinx
- )
- test? ( app-arch/libarchive[zstd] )
-"
-
-S="${WORKDIR}/${MY_P}"
-
-SITEFILE="50${PN}-gentoo.el"
-
-PATCHES=(
- # prefix
- "${FILESDIR}"/${PN}-3.16.0_rc4-darwin-bundle.patch
- "${FILESDIR}"/${PN}-3.14.0_rc3-prefix-dirs.patch
- "${FILESDIR}"/${PN}-3.19.1-darwin-gcc.patch
-
- # handle gentoo packaging in find modules
- "${FILESDIR}"/${PN}-3.17.0_rc1-FindBLAS.patch
- # Next patch needs to be reworked
- #"${FILESDIR}"/${PN}-3.17.0_rc1-FindLAPACK.patch
- "${FILESDIR}"/${PN}-3.5.2-FindQt4.patch
-
- # respect python eclasses
- "${FILESDIR}"/${PN}-2.8.10.2-FindPythonLibs.patch
- "${FILESDIR}"/${PN}-3.9.0_rc2-FindPythonInterp.patch
-
- "${FILESDIR}"/${PN}-3.18.0-filter_distcc_warning.patch # bug 691544
-
- # upstream fixes (can usually be removed with a version bump)
-)
-
-cmake_src_bootstrap() {
- # disable running of cmake in bootstrap command
- sed -i \
- -e '/"${cmake_bootstrap_dir}\/cmake"/s/^/#DONOTRUN /' \
- bootstrap || die "sed failed"
-
- # execinfo.h on Solaris isn't quite what it is on Darwin
- if [[ ${CHOST} == *-solaris* ]] ; then
- sed -i -e 's/execinfo\.h/blablabla.h/' \
- Source/kwsys/CMakeLists.txt || die
- fi
-
- # bootstrap script isn't exactly /bin/sh compatible
- tc-env_build ${CONFIG_SHELL:-sh} ./bootstrap \
- --prefix="${T}/cmakestrap/" \
- --parallel=$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)") \
- || die "Bootstrap failed"
-}
-
-cmake_src_test() {
- # fix OutDir and SelectLibraryConfigurations tests
- # these are altered thanks to our eclass
- sed -i -e 's:^#_cmake_modify_IGNORE ::g' \
- "${S}"/Tests/{OutDir,CMakeOnly/SelectLibraryConfigurations}/CMakeLists.txt \
- || die
-
- pushd "${BUILD_DIR}" > /dev/null
-
- local ctestargs
- [[ -n ${TEST_VERBOSE} ]] && ctestargs="--extra-verbose --output-on-failure"
-
- # Excluded tests:
- # BootstrapTest: we actually bootstrap it every time so why test it.
- # BundleUtilities: bundle creation broken
- # CMakeOnly.AllFindModules: pthread issues
- # CTest.updatecvs: fails to commit as root
- # Fortran: requires fortran
- # RunCMake.CompilerLauncher: also requires fortran
- # RunCMake.CPack_RPM: breaks if app-arch/rpm is installed because
- # debugedit binary is not in the expected location
- # RunCMake.CPack_DEB: breaks if app-arch/dpkg is installed because
- # it can't find a deb package that owns libc
- # RunCMake.{IncompatibleQt,ObsoleteQtMacros}: Require Qt4
- # TestUpload: requires network access
- "${BUILD_DIR}"/bin/ctest \
- -j "$(makeopts_jobs)" \
- --test-load "$(makeopts_loadavg)" \
- ${ctestargs} \
- -E "(BootstrapTest|BundleUtilities|ConfigSources|CMakeOnly.AllFindModules|CPackComponentsDEB-components-depend2|CompileOptions|CTest.UpdateCVS|DependencyGraph|Fortran|RunCMake.CompilerLauncher|RunCMake.IncompatibleQt|RunCMake.ObsoleteQtMacros|RunCMake.PrecompileHeaders|RunCMake.CPack_(DEB|RPM)|TestUpload)" \
- || die "Tests failed"
-
- popd > /dev/null
-}
-
-src_prepare() {
- cmake_src_prepare
-
- if [[ ${CHOST} == *-darwin* ]] ; then
- # disable Xcode hooks, bug #652134
- sed -i -e 's/cm\(\|Global\|Local\)XCode[^.]\+\.\(cxx\|h\)//' \
- Source/CMakeLists.txt || die
- sed -i -e '/define CMAKE_USE_XCODE/s/XCODE/NO_XCODE/' \
- -e '/cmGlobalXCodeGenerator.h/d' \
- Source/cmake.cxx || die
- # disable isysroot usage with GCC, we've properly instructed
- # where things are via GCC configuration and ldwrapper
- sed -i -e '/cmake_gnu_set_sysroot_flag/d' \
- Modules/Platform/Apple-GNU-*.cmake || die
- # disable isysroot usage with clang as well
- sed -i -e '/_SYSROOT_FLAG/d' \
- Modules/Platform/Apple-Clang.cmake || die
- # don't set a POSIX standard, system headers don't like that, #757426
- sed -i -e 's/^#if !defined(_WIN32) && !defined(__sun)/& \&\& !defined(__APPLE__)/' \
- Source/cmLoadCommandCommand.cxx \
- Source/cmStandardLexer.h \
- Source/cmSystemTools.cxx \
- Source/cmTimestamp.cxx
- sed -i -e 's/^#if !defined(_POSIX_C_SOURCE) && !defined(_WIN32) && !defined(__sun)/& \&\& !defined(__APPLE__)/' \
- Source/cmStandardLexer.h
- fi
-
- # Add gcc libs to the default link paths
- sed -i \
- -e "s|@GENTOO_PORTAGE_GCCLIBDIR@|${EPREFIX}/usr/${CHOST}/lib/|g" \
- -e "$(usex prefix-guest "s|@GENTOO_HOST@||" "/@GENTOO_HOST@/d")" \
- -e "s|@GENTOO_PORTAGE_EPREFIX@|${EPREFIX}/|g" \
- Modules/Platform/{UnixPaths,Darwin}.cmake || die "sed failed"
- if ! has_version -b \>=${CATEGORY}/${PN}-3.4.0_rc1 || ! cmake --version &>/dev/null ; then
- CMAKE_BINARY="${S}/Bootstrap.cmk/cmake"
- cmake_src_bootstrap
- fi
-}
-
-src_configure() {
- # Fix linking on Solaris
- [[ ${CHOST} == *-solaris* ]] && append-ldflags -lsocket -lnsl
-
- local mycmakeargs=(
- -DCMAKE_USE_SYSTEM_LIBRARIES=ON
- -DCMAKE_DOC_DIR=/share/doc/${PF}
- -DCMAKE_MAN_DIR=/share/man
- -DCMAKE_DATA_DIR=/share/${PN}
- -DSPHINX_MAN=$(usex doc)
- -DSPHINX_HTML=$(usex doc)
- -DBUILD_CursesDialog="$(usex ncurses)"
- -DBUILD_TESTING=$(usex test)
- )
- use qt5 && mycmakeargs+=( -DBUILD_QtDialog=ON )
-
- cmake_src_configure
-}
-
-src_compile() {
- cmake_src_compile
- use emacs && elisp-compile Auxiliary/cmake-mode.el
-}
-
-src_test() {
- virtx cmake_src_test
-}
-
-src_install() {
- cmake_src_install
-
- if use emacs; then
- elisp-install ${PN} Auxiliary/cmake-mode.el Auxiliary/cmake-mode.elc
- elisp-site-file-install "${FILESDIR}/${SITEFILE}"
- fi
-
- insinto /usr/share/vim/vimfiles/syntax
- doins Auxiliary/vim/syntax/cmake.vim
-
- insinto /usr/share/vim/vimfiles/indent
- doins Auxiliary/vim/indent/cmake.vim
-
- insinto /usr/share/vim/vimfiles/ftdetect
- doins "${FILESDIR}/${PN}.vim"
-
- dobashcomp Auxiliary/bash-completion/{${PN},ctest,cpack}
-}
-
-pkg_postinst() {
- use emacs && elisp-site-regen
- if use qt5; then
- xdg_icon_cache_update
- xdg_desktop_database_update
- xdg_mimeinfo_database_update
- fi
-}
-
-pkg_postrm() {
- use emacs && elisp-site-regen
- if use qt5; then
- xdg_icon_cache_update
- xdg_desktop_database_update
- xdg_mimeinfo_database_update
- fi
-}