[gentoo-commits] repo/gentoo:master commit in: app-i18n/ibus-table/

["Akinori Hattori" <hattya@gentoo.org>]

commit:     57871a71dc130bd8aa33770f0d5662e5a760703f
Author:     Akinori Hattori <hattya <AT> gentoo <DOT> org>
AuthorDate: Sat Feb  5 14:42:32 2022 +0000
Commit:     Akinori Hattori <hattya <AT> gentoo <DOT> org>
CommitDate: Sat Feb  5 14:42:32 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=57871a71

app-i18n/ibus-table: new upstream release

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Akinori Hattori <hattya <AT> gentoo.org>

 app-i18n/ibus-table/Manifest                 |  1 +
 app-i18n/ibus-table/ibus-table-1.16.7.ebuild | 55 ++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/app-i18n/ibus-table/Manifest b/app-i18n/ibus-table/Manifest
index 188cfd582070..0f6b2cc10ad9 100644
--- a/app-i18n/ibus-table/Manifest
+++ b/app-i18n/ibus-table/Manifest
@@ -1 +1,2 @@
 DIST ibus-table-1.14.1.tar.gz 1451943 BLAKE2B e8fc54daf89aaee813de6788bef9f56a654ffdf4751acf3e2f622d971134c3aba906ca2b106f51b2fa305b8c65fb4db862f57f5f9e3e82a569c5a72e3017e627 SHA512 a658c2d370d173d2fe2f38c02c6b822a17771754ac98a856f954c4c998e90a857f9d54ed652c74159af9545d445001d202e7b5578e7694f8767f928b42db9055
+DIST ibus-table-1.16.7.tar.gz 1463213 BLAKE2B 2d3eb68570c834f668f8d8f50ea4fc79cb1def331405f136000dda37d9be0150a442e2b92a29610632eefde42089f6c5b782ea63fa1d9b5fde9443419a6831cf SHA512 6dc08df4c5e7216b3b9e366c404dd6d89566937f83f58074aed1c5c925bc411568855ac08a8edab306b4b535da428ae660d4876a35e546aad75ede01aa608ee3

diff --git a/app-i18n/ibus-table/ibus-table-1.16.7.ebuild b/app-i18n/ibus-table/ibus-table-1.16.7.ebuild
new file mode 100644
index 000000000000..7314f41b0540
--- /dev/null
+++ b/app-i18n/ibus-table/ibus-table-1.16.7.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE="sqlite(+)"
+
+inherit gnome2-utils python-single-r1 xdg
+
+DESCRIPTION="Tables engines for IBus"
+HOMEPAGE="https://github.com/ibus/ibus/wiki"
+SRC_URI="https://github.com/kaio/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls"
+RESTRICT="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	virtual/libiconv
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	python_fix_shebang .
+
+	default
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+pkg_preinst() {
+	xdg_pkg_preinst
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}