[gentoo-commits] repo/gentoo:master commit in: net-dialup/minicom/

["Sam James" <sam@gentoo.org>]

commit:     ead8a7a490a86bd6b80c47b529d5cf6632e4a205
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 17 05:47:35 2022 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Jan 17 05:47:59 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ead8a7a4

net-dialup/minicom: fix sysconfdir

Must be consistent with where we install the default config file.

Closes: https://bugs.gentoo.org/788142
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-dialup/minicom/minicom-2.8-r1.ebuild | 64 ++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/net-dialup/minicom/minicom-2.8-r1.ebuild b/net-dialup/minicom/minicom-2.8-r1.ebuild
new file mode 100644
index 000000000000..f9617802793f
--- /dev/null
+++ b/net-dialup/minicom/minicom-2.8-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Serial Communication Program"
+HOMEPAGE="https://salsa.debian.org/minicom-team/minicom"
+SRC_URI="https://salsa.debian.org/${PN}-team/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="nls"
+
+DEPEND="sys-libs/ncurses:="
+
+RDEPEND="
+	${DEPEND}
+	net-dialup/lrzsz
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.8-gentoo-runscript.patch
+	"${FILESDIR}"/${PN}-2.8-lockdir.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# Lockdir must exist if not manually specified.
+	# '/var/lock' is created by OpenRC.
+	local myeconfargs=(
+		# See bug #788142
+		--sysconfdir="${EPREFIX}"/etc/${PN}
+
+		--disable-rpath
+		--enable-lock-dir="/var/lock"
+		$(use_enable nls)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	# Needs to match --sysconfdir above
+	insinto /etc/minicom
+	doins "${FILESDIR}"/minirc.dfl
+}
+
+pkg_preinst() {
+	[[ -s "${EROOT}"/etc/minicom/minirc.dfl ]] && rm -f "${ED}"/etc/minicom/minirc.dfl
+}