[gentoo-commits] repo/gentoo:master commit in: dev-python/pylibmc/

["Michał Górny" <mgorny@gentoo.org>]

commit:     1535a00b0a5e4c8813e1628f6b8c343cb09186ce
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 29 21:15:03 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Jan 29 21:15:03 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1535a00b

dev-python/pylibmc: Switch to PEP 517 build

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pylibmc/pylibmc-1.6.1-r2.ebuild | 57 ++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

diff --git a/dev-python/pylibmc/pylibmc-1.6.1-r2.ebuild b/dev-python/pylibmc/pylibmc-1.6.1-r2.ebuild
new file mode 100644
index 000000000000..93cd31ed9d80
--- /dev/null
+++ b/dev-python/pylibmc/pylibmc-1.6.1-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Libmemcached wrapper written as a Python extension"
+HOMEPAGE="
+	https://sendapatch.se/projects/pylibmc/
+	https://pypi.org/project/pylibmc/
+	https://github.com/lericson/pylibmc/"
+# One image is missing from the doc at PyPI
+# https://github.com/lericson/pylibmc/pull/221
+SRC_URI="https://github.com/lericson/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+
+RDEPEND=">=dev-libs/libmemcached-0.32"
+# Older sphinx versions fail to compile the doc
+# https://github.com/sphinx-doc/sphinx/issues/3266
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		net-misc/memcached
+	)"
+
+PATCHES=(
+	"${FILESDIR}/pylibmc-1.6.1-fix-test-failures-r1.patch"
+)
+
+distutils_enable_sphinx docs
+distutils_enable_tests nose
+
+python_prepare_all() {
+	sed -e "/with-info=1/d" -i setup.cfg || die
+
+	# some amazon thing, expects to be in AWS
+	rm tests/test_autoconf.py || die
+	distutils-r1_python_prepare_all
+
+	# needed for docs
+	export PYLIBMC_DIR=.
+}
+
+src_test() {
+	local -x MEMCACHED_PORT=11219
+	memcached -d -p "${MEMCACHED_PORT}" -u nobody -l localhost \
+		-P "${T}/m.pid" || die
+	distutils-r1_src_test
+	kill "$(<"${T}/m.pid")" || die
+}