[gentoo-commits] repo/gentoo:master commit in: dev-python/dulwich/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     975ad5c29c391a7f59b34ac7a7958a528fbd9275
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  5 07:46:51 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Wed Jan  5 08:45:57 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=975ad5c2

dev-python/dulwich: add 0.20.27

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/dulwich/Manifest               |  1 +
 dev-python/dulwich/dulwich-0.20.27.ebuild | 55 +++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/dev-python/dulwich/Manifest b/dev-python/dulwich/Manifest
index dc48a6c23dfa..558675fffec1 100644
--- a/dev-python/dulwich/Manifest
+++ b/dev-python/dulwich/Manifest
@@ -1 +1,2 @@
 DIST dulwich-0.20.23.tar.gz 414150 BLAKE2B 0f7bfb237acc6bad874465a5bfed21adc29a2ef23875fbcbb92e7e3ff0ed6a4191a30b3975f90ef20b8320575e42abf31f8ec2199d558382c917d0510c2a8d96 SHA512 8bad3528dc87e70b39b59b2f7218579327db4dbd15937b63db76c9b8e7ba6d22e963eaec45b8d675c92f250516a541c395fdac391db68d0932dc5d8cd7ed9fb9
+DIST dulwich-0.20.27.tar.gz 416618 BLAKE2B 73ed04d9fc871a82126e212bdac0eaf235e44aa76f3e54c98bd50f71379fdd3082b2a3af12a22f3276a45909ef17e38a116deb6adfd650cdbfa19afa41803dd1 SHA512 dc82250c5b3cbccc1ccbb55ca2d871f4d17ddb3616cd92146468fc5f0d805d3fe349b2cedfb4e814e027c07f9352e87c72ca7e97ed6218aa621fa9311dc075c5

diff --git a/dev-python/dulwich/dulwich-0.20.27.ebuild b/dev-python/dulwich/dulwich-0.20.27.ebuild
new file mode 100644
index 000000000000..e282dc27d571
--- /dev/null
+++ b/dev-python/dulwich/dulwich-0.20.27.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python implementation of the Git file formats and protocols"
+HOMEPAGE="
+	https://github.com/dulwich/dulwich/
+	https://pypi.org/project/dulwich/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+ Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		!hppa? ( !ia64? (
+			dev-python/gevent[${PYTHON_USEDEP}]
+			dev-python/geventhttpclient[${PYTHON_USEDEP}]
+		) )
+		app-crypt/gpgme[python,${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/fastimport[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs
+
+python_test() {
+	# remove interference from the tests that do stuff like user.name
+	unset GIT_AUTHOR_NAME GIT_AUTHOR_EMAIL GIT_AUTHOR_DATE \
+		GIT_COMMITTER_NAME GIT_COMMITTER_EMAIL GIT_COMMITTER_DATE EMAIL
+	# Do not use make check which rebuilds the extension and uses -Werror,
+	# causing unexpected failures.
+	"${EPYTHON}" -m unittest -v dulwich.tests.test_suite \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		dodoc -r examples
+	fi
+	distutils-r1_python_install_all
+}