[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-session/

["Sam James" <sam@gentoo.org>]

commit:     a7ecdbaf62223167f67c0be3e861280ec32cc17a
Author:     Adel KARA SLIMANE <adel.ks <AT> zegrapher <DOT> com>
AuthorDate: Tue Jan 11 11:52:43 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jan 21 19:07:03 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a7ecdbaf

lxqt-base/lxqt-session: version bump to 1.0.1

Signed-off-by: Adel KARA SLIMANE <adel.ks <AT> zegrapher.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 lxqt-base/lxqt-session/Manifest                  |  1 +
 lxqt-base/lxqt-session/lxqt-session-1.0.1.ebuild | 60 ++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/lxqt-base/lxqt-session/Manifest b/lxqt-base/lxqt-session/Manifest
index 7f83e2a9388b..3b378e8db596 100644
--- a/lxqt-base/lxqt-session/Manifest
+++ b/lxqt-base/lxqt-session/Manifest
@@ -1 +1,2 @@
 DIST lxqt-session-0.17.0.tar.xz 179028 BLAKE2B 5f5a152f294482cc22e6285b22041eab6769d65f1f8ecccad560187e61827e4aad50a3069ea14044cd77610a4a4d3e23b575a427a4098af946d79d5b24df00a5 SHA512 e3573ee76e5fcf285b0ddd177ae7324f6fee038ea110c950d7054da622bf6615d9ac8715cc0cde6db9034d710933a80c80f14470197d2cc275d48695f74ba7b6
+DIST lxqt-session-1.0.1.tar.xz 182644 BLAKE2B 8ca252ceca5f122326337bf465db462ea5c78c970aa050c2a360c40ff882d77e8864ad6e2de97c000a9731aad583a375529824e09abd694baec93c1ca78ef4db SHA512 1f027237fa02a95952c0a42b9aac9ae1f55bb1bc74ceeee52eca2517a16804874639add7e1a130550a22373409012f203928953c14317ec1cbd7f18b238e017e

diff --git a/lxqt-base/lxqt-session/lxqt-session-1.0.1.ebuild b/lxqt-base/lxqt-session/lxqt-session-1.0.1.ebuild
new file mode 100644
index 000000000000..532c7ab67f83
--- /dev/null
+++ b/lxqt-base/lxqt-session/lxqt-session-1.0.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt Session Manager"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+IUSE="+udev"
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.15:5
+	>=dev-util/lxqt-build-tools-0.10.0
+"
+DEPEND="
+	>=dev-libs/libqtxdg-3.3.1
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtdbus-5.15:5
+	>=dev-qt/qtgui-5.15:5
+	>=dev-qt/qtwidgets-5.15:5
+	>=dev-qt/qtx11extras-5.15:5
+	kde-frameworks/kwindowsystem:5[X]
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	sys-process/procps:=
+	x11-libs/libX11
+	x11-misc/xdg-user-dirs
+	udev? ( virtual/libudev:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_LIBUDEV=$(usex udev)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman lxqt-config-session/man/*.1 lxqt-session/man/*.1
+
+	newenvd - 91lxqt-config-dir <<- _EOF_
+		XDG_CONFIG_DIRS='${EPREFIX}/usr/share'
+	_EOF_
+}