[gentoo-commits] repo/gentoo:master commit in: dev-java/emma/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     304088427c29784f91c72ec71ef2f4ac0f572b0c
Author:     Volkmar W. Pogatzki <gentoo <AT> pogatzki <DOT> net>
AuthorDate: Mon Jan 24 17:05:56 2022 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Tue Jan 25 09:32:13 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30408842

dev-java/emma: EAPI 8, min java 1.8:*

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Volkmar W. Pogatzki <gentoo <AT> pogatzki.net>
Closes: https://github.com/gentoo/gentoo/pull/23941
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 dev-java/emma/emma-2.0.5312-r4.ebuild | 52 +++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

diff --git a/dev-java/emma/emma-2.0.5312-r4.ebuild b/dev-java/emma/emma-2.0.5312-r4.ebuild
new file mode 100644
index 000000000000..5e00f2ec4a50
--- /dev/null
+++ b/dev-java/emma/emma-2.0.5312-r4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="source"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Free Java code coverage tool"
+HOMEPAGE="http://emma.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.zip"
+
+LICENSE="CPL-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+IUSE="+launcher"
+
+CDEPEND="
+	dev-java/ant-core
+	launcher? ( !sci-biology/emboss )"
+
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.8:*"
+
+DEPEND="
+	${CDEPEND}
+	>=virtual/jdk-1.8:*"
+
+BDEPEND="app-arch/unzip"
+
+EANT_BUILD_TARGET="build"
+
+src_prepare() {
+	default
+	eapply "${FILESDIR}/${P}-java15api.patch"
+	# bcp mangling unneccessary for 1.4+ and breaks with IBM 1.6 - bug #220463
+	sed -e '/bootclasspathref/d' -e '/extdirs/d' -i build.xml || die
+}
+
+src_install() {
+	java-pkg_dojar "dist/${PN}.jar"
+	java-pkg_dojar "dist/${PN}_ant.jar"
+	java-pkg_register-ant-task
+
+	use launcher && java-pkg_dolauncher ${PN} --main emmarun
+
+	# One of these does not have java sources
+	use source && java-pkg_dosrc */*/com 2> /dev/null
+}