[gentoo-commits] repo/gentoo:master commit in: games-emulation/higan/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     449c17df7acb237f57a519acb11b499303d9d9a3
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Jan 13 04:45:16 2022 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Jan 13 08:06:18 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=449c17df

games-emulation/higan: drop 116_pre20210404

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-emulation/higan/Manifest                     |   1 -
 games-emulation/higan/higan-116_pre20210404.ebuild | 106 ---------------------
 2 files changed, 107 deletions(-)

diff --git a/games-emulation/higan/Manifest b/games-emulation/higan/Manifest
index 8c4d29547d09..fc1ffb2a3c7a 100644
--- a/games-emulation/higan/Manifest
+++ b/games-emulation/higan/Manifest
@@ -1,2 +1 @@
-DIST higan-116_pre20210404.tar.gz 9130899 BLAKE2B bb9830901d7014f9d442f3a3bd9bd82ad791d2ba62a3264cfc187e5d7498a5ec6eae1fff6509f5206d9a21294e2a3ef710fbed5fac3626ecc88c4156bd50f289 SHA512 8ee40d8b9867fe767d5321dc4df3e73039fa39b7ecad2eddb58c3114bcf42b1b2074396ae5c4783ca060057aeb4bca7110101cc44d9608fe7c4d5f561b3f40a5
 DIST higan-116_pre20210818.tar.gz 9131284 BLAKE2B 4d3a514b9b8ec46353066b7257814c42024bff86c462b7a121aad5b5d1969d21cd7a96097e7d9d89d35e7a7f66a14c11a35cd77be05e73eca96caa3990e1c9b5 SHA512 d218feab3a3a39cd58fd2a727320ac88a4f006aa987c26860463f577039a9124b93119ee162f7d120f3bb4c23974eec53c7a0850c6e5743a8fdc8e48d108125d

diff --git a/games-emulation/higan/higan-116_pre20210404.ebuild b/games-emulation/higan/higan-116_pre20210404.ebuild
deleted file mode 100644
index 53899e2c610a..000000000000
--- a/games-emulation/higan/higan-116_pre20210404.ebuild
+++ /dev/null
@@ -1,106 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-COMMIT=9a625c545ca89b094d5c1da40bbfa5d07156a4aa
-
-inherit desktop toolchain-funcs xdg
-
-DESCRIPTION="Multi-system emulator focused on accuracy, preservation, and configurability"
-HOMEPAGE="https://github.com/higan-emu/higan"
-SRC_URI="https://github.com/higan-emu/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/${PN}-${COMMIT}"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="alsa ao +gtk openal +opengl oss +pulseaudio +sdl udev xv"
-
-RDEPEND="
-	x11-libs/libX11
-	x11-libs/libXext
-	alsa? ( media-libs/alsa-lib )
-	ao? ( media-libs/libao )
-	openal? ( media-libs/openal )
-	opengl? ( virtual/opengl )
-	pulseaudio? ( media-sound/pulseaudio )
-	sdl? ( media-libs/libsdl2[joystick] )
-	udev? ( virtual/udev )
-	xv? ( x11-libs/libXv )
-	gtk? (
-		x11-libs/cairo
-		x11-libs/gtk+:3
-		x11-libs/gtksourceview:3.0
-	)
-	!gtk? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtwidgets:5
-	)"
-DEPEND="${RDEPEND}"
-BDEPEND="virtual/pkgconfig"
-
-PATCHES=(
-	# insane build system, reinvents every built-in rule
-	"${FILESDIR}"/${P}-makefile.patch
-)
-
-src_compile() {
-	local makeopts=(
-		platform=linux
-		compiler="$(tc-getCXX)"
-		hiro="$(usex gtk gtk3 qt5)"
-	)
-
-	local drivers=(
-		video.xshm
-		input.xlib
-		$(usex alsa audio.alsa "")
-		$(usex ao audio.ao "")
-		$(usex openal audio.openal "")
-		$(usex opengl "video.glx video.glx2" "")
-		$(usex oss audio.oss "")
-		$(usex pulseaudio "audio.pulseaudio audio.pulseaudiosimple" "")
-		$(usex sdl input.sdl "")
-		$(usex udev input.udev "")
-		$(usex xv video.xvideo "")
-	)
-
-	local coreopts=(
-		cores="cv fc gb gba md ms msx ngp pce sfc sg ws"
-		ruby="${drivers[*]}"
-		build=performance
-		local=false
-	)
-
-	# Make higan
-	emake "${makeopts[@]}" "${coreopts[@]}" -C higan-ui
-
-	# Make icarus
-	emake "${makeopts[@]}" -C icarus
-}
-
-src_install() {
-	# Install higan
-	dobin higan-ui/out/higan
-
-	insinto /usr/share/${P}
-	doins -r higan/System
-
-	domenu higan-ui/resource/higan.desktop
-	doicon -s 256 higan-ui/resource/higan.png
-
-	doins -r extras
-
-	# Install icarus
-	dobin icarus/out/icarus
-
-	domenu icarus/resource/icarus.desktop
-	doicon -s scalable icarus/resource/icarus.svg
-
-	insinto /usr/share/${P}/Database
-	doins -r icarus/Database
-	insinto /usr/share/${P}/Firmware
-	doins -r icarus/Firmware
-}