[gentoo-commits] repo/gentoo:master commit in: media-gfx/alembic/

["Sam James" <sam@gentoo.org>]

commit:     cdbdfa031ae9572cc3558609adb4eca5e3508216
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sat Feb 12 14:27:53 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Feb 12 14:27:53 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cdbdfa03

media-gfx/alembic: flip over to OpenEXR 3

Things are getting complicated with trying to keep Blender
on OpenEXR 2. Blender needs to switch as a result, but
so do its dependencies.

Bug: https://bugs.gentoo.org/818232
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-gfx/alembic/alembic-1.8.3-r2.ebuild | 65 +++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

diff --git a/media-gfx/alembic/alembic-1.8.3-r2.ebuild b/media-gfx/alembic/alembic-1.8.3-r2.ebuild
new file mode 100644
index 000000000000..ad3d9d128436
--- /dev/null
+++ b/media-gfx/alembic/alembic-1.8.3-r2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="Open framework for storing and sharing scene data"
+HOMEPAGE="https://www.alembic.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="examples hdf5 python test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/imath:=
+	python? ( dev-libs/imath:=[python,${PYTHON_SINGLE_USEDEP}] )
+	hdf5? (
+		>=sci-libs/hdf5-1.10.2:=[zlib(+)]
+		>=sys-libs/zlib-1.2.11-r1
+	)
+	python? ( $(python_gen_cond_dep 'dev-libs/boost[python,${PYTHON_USEDEP}]') )
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.0-0001-set-correct-libdir.patch
+	"${FILESDIR}"/${P}-0001-find-py-ilmbase-in-config-mode.patch
+)
+
+DOCS=( ACKNOWLEDGEMENTS.txt FEEDBACK.txt NEWS.txt README.txt )
+
+src_prepare() {
+	cmake_src_prepare
+	# PyAlembic test doesn't properly find Imath, comment it for now
+	cmake_run_in python/PyAlembic cmake_comment_add_subdirectory Tests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DALEMBIC_BUILD_LIBS=ON
+		-DALEMBIC_SHARED_LIBS=ON
+		# currently does nothing but require doxygen
+		-DDOCS_PATH=OFF
+		-DUSE_ARNOLD=OFF
+		-DUSE_BINARIES=ON
+		-DUSE_EXAMPLES=$(usex examples)
+		-DUSE_HDF5=$(usex hdf5)
+		-DUSE_MAYA=OFF
+		-DUSE_PRMAN=OFF
+		-DUSE_PYALEMBIC=$(usex python)
+		-DUSE_TESTS=$(usex test)
+	)
+
+	use python && mycmakeargs+=( -DPython3_EXECUTABLE=${PYTHON} )
+
+	cmake_src_configure
+}