[gentoo-commits] repo/gentoo:master commit in: media-video/devedeng/

["Bernard Cafarelli" <voyageur@gentoo.org>]

commit:     08230d43d57767f1ad235fe82f739e47a8e49936
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Tue Feb  1 23:19:48 2022 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Tue Feb  1 23:20:00 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=08230d43

media-video/devedeng: update python versions, enable unit tests

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 media-video/devedeng/devedeng-4.16.0-r2.ebuild | 53 ++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/media-video/devedeng/devedeng-4.16.0-r2.ebuild b/media-video/devedeng/devedeng-4.16.0-r2.ebuild
new file mode 100644
index 000000000000..bca23b638370
--- /dev/null
+++ b/media-video/devedeng/devedeng-4.16.0-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 xdg
+
+DESCRIPTION="DevedeNG is a program to create video DVDs and CDs (VCD, sVCD or CVD)"
+HOMEPAGE="https://www.rastersoft.com/programas/devede.html"
+SRC_URI="https://gitlab.com/rastersoft/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	app-cdr/cdrtools
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3
+	|| ( media-video/vlc media-video/mpv media-video/mplayer )
+	media-video/ffmpeg
+	media-video/dvdauthor
+	media-video/vcdimager
+	|| ( app-cdr/brasero kde-apps/k3b app-cdr/xfburn )"
+
+DEPEND="${PYTHON_DEPS}"
+
+PATCHES=( "${FILESDIR}"/${PN}-4.14.0-no_compress_man.patch )
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	default
+
+	# Documentation path
+	sed -e "s#/usr/share/doc/devedeng#/usr/share/doc/${P}#" \
+		-i src/devedeng/configuration_data.py || die
+	sed -e "/'doc'/s/devedeng/${P}/" -i setup.py || die
+
+	# Desktop icon
+	sed -e "/^Icon/s/.svg$//#" -i data/devede_ng.py.desktop || die
+}
+
+python_test() {
+	pushd src/unitests || die
+	eunittest
+	popd || die
+
+}