[gentoo-commits] repo/gentoo:master commit in: dev-util/rizin/

["John Helmert III" <ajak@gentoo.org>]

commit:     cd5e6576a7852a0436a0ce47aa26b8345f145a99
Author:     John Helmert III <ajak <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 10 06:02:46 2022 +0000
Commit:     John Helmert III <ajak <AT> gentoo <DOT> org>
CommitDate: Mon Jan 10 06:10:23 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cd5e6576

dev-util/rizin: add 0.3.4

Signed-off-by: John Helmert III <ajak <AT> gentoo.org>

 dev-util/rizin/Manifest           |   1 +
 dev-util/rizin/rizin-0.3.4.ebuild | 103 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 104 insertions(+)

diff --git a/dev-util/rizin/Manifest b/dev-util/rizin/Manifest
index 73cb41299bc5..8a3a8efbb804 100644
--- a/dev-util/rizin/Manifest
+++ b/dev-util/rizin/Manifest
@@ -1,5 +1,6 @@
 DIST rizin-src-v0.3.1.tar.xz 64089580 BLAKE2B 04f7e3cfa20a787f47af90c78405f295b346cc0c7d81164ff01bc6a69df526f3f9112ab4cb62092297ae2dda1fa738a2e7feff35e0f1b7f3e7467a8c6e4d1a1e SHA512 743f8f2c9ddb045f39147de9ad971d47f1a26bfcc233f41c12c64ade5e31c992104cf3f93c44c5035142b554779e895224b68f839cd87a59aaf344b4ec88d5fe
 DIST rizin-src-v0.3.2.tar.xz 64170200 BLAKE2B fe11317e4acc1a803323f42fd4c2c6435a2fe4032581ed509f37f7221ec53e0afac04ebe8cb9da693ac283b61c0a70e135007d635c4c5010519a5c7e7cfa19cf SHA512 c472770ee1b156d42a98d4641f365e2255f16489b2223b117c8b88dcac0d72065d1fd7eedad70046188231889e492bafb7b8462987c68311143f14808eaab1cc
 DIST rizin-src-v0.3.3.tar.xz 10409328 BLAKE2B 4d62ecbcabf960a0f8363ff5f8cc75911bb52ca15d7e7d0a6a78e754910d9607264086e8b0c28cd1423525b650443ab99a090624c8d2b7a376fbc8f71baa03b0 SHA512 4aca0a06be80434b61a92479588c92d32598b8eebb24a82acbc7e6c7b26fdde638b8dfa5b66afbd6cd369329f9514594595bab9314de92b8b2580d129543882d
+DIST rizin-src-v0.3.4.tar.xz 10411432 BLAKE2B 99745f069e6bd72aec6a6f335f3aa0ccc46ebf186b1dc0aaf32b4f95d2be4bb49e8d3d976a72978c22fce82d896e70bf8403568e100b73898731045ef06a2ad5 SHA512 cda35afe8c031f3207c055ed31d7f76a46b7addd04cead0f5aadf0733b66f4dd953ca16f054b47da7921d4726d6ea1250436012954a9755c1cd524a8fd0d670c
 DIST rizin-testbins-aa6a88dcdfaad54335e3935c16ce21a124ff861d.tar.gz 127254454 BLAKE2B e7a4536be7169abd197c2128e103b8d669fbb7532ce265b27da3ce347b1aa58c8a96c95d85cf7700f66a44c041a0575175de3a0e176a0d31c490f7ccfb2f6d6b SHA512 20cf299e5324793f07f8a2fdcfa3d66c3a418f09bfc6a272e35ab31d4a64408bf91532ae431098dede1a2d0ad0b1c02433304c514816d98dc068f6c0528a4099
 DIST rizin-testbins-d66fa0feaf3b1ecdad261ca17542f1d5d0b101cc.tar.gz 126773703 BLAKE2B f5eaeb7e99e9091b6ca043dd50d03143950adc06b75b5834886d96d6280207c0bea73101a5f9e06c38ba60c0d4cff82dbf1f00364f7d87fe183c0687b06d1904 SHA512 0a017954017c8d57133d51b441411a50aa9ed062c0cc61e1561951fdf0703f5244230cda377885199e9e35dca6780d8582a445ac92286b63ef2ac784777ec0c4

