[gentoo-commits] repo/gentoo:master commit in: kde-frameworks/kimageformats/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     3996d9fbec7246e80d83c23418a6885c22be53ab
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 20 13:43:35 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Dec 20 15:18:41 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3996d9fb

kde-frameworks/kimageformats: Switch to media-libs/openexr:3=

Now that stable versions of media-libs/openexr:3 are available, switch
to unconditionally depend on the new slot instead of trying to support
both, involving a messy alternative dependency declaration with
media-libs/ilmbase.

See also: https://github.com/gentoo/gentoo/pull/20930

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../kimageformats/kimageformats-5.89.0-r1.ebuild   | 39 ++++++++++++++++++++++
 1 file changed, 39 insertions(+)

diff --git a/kde-frameworks/kimageformats/kimageformats-5.89.0-r1.ebuild b/kde-frameworks/kimageformats/kimageformats-5.89.0-r1.ebuild
new file mode 100644
index 000000000000..633db4591250
--- /dev/null
+++ b/kde-frameworks/kimageformats/kimageformats-5.89.0-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="false"
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Framework providing additional format plugins for Qt's image I/O system"
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="avif eps heif openexr"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	=kde-frameworks/karchive-${PVCUT}*:5
+	avif? ( >=media-libs/libavif-0.8.2:= )
+	eps? ( >=dev-qt/qtprintsupport-${QTMIN}:5 )
+	heif? ( >=media-libs/libheif-1.10.0:= )
+	openexr? ( media-libs/openexr:3= )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( src/imageformats/AUTHORS )
+
+src_configure() {
+	local mycmakeargs=(
+		-DKIMAGEFORMATS_JXL=OFF # TODO: libjxl not packaged yet
+		$(cmake_use_find_package avif libavif)
+		$(cmake_use_find_package eps Qt5PrintSupport)
+		-DKIMAGEFORMATS_HEIF=$(usex heif)
+		$(cmake_use_find_package openexr OpenEXR)
+	)
+
+	ecm_src_configure
+}