From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1365647-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id BF54415808B
for <garchives@archives.gentoo.org>; Tue, 8 Feb 2022 07:57:26 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id E89FDE0788;
Tue, 8 Feb 2022 07:57:25 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 4CF0FE070D
for <gentoo-commits@lists.gentoo.org>; Tue, 8 Feb 2022 07:57:25 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id CF530342D52
for <gentoo-commits@lists.gentoo.org>; Tue, 8 Feb 2022 07:57:23 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 38E7D2AF
for <gentoo-commits@lists.gentoo.org>; Tue, 8 Feb 2022 07:57:22 +0000 (UTC)
From: "Lars Wendler" <polynomial-c@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Lars Wendler" <polynomial-c@gentoo.org>
Message-ID: <1644307024.12d68e5192c7e9e06eb3716be075d0e0cc0518ab.polynomial-c@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-crypt/gpgme/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-crypt/gpgme/Manifest app-crypt/gpgme/gpgme-1.17.0.ebuild
X-VCS-Directories: app-crypt/gpgme/
X-VCS-Committer: polynomial-c
X-VCS-Committer-Name: Lars Wendler
X-VCS-Revision: 12d68e5192c7e9e06eb3716be075d0e0cc0518ab
X-VCS-Branch: master
Date: Tue, 8 Feb 2022 07:57:22 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: d9951db0-ce12-4df0-900d-7b6084fd997b
X-Archives-Hash: 76ba9f5d1c8253877cea2bd96247d200
commit: 12d68e5192c7e9e06eb3716be075d0e0cc0518ab
Author: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Tue Feb 8 07:21:26 2022 +0000
Commit: Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Tue Feb 8 07:57:04 2022 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=12d68e51
app-crypt/gpgme: Bump to version 1.17.0
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>
app-crypt/gpgme/Manifest | 1 +
app-crypt/gpgme/gpgme-1.17.0.ebuild | 111 ++++++++++++++++++++++++++++++++++++
2 files changed, 112 insertions(+)
diff --git a/app-crypt/gpgme/Manifest b/app-crypt/gpgme/Manifest
index df3e6542686b..5715ee6062f7 100644
--- a/app-crypt/gpgme/Manifest
+++ b/app-crypt/gpgme/Manifest
@@ -1,2 +1,3 @@
DIST gpgme-1.15.1.tar.bz2 1699349 BLAKE2B d3a6ccaa35360ed3fc79364dfcc3f2fdcb70e5e41ac72ef011373a39d5def9be9ce1be45843ab65a87630d3fc570d29db5f40b9a273aa8e281464c9d1d3477de SHA512 1d75a848cce6389f7cb8896b57a28dfe1dc5a447bfb4f128b0994a43e04134343400a3be063e971f03dfd595474cfd558519741d5d56afb3e84853ad4f2a45c2
DIST gpgme-1.16.0.tar.bz2 1718913 BLAKE2B da55e695b148e949a1c0770d0298d7a8c9f87d7a1f9e45d380f8c13c472bd44cb4266adb9a113e2b1dcc2596291744f48fdf998ff2de876059d89d184dc87f3a SHA512 69487be69612e9bf0221ff56ae687248bd13635db1b7087130e93c1670e38f3c810bbca17723555c04fe207976c35871bbc3da005179ce099504321cf33636e4
+DIST gpgme-1.17.0.tar.bz2 1748416 BLAKE2B 32df1e3e579275d39507cb013ab7eded12149735f27a5eb1f4c3142df6b97864947a64c7fa58736e6cdea4ae623fb42eeb007596ec08ac5fdfb2af7826447550 SHA512 7ab379c6be2031ff24334a636e596f01c9d491627b695cc6cce7a361e78c6054b7891c521f07becea3c5da10c58043c1acffbba6058bbbfaa515241d75dd6c46
diff --git a/app-crypt/gpgme/gpgme-1.17.0.ebuild b/app-crypt/gpgme/gpgme-1.17.0.ebuild
new file mode 100644
index 000000000000..c6303a56b2af
--- /dev/null
+++ b/app-crypt/gpgme/gpgme-1.17.0.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_OPTIONAL=1
+
+inherit distutils-r1 flag-o-matic libtool qmake-utils toolchain-funcs
+
+DESCRIPTION="GnuPG Made Easy is a library for making GnuPG easier to use"
+HOMEPAGE="http://www.gnupg.org/related_software/gpgme"
+SRC_URI="mirror://gnupg/gpgme/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="1/11" # subslot = soname major version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="common-lisp static-libs +cxx python qt5"
+
+# Note: On each bump, update dep bounds on each version from configure.ac!
+RDEPEND=">=app-crypt/gnupg-2
+ >=dev-libs/libassuan-2.5.3:=
+ >=dev-libs/libgpg-error-1.36:=
+ python? ( ${PYTHON_DEPS} )
+ qt5? ( dev-qt/qtcore:5 )"
+ #doc? ( app-doc/doxygen[dot] )
+DEPEND="${RDEPEND}
+ qt5? ( dev-qt/qttest:5 )"
+BDEPEND="python? ( dev-lang/swig )"
+
+REQUIRED_USE="qt5? ( cxx ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+do_python() {
+ if use python; then
+ pushd "lang/python" > /dev/null || die
+ top_builddir="../.." srcdir="." CPP=$(tc-getCPP) distutils-r1_src_${EBUILD_PHASE}
+ popd > /dev/null
+ fi
+}
+
+pkg_setup() {
+ addpredict /run/user/$(id -u)/gnupg
+
+ local MAX_WORKDIR=66
+ if [[ "${#WORKDIR}" -gt "${MAX_WORKDIR}" ]]; then
+ ewarn "Disabling tests as WORKDIR '${WORKDIR}' is longer than ${MAX_WORKDIR} which will fail tests"
+ SKIP_TESTS=1
+ fi
+}
+
+src_prepare() {
+ default
+ elibtoolize
+
+ # Make best effort to allow longer PORTAGE_TMPDIR
+ # as usock limitation fails build/tests
+ ln -s "${P}" "${WORKDIR}/b"
+ S="${WORKDIR}/b"
+}
+
+src_configure() {
+ local languages=()
+ use common-lisp && languages+=( "cl" )
+ use cxx && languages+=( "cpp" )
+ if use qt5; then
+ languages+=( "qt" )
+ #use doc ||
+ export DOXYGEN=true
+ export MOC="$(qt5_get_bindir)/moc"
+ fi
+
+ econf \
+ $([[ -n "${SKIP_TESTS}" ]] && echo "--disable-gpg-test --disable-gpgsm-test") \
+ --enable-languages="${languages[*]}" \
+ $(use_enable static-libs static)
+
+ use python && make -C lang/python prepare
+
+ do_python
+}
+
+src_compile() {
+ default
+ do_python
+}
+
+src_test() {
+ [[ -z "${SKIP_TESTS}" ]] || return
+
+ default
+ if use python; then
+ test_python() {
+ emake -C lang/python/tests check \
+ PYTHON=${EPYTHON} \
+ PYTHONS=${EPYTHON} \
+ TESTFLAGS="--python-libdir=${BUILD_DIR}/lib"
+ }
+ python_foreach_impl test_python
+ fi
+}
+
+src_install() {
+ default
+ do_python
+ find "${ED}" -type f -name '*.la' -delete || die
+
+ # backward compatibility for gentoo
+ # in the past we had slots
+ dodir /usr/include/gpgme
+ dosym ../gpgme.h /usr/include/gpgme/gpgme.h
+}