[gentoo-commits] repo/gentoo:master commit in: dev-python/pillow/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     7c1bb06397f328afec57551a3365ad36d91ded2d
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 16 20:30:19 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sun Jan 16 20:30:19 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7c1bb063

dev-python/pillow: drop 8.4.0

Bug: https://bugs.gentoo.org/830934
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/pillow/Manifest            |  1 -
 dev-python/pillow/pillow-8.4.0.ebuild | 98 -----------------------------------
 2 files changed, 99 deletions(-)

diff --git a/dev-python/pillow/Manifest b/dev-python/pillow/Manifest
index d8c2375c69a0..cb676a730573 100644
--- a/dev-python/pillow/Manifest
+++ b/dev-python/pillow/Manifest
@@ -1,2 +1 @@
-DIST pillow-8.4.0.tar.gz 49364586 BLAKE2B f6a0fbafc0869c952bf88ad96146f27cf70c5680f372763bc9989cc49515bc74886a9d7648114797880ca06defc79e2e50d7ecf36bfa7adbd969450615ac0bd1 SHA512 d395f69ccb37c52a3b6f45836700ffbc3173afae31848cc61d7b47db88ca1594541023beb9a14fd9067aca664e182c7d6e3300ab3e3095c31afe8dcbc6e08233
 DIST pillow-9.0.0.tar.gz 49510604 BLAKE2B c3b0d07e8fe280e3a253067c4da18ac2dee40d216280632d58ddaa7848e13a165587b9aca61c98f8b5380e53d6d59a4097320bacf6e016e236239af518ec7780 SHA512 d2fd74dd1b8824d994e3767ef9794175dd2f4adc8173612432a3e171705723ee8757d299a87fb1c010b40919792c1ca76578f41977ee3303ccb6f75165deb791

diff --git a/dev-python/pillow/pillow-8.4.0.ebuild b/dev-python/pillow/pillow-8.4.0.ebuild
deleted file mode 100644
index 31930eb7c91d..000000000000
--- a/dev-python/pillow/pillow-8.4.0.ebuild
+++ /dev/null
@@ -1,98 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..10} pypy3 )
-PYTHON_REQ_USE='tk?,threads(+)'
-
-inherit distutils-r1 toolchain-funcs virtualx
-
-MY_PN=Pillow
-MY_P=${MY_PN}-${PV}
-
-DESCRIPTION="Python Imaging Library (fork)"
-HOMEPAGE="https://python-pillow.org/"
-SRC_URI="https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/${MY_P}"
-
-LICENSE="HPND"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
-IUSE="examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
-REQUIRED_USE="test? ( jpeg jpeg2k tiff truetype )"
-RESTRICT="!test? ( test )"
-
-DEPEND="
-	imagequant? ( media-gfx/libimagequant:0 )
-	jpeg? ( virtual/jpeg:0 )
-	jpeg2k? ( media-libs/openjpeg:2= )
-	lcms? ( media-libs/lcms:2= )
-	tiff? ( media-libs/tiff:0=[jpeg,zlib] )
-	truetype? ( media-libs/freetype:2= )
-	webp? ( media-libs/libwebp:0= )
-	xcb? ( x11-libs/libxcb )
-	zlib? ( sys-libs/zlib:0= )"
-RDEPEND="${DEPEND}
-	dev-python/olefile[${PYTHON_USEDEP}]"
-BDEPEND="
-	virtual/pkgconfig
-	test? (
-		${RDEPEND}
-		dev-python/pytest[${PYTHON_USEDEP}]
-		|| (
-			media-gfx/imagemagick[png]
-			media-gfx/graphicsmagick[png]
-		)
-	)
-"
-
-python_configure_all() {
-	# It's important that these flags are also passed during the install phase
-	# as well. Make sure of that if you change the lines below. See bug 661308.
-	DISTUTILS_ARGS=(
-		build_ext
-		--disable-platform-guessing
-		$(use_enable truetype freetype)
-		$(use_enable jpeg)
-		$(use_enable jpeg2k jpeg2000)
-		$(use_enable lcms)
-		$(use_enable tiff)
-		$(use_enable imagequant)
-		$(use_enable webp)
-		$(use_enable webp webpmux)
-		$(use_enable xcb)
-		$(use_enable zlib)
-	)
-
-	# setup.py sucks at adding the right toolchain paths but it does
-	# accept additional ones from INCLUDE and LIB so set these. You
-	# wouldn't normally need these at all as the toolchain should look
-	# here anyway but this setup.py does stupid things.
-	export \
-		INCLUDE=${ESYSROOT}/usr/include \
-		LIB=${ESYSROOT}/usr/$(get_libdir)
-
-	# We have patched in this env var.
-	tc-export PKG_CONFIG
-}
-
-python_test() {
-	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
-	# no:relaxed: pytest-relaxed plugin make our tests fail. deactivate if installed
-	virtx epytest -p no:relaxed
-}
-
-python_install() {
-	python_doheader src/libImaging/*.h
-	distutils-r1_python_install
-}
-
-python_install_all() {
-	if use examples ; then
-		docinto example
-		dodoc docs/example/*
-		docompress -x /usr/share/doc/${PF}/example
-	fi
-	distutils-r1_python_install_all
-}