[gentoo-commits] repo/gentoo:master commit in: dev-scheme/cyclone/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     65cd25afaccc72d85a4a399f7d69e142f3e49120
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  3 18:21:58 2022 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon Jan  3 18:22:45 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=65cd25af

dev-scheme/cyclone: bump to 0.34.0

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 dev-scheme/cyclone/Manifest              |  1 +
 dev-scheme/cyclone/cyclone-0.34.0.ebuild | 55 ++++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/dev-scheme/cyclone/Manifest b/dev-scheme/cyclone/Manifest
index 4d230a99c9dd..5cfb186e2a3d 100644
--- a/dev-scheme/cyclone/Manifest
+++ b/dev-scheme/cyclone/Manifest
@@ -1 +1,2 @@
 DIST cyclone-0.33.0.tar.gz 3946573 BLAKE2B 7eba62995ef3d327e14d6fbcf433d40e73c244508f8858d636a3a3fd05660e2921055932dedbe50ce8b384e9a9b44a09112aca6f851af6cd38b9b372769b2adc SHA512 96ffd3d04636b27f36c98920359a9f880c4b2a15e9820e5d91c82f821dc93357b665537e7688b00510d6a4fd113666edbd5ec109ff491f4f18d547129527b763
+DIST cyclone-0.34.0.tar.gz 3947685 BLAKE2B db86669bda00c89cee0d6b9224e7cb407961e6c7a8ccc0743a655966da16c8a06516c481ae75cb609053a9622fafcbb47bcc9f53226f3842a0abcde19eb86c3b SHA512 581866985709bff90a4f4fab9a24fc013ee43225b04fb2bd1128da02f0164de55f6d7d80d5cfcff5eedaf23b3fc38dc3c46e6f376e2f341b4991a3f1c54cd53b

diff --git a/dev-scheme/cyclone/cyclone-0.34.0.ebuild b/dev-scheme/cyclone/cyclone-0.34.0.ebuild
new file mode 100644
index 000000000000..a60d8cdc7056
--- /dev/null
+++ b/dev-scheme/cyclone/cyclone-0.34.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Cyclone is a self-hosting Scheme to C compiler
+# cyclone-bootstrap is the Cyclone SOURCE transpiled by it to C
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="R7RS Scheme to C compiler"
+HOMEPAGE="http://justinethier.github.io/cyclone/"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/justinethier/${PN}-bootstrap.git"
+else
+	SRC_URI="https://github.com/justinethier/${PN}-bootstrap/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-bootstrap-${PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="dev-libs/concurrencykit"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	export CYC_GCC_OPT_FLAGS="${CFLAGS}"
+	append-cflags -fPIC -Iinclude
+	append-ldflags -L.
+	tc-export AR CC RANLIB
+}
+
+src_compile() {
+	local myopts=(
+		PREFIX="/usr"
+		CYC_GCC_OPT_FLAGS="${CYC_GCC_OPT_FLAGS}"
+		AR="$(tc-getAR)"
+		CC="$(tc-getCC)"
+		RANLIB="$(tc-getRANLIB)"
+	)
+	emake "${myopts[@]}"
+}
+
+src_test() {
+	emake LDFLAGS="" test
+}
+
+src_install() {
+	einstalldocs
+
+	emake PREFIX="/usr" DESTDIR="${D}" install
+}