[gentoo-commits] repo/gentoo:master commit in: net-misc/connman/

["Ben Kohler" <bkohler@gentoo.org>]

commit:     cb0947ef5f77d8cb7e3e6599f9f1d791f70fef6f
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 27 12:43:13 2022 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Thu Jan 27 12:44:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cb0947ef

net-misc/connman: snapshot for security fixes

Bug: https://bugs.gentoo.org/832028
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 net-misc/connman/Manifest                      |   1 +
 net-misc/connman/connman-1.40_p20220125.ebuild | 105 +++++++++++++++++++++++++
 2 files changed, 106 insertions(+)

diff --git a/net-misc/connman/Manifest b/net-misc/connman/Manifest
index 1b9d3242e462..001e8ddd36a4 100644
--- a/net-misc/connman/Manifest
+++ b/net-misc/connman/Manifest
@@ -1 +1,2 @@
 DIST connman-1.40.tar.xz 758516 BLAKE2B 66834032f82e80a6f950d7ff823dc5f1f45090f3444b5a0241cabd0346cf9749b8780b624ce6a8e505305cc1a75423e5a95a7b1f77a282d231845bc33389924a SHA512 33df90814b7499aeafcd51fca4f8ffbc07efacfa29dda46d3b9bcd3ff26264dc53c3991e7e53a8563ca403015c345e59c7ad29427c38ee3d88dd282479db7a0f
+DIST connman-6f1315d1960fc3f71bca9b3044f4f2b1560aea5f.tar.gz 733290 BLAKE2B 5dbac4e00668cd9b268906482a60214525872d5adfea2e424ca62cf37ee5079ba3c9f74fd604b4603614884494d691fd170a9b88eb5f0c4e7546aa6999691eef SHA512 060d7c9fe3c37f994db37118c59f4781a1a93e796d09354e3a2e9284b5f488f24a7d8066722b14c2b2ef953501f0fc0d69c027ca38797ab190191012a0f006b3

diff --git a/net-misc/connman/connman-1.40_p20220125.ebuild b/net-misc/connman/connman-1.40_p20220125.ebuild
new file mode 100644
index 000000000000..c798015285ac
--- /dev/null
+++ b/net-misc/connman/connman-1.40_p20220125.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+inherit autotools systemd tmpfiles
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/network/connman/connman.git"
+else
+	#SRC_URI="https://www.kernel.org/pub/linux/network/${PN}/${P}.tar.xz"
+	COMMIT="6f1315d1960fc3f71bca9b3044f4f2b1560aea5f"
+	SRC_URI="https://git.kernel.org/pub/scm/network/${PN}/${PN}.git/snapshot/${PN}-${COMMIT}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+DESCRIPTION="Provides a daemon for managing internet connections"
+HOMEPAGE="https://git.kernel.org/pub/scm/network/connman/connman.git/"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="bluetooth debug doc +ethernet examples iptables iwd l2tp networkmanager
++nftables ofono openconnect openvpn policykit pptp tools vpnc +wifi wireguard
+wispr"
+
+REQUIRED_USE="^^ ( iptables nftables )"
+BDEPEND="virtual/pkgconfig"
+RDEPEND=">=dev-libs/glib-2.16
+	>=sys-apps/dbus-1.2.24
+	sys-libs/readline:0=
+	bluetooth? ( net-wireless/bluez )
+	iptables? ( >=net-firewall/iptables-1.4.8 )
+	iwd? ( net-wireless/iwd )
+	l2tp? ( net-dialup/xl2tpd )
+	nftables? (
+		>=net-libs/libnftnl-1.0.4:0=
+		>=net-libs/libmnl-1.0.0:0= )
+	ofono? ( net-misc/ofono )
+	openconnect? ( net-vpn/openconnect )
+	openvpn? ( net-vpn/openvpn )
+	policykit? ( sys-auth/polkit )
+	pptp? ( net-dialup/pptpclient )
+	vpnc? ( net-vpn/vpnc )
+	wifi? ( >=net-wireless/wpa_supplicant-2.0[dbus] )
+	wireguard? ( >=net-libs/libmnl-1.0.0:0= )
+	wispr? ( net-libs/gnutls )"
+
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.39"
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		--runstatedir=/run \
+		--with-systemdunitdir=$(systemd_get_systemunitdir) \
+		--with-tmpfilesdir="${EPREFIX}"/usr/lib/tmpfiles.d \
+		--enable-client \
+		--enable-datafiles \
+		--enable-loopback=builtin \
+		$(use_enable bluetooth bluetooth builtin) \
+		$(use_enable debug) \
+		$(use_enable ethernet ethernet builtin) \
+		$(use_enable examples test) \
+		$(use_enable iwd) \
+		$(use_enable l2tp l2tp builtin) \
+		$(use_enable networkmanager nmcompat) \
+		$(use_enable ofono ofono builtin) \
+		$(use_enable openconnect openconnect builtin) \
+		$(use_enable openvpn openvpn builtin) \
+		$(use_enable policykit polkit builtin) \
+		$(use_enable pptp pptp builtin) \
+		$(use_enable tools) \
+		$(use_enable vpnc vpnc builtin) \
+		$(use_enable wifi wifi builtin) \
+		$(use_enable wireguard) \
+		$(use_enable wispr wispr builtin) \
+		--with-firewall=$(usex iptables "iptables" "nftables" ) \
+		--disable-iospm \
+		--disable-hh2serial-gps
+}
+
+src_install() {
+	default
+	dobin client/connmanctl
+
+	if use doc; then
+		dodoc doc/*.txt
+	fi
+	keepdir /usr/lib/${PN}/scripts
+	keepdir /var/lib/${PN}
+	newinitd "${FILESDIR}"/${PN}.initd2 ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+}
+
+pkg_postinst() {
+	tmpfiles_process connman_resolvconf.conf
+}