[gentoo-commits] repo/gentoo:master commit in: dev-libs/leveldb/

["Arthur Zamarin" <arthurzam@gentoo.org>]

commit:     6f08888b9077ab113eff4c786b3b89c992334bf0
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 31 16:09:13 2021 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Fri Dec 31 16:09:13 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6f08888b

dev-libs/leveldb: enable RTTI for consumers

needed for ceph and plyvel and possibly other consumers
Arch Linux also enables it

https://github.com/google/leveldb/issues/731

Reported-by: Louis Sautier <sbraz <AT> gentoo.org>
Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-libs/leveldb/leveldb-1.23-r2.ebuild | 42 +++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/dev-libs/leveldb/leveldb-1.23-r2.ebuild b/dev-libs/leveldb/leveldb-1.23-r2.ebuild
new file mode 100644
index 000000000000..a245acc26713
--- /dev/null
+++ b/dev-libs/leveldb/leveldb-1.23-r2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A fast key-value storage library written at Google"
+HOMEPAGE="https://github.com/google/leveldb"
+SRC_URI="https://github.com/google/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+crc32c +snappy +tcmalloc test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="crc32c? ( dev-libs/crc32c )
+	snappy? ( app-arch/snappy )
+	tcmalloc? ( dev-util/google-perftools )"
+RDEPEND="${DEPEND}"
+BDEPEND="test? ( dev-cpp/gtest )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.23-system-testdeps.patch
+	"${FILESDIR}"/${PN}-1.23-remove-benchmark-dep.patch
+)
+
+src_prepare() {
+	sed -e '/fno-rtti/d' -i CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DLEVELDB_BUILD_BENCHMARKS=OFF
+		-DLEVELDB_BUILD_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}