[gentoo-commits] repo/gentoo:master commit in: net-libs/libomemo/

["Sebastian Pipping" <sping@gentoo.org>]

commit:     e4d887b2d811b34fc17ca3d641be942a736509f2
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 15 01:56:14 2022 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Tue Feb 15 01:56:14 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e4d887b2

net-libs/libomemo: 0.8.0

Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-3.0.30, Repoman-3.0.3

 net-libs/libomemo/Manifest              |  1 +
 net-libs/libomemo/libomemo-0.8.0.ebuild | 51 +++++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)

diff --git a/net-libs/libomemo/Manifest b/net-libs/libomemo/Manifest
index 910b73b72493..708dbeb43cff 100644
--- a/net-libs/libomemo/Manifest
+++ b/net-libs/libomemo/Manifest
@@ -1 +1,2 @@
 DIST libomemo-0.7.1.tar.gz 23770 BLAKE2B a3909650e399075f62026bd048a667a276a6cd7197ac18ddf9e3c12f57e5fd9cb2f5532ba69d0836af87e1415a5ffdc1746cf90a596dcf255265a64e921f039d SHA512 e5769dee4db7be246853e47e29ded9eefad2f62422951ce5dd0c1acee3bb92131c0423f09bc716be0f55fb02c747f07a6d5b2c656bdfeee0ee148252c51a1050
+DIST libomemo-0.8.0.tar.gz 25743 BLAKE2B 9b13aaaa21f16425fcecf963e187c5b686986e6bb01255c78042ea64e48d2c75a06729d1ad6e6b26d62d191e7d99305b7a8f1e07078221c6d14a12f587bf0743 SHA512 ff90de81928754f56bd2c6f3fcc83c13bb87d346e9bbedd6327bec33aab61a79061a709d541082723840205eb631b1a5493a43a5824e9e87e257d370692a606b

diff --git a/net-libs/libomemo/libomemo-0.8.0.ebuild b/net-libs/libomemo/libomemo-0.8.0.ebuild
new file mode 100644
index 000000000000..14c96fe495e2
--- /dev/null
+++ b/net-libs/libomemo/libomemo-0.8.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Implementation of OMEMO (XEP-0384) in C"
+HOMEPAGE="https://github.com/gkdr/libomemo"
+SRC_URI="https://github.com/gkdr/libomemo/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="static-libs test"
+
+RDEPEND="
+	dev-db/sqlite
+	dev-libs/glib
+	dev-libs/libgcrypt
+	dev-libs/mxml
+	"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-util/cmocka )
+	"
+
+RESTRICT="!test? ( test )"
+
+DOCS=( CHANGELOG.md README.md )
+
+src_compile() {
+	emake PREFIX=/usr
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX=/usr install
+
+	# Respect libdir other than /usr/lib, e.g. /usr/lib64
+	local libdir="$(get_libdir)"
+	if [[ ${libdir} != lib ]]; then
+		mv "${D}"/usr/{lib,${libdir}} || die
+		sed "s|^libdir=.*|libdir=\${prefix}/${libdir}|" \
+				-i "${D}/usr/${libdir}/pkgconfig/libomemo.pc" || die
+	fi
+
+	einstalldocs
+
+	if ! use static-libs ; then
+		rm "${D}/usr/${libdir}/libomemo.a" || die
+	fi
+}