[gentoo-commits] repo/gentoo:master commit in: gnome-extra/cinnamon-control-center/

["Sam James" <sam@gentoo.org>]

commit:     c48c817117a7e0a622b4915ed60ed3c161d2d5da
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Tue Dec 28 21:15:27 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jan 21 17:15:09 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c48c8171

gnome-extra/cinnamon-control-center: 5.2.1 version bump

Add Python 3.10 support.

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 gnome-extra/cinnamon-control-center/Manifest       |  1 +
 .../cinnamon-control-center-5.2.1.ebuild           | 98 ++++++++++++++++++++++
 2 files changed, 99 insertions(+)

diff --git a/gnome-extra/cinnamon-control-center/Manifest b/gnome-extra/cinnamon-control-center/Manifest
index 8d09cffdc441..c4bb6f731215 100644
--- a/gnome-extra/cinnamon-control-center/Manifest
+++ b/gnome-extra/cinnamon-control-center/Manifest
@@ -1 +1,2 @@
 DIST cinnamon-control-center-5.0.2.tar.gz 3866962 BLAKE2B d292d610516647e149198cbfce652bfd094338612ef6b4765fcb80bd1fe15f2d643bbaa5343f1d79d57f3327c87a3256cfc3900493daf6f80569b1a0bacd821a SHA512 f47b88005ba1d7359ab99d80e99d2c42a93561ecddd98014f91674a5ae806b991169c88f3af6c8c187df23ebb8a9e12bbae5eefbfeaf2f3d087981192448c3c2
+DIST cinnamon-control-center-5.2.1.tar.gz 3863530 BLAKE2B 826494b8f8a4dead32d6031d7b4b2a44d357b3e8fedf1065b61193caa86ad433ba68fd9344f70bbce77bb94e086ae15f8854dc73916a5f60c49b1b2bd9e7101c SHA512 d322a9b460f13c697d327dda75a3ea16dd96414ed52ffbcdfc19479533178585da795c064ae441b36ef02f1aa779704db039328ca4ac4c373f363967948f2301

diff --git a/gnome-extra/cinnamon-control-center/cinnamon-control-center-5.2.1.ebuild b/gnome-extra/cinnamon-control-center/cinnamon-control-center-5.2.1.ebuild
new file mode 100644
index 000000000000..e8ca7c2831ca
--- /dev/null
+++ b/gnome-extra/cinnamon-control-center/cinnamon-control-center-5.2.1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit meson gnome2-utils python-any-r1 xdg virtualx
+
+DESCRIPTION="Cinnamons's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-control-center"
+SRC_URI="https://github.com/linuxmint/cinnamon-control-center/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="+colord input_devices_wacom +networkmanager +modemmanager gnome-online-accounts systemd test"
+REQUIRED_USE="modemmanager? ( networkmanager )"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=gnome-base/libgnomekbd-3.0.0:0=
+	>=gnome-extra/cinnamon-desktop-5.2:0=
+	>=gnome-extra/cinnamon-menus-5.2:0=
+	media-libs/fontconfig
+	>=sys-auth/polkit-0.103
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=x11-libs/libnotify-0.7.3:0=
+	x11-libs/libX11
+	>=x11-libs/libxklavier-5.1
+
+	colord? ( >=x11-misc/colord-0.1.14:0= )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7
+		>=gnome-extra/cinnamon-settings-daemon-5.2:0=
+		>=x11-libs/libXi-1.2 )
+	networkmanager? (
+		>=gnome-extra/nm-applet-1.2.0
+		>=net-misc/networkmanager-1.2.0:=[modemmanager?]
+
+		modemmanager? ( >=net-misc/modemmanager-0.7 )
+	)
+	gnome-online-accounts? (
+		>=net-libs/gnome-online-accounts-3.18.0
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+
+	colord? ( >=gnome-extra/gnome-color-manager-3 )
+	input_devices_wacom? ( gnome-extra/cinnamon-settings-daemon[input_devices_wacom] )
+	systemd? ( >=sys-apps/systemd-31 )
+	!systemd? ( app-admin/openrc-settingsd )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	app-text/iso-codes
+	x11-base/xorg-proto
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang meson_install_schemas.py
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use colord color)
+		$(meson_use modemmanager)
+		$(meson_use networkmanager)
+		$(meson_use gnome-online-accounts onlineaccounts)
+		$(meson_use input_devices_wacom wacom)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}