[gentoo-commits] repo/gentoo:master commit in: www-apps/cgp/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     b38e2080ea0b9192ce965dee5ebaa897c09fea7a
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Wed Feb  9 21:42:39 2022 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Wed Feb  9 22:56:48 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b38e2080

www-apps/cgp: update EAPI 7 -> 8

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 www-apps/cgp/cgp-1_p20190510-r2.ebuild | 55 ++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/www-apps/cgp/cgp-1_p20190510-r2.ebuild b/www-apps/cgp/cgp-1_p20190510-r2.ebuild
new file mode 100644
index 000000000000..2464e6c569ee
--- /dev/null
+++ b/www-apps/cgp/cgp-1_p20190510-r2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit webapp
+
+MY_PN="${PN^^}"
+MY_PV="fd8fa70739d18d786e88f7ffa57e250e0e41af8f"
+
+DESCRIPTION="A graphical web-based front-end for visualizing RRD collected by collectd"
+HOMEPAGE="https://github.com/pommi/CGP"
+SRC_URI="https://github.com/pommi/${MY_PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+LICENSE="CC-BY-2.0 GPL-2+ GPL-3 MIT"
+KEYWORDS="amd64 x86"
+
+RDEPEND="
+	dev-lang/php[json(+)]
+	net-analyzer/rrdtool[graph]
+	virtual/httpd-php
+"
+
+need_httpd_cgi
+
+DOCS=( "README.md" "doc/CHANGELOG" "doc/nginx.conf" )
+
+PATCHES=( "${FILESDIR}/${P}-double-quote.patch" )
+
+src_install() {
+	webapp_src_preinst
+
+	einstalldocs
+
+	# Since the docs are already installed, remove them from htdocs
+	# The file doc/CHANGELOG is needed, as CGP reads from there it's version
+	rm -r .gitignore LICENSE doc/nginx.conf || die
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+
+	webapp_src_install
+}
+
+pkg_postinst() {
+	webapp_pkg_postinst
+
+	einfo "The command shell_exec must not be disabled"
+	einfo "through the disable_functions php.ini directive."
+	einfo "It must allow execution of the rrdtool program."
+	einfo ""
+	einfo "An configuration file for www-servers/nginx"
+	einfo "has been installed as an example."
+}