[gentoo-commits] repo/gentoo:master commit in: games-puzzle/braid-gog/

["James Le Cuirot" <chewi@gentoo.org>]

commit:     d6b4159a27c6db4631c97b379bbc1aea8e27ac9a
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Sun Feb  6 14:51:23 2022 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Sun Feb  6 14:52:24 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d6b4159a

games-puzzle/braid-gog: New package for the GOG version

Closes: https://bugs.gentoo.org/349136
Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 games-puzzle/braid-gog/Manifest                 |  1 +
 games-puzzle/braid-gog/braid-gog-2.0.0.3.ebuild | 55 +++++++++++++++++++++++++
 games-puzzle/braid-gog/metadata.xml             |  8 ++++
 3 files changed, 64 insertions(+)

diff --git a/games-puzzle/braid-gog/Manifest b/games-puzzle/braid-gog/Manifest
new file mode 100644
index 000000000000..0d8afa9dbc5f
--- /dev/null
+++ b/games-puzzle/braid-gog/Manifest
@@ -0,0 +1 @@
+DIST gog_braid_2.0.0.3.sh 122931560 BLAKE2B a15dde4a56510613d7104126c1f275ff17f07a246fc3f09cd2df26b870488c4b4e81a32f7505fc3b720f503f252ac00259aa7225b25c804af64bcced24c81bec SHA512 a7cccb0135e359e5bd7e0499fa449ff1e57c00a648aba37a5df7a12ec5a2a6d3b1758af7a168aec562c83bde864fa6cbbe2504b8a334bab01f6b209a8e4aadc6

diff --git a/games-puzzle/braid-gog/braid-gog-2.0.0.3.ebuild b/games-puzzle/braid-gog/braid-gog-2.0.0.3.ebuild
new file mode 100644
index 000000000000..d01598d9c1ba
--- /dev/null
+++ b/games-puzzle/braid-gog/braid-gog-2.0.0.3.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop unpacker wrapper xdg
+
+MY_PN="braid"
+DESCRIPTION="Platform game where you manipulate flow of time"
+HOMEPAGE="https://www.gog.com/en/game/braid"
+SRC_URI="gog_${MY_PN}_${PV}.sh"
+
+LICENSE="GOG-EULA Arphic CC-BY-NC-SA-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="bindist fetch splitdebug"
+
+BDEPEND="
+	app-arch/unzip
+"
+
+RDEPEND="
+	media-gfx/nvidia-cg-toolkit[abi_x86_32]
+	media-libs/libsdl2[joystick,opengl,sound,video,abi_x86_32]
+	virtual/opengl[abi_x86_32]
+	x11-libs/fltk:1[abi_x86_32]
+	x11-libs/libX11[abi_x86_32]
+	!${CATEGORY}/${MY_PN}-hb
+"
+
+S="${WORKDIR}/data/noarch/game"
+DIR="/opt/${MY_PN}"
+QA_PREBUILT="${DIR#/}/*"
+
+pkg_nofetch() {
+	einfo "Please buy and download ${SRC_URI} from:"
+	einfo "  ${HOMEPAGE}"
+	einfo "and move it to your distfiles directory."
+}
+
+src_unpack() {
+	unpack_zip ${A}
+}
+
+src_install() {
+	exeinto "${DIR}"
+	insinto "${DIR}"
+
+	doexe {Braid,launcher}.bin.x86
+	doins -r data Icon.*
+	dodoc READ_ME.txt
+
+	make_wrapper ${MY_PN} ./launcher.bin.x86 "${DIR}" /usr/$(ABI=x86 get_libdir)/fltk
+	make_desktop_entry ${MY_PN} Braid "${EPREFIX}${DIR}"/Icon.png
+}

diff --git a/games-puzzle/braid-gog/metadata.xml b/games-puzzle/braid-gog/metadata.xml
new file mode 100644
index 000000000000..7c730d47817a
--- /dev/null
+++ b/games-puzzle/braid-gog/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+</pkgmetadata>