diff --git a/dev-util/rizin/rizin-0.3.4.ebuild b/dev-util/rizin/rizin-0.3.4.ebuild
new file mode 100644
index 000000000000..b4bfee6c1042
--- /dev/null
+++ b/dev-util/rizin/rizin-0.3.4.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=(python3_{8,9,10})
+
+# This is the commit that the CI for the release commit used
+BINS_COMMIT="aa6a88dcdfaad54335e3935c16ce21a124ff861d"
+
+inherit meson python-any-r1
+
+DESCRIPTION="reverse engineering framework for binary analysis"
+HOMEPAGE="https://rizin.re/"
+
+SRC_URI="mirror+https://github.com/rizinorg/rizin/releases/download/v${PV}/rizin-src-v${PV}.tar.xz
+	test? ( https://github.com/rizinorg/rizin-testbins/archive/${BINS_COMMIT}.tar.gz -> rizin-testbins-${BINS_COMMIT}.tar.gz )"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+LICENSE="Apache-2.0 BSD LGPL-3 MIT"
+SLOT="0/${PV}"
+IUSE="test"
+
+# Need to audit licenses of the binaries used for testing
+RESTRICT="fetch !test? ( test )"
+
+RDEPEND="
+	sys-apps/file
+	app-arch/lz4:0=
+	dev-libs/capstone:0=
+	dev-libs/libuv:0=
+	dev-libs/libzip:0=
+	dev-libs/openssl:0=
+	>=dev-libs/tree-sitter-0.19.0
+	dev-libs/xxhash
+	sys-libs/zlib:0=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.3.0-typedb-prefix.patch"
+	"${FILESDIR}/${PN}-0.3.2-never-rebuild-parser.patch"
+)
+
+S="${WORKDIR}/${PN}-v${PV}"
+
+src_prepare() {
+	default
+
+	local py_to_mangle=(
+		librz/core/cmd_descs/cmd_descs_generate.py
+		subprojects/lz4-1.9.3/contrib/meson/meson/GetLz4LibraryVersion.py
+		subprojects/lz4-1.9.3/contrib/meson/meson/InstallSymlink.py
+		subprojects/lz4-1.9.3/tests/test-lz4-list.py
+		subprojects/lz4-1.9.3/tests/test-lz4-speed.py
+		subprojects/lz4-1.9.3/tests/test-lz4-versions.py
+		sys/clang-format.py
+		test/fuzz/scripts/fuzz_rz_asm.py
+		test/scripts/gdbserver.py
+	)
+
+	python_fix_shebang "${py_to_mangle[@]}"
+
+	if use test; then
+		cp -r "${WORKDIR}/rizin-testbins-${BINS_COMMIT}" "${S}/test/bins" || die
+		cp -r "${WORKDIR}/rizin-testbins-${BINS_COMMIT}" "${S}" || die
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcli=enabled
+		-Duse_sys_capstone=enabled
+		-Duse_sys_magic=enabled
+		-Duse_sys_libzip=enabled
+		-Duse_sys_zlib=enabled
+		-Duse_sys_lz4=enabled
+		-Duse_sys_xxhash=enabled
+		-Duse_sys_openssl=enabled
+		-Duse_sys_tree_sitter=enabled
+
+		$(meson_use test enable_tests)
+		$(meson_use test enable_rz_test)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Rizin uses data files that it expects to be installed on the
+	# system. To hack around this, we create a tree of what it expects
+	# in ${T}, and patch the tests to support a prefix from the
+	# environment. https://github.com/rizinorg/rizin/issues/1789
+	mkdir -p "${T}/usr/share/${PN}/${PV}" || die
+	ln -sf "${BUILD_DIR}/librz/analysis/d" "${T}/usr/share/${PN}/${PV}/types" || die
+	ln -sf "${BUILD_DIR}/librz/syscall/d" "${T}/usr/share/${PN}/${PV}/syscall" || die
+	ln -sf "${BUILD_DIR}/librz/asm/d" "${T}/usr/share/${PN}/${PV}/opcodes" || die
+	# https://github.com/rizinorg/rizin/issues/1797
+	ln -sf "${BUILD_DIR}/librz/flag/d" "${T}/usr/share/${PN}/${PV}/flag" || die
+	export RZ_PREFIX="${T}/usr"
+
+	meson_src_test
+}