From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1350969-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 4567C158086
for <garchives@archives.gentoo.org>; Sun, 19 Dec 2021 04:53:24 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id B01F9E07D1;
Sun, 19 Dec 2021 04:53:18 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 2B0BCE07C7
for <gentoo-commits@lists.gentoo.org>; Sun, 19 Dec 2021 04:53:18 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id DC8DF343147
for <gentoo-commits@lists.gentoo.org>; Sun, 19 Dec 2021 04:53:16 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 0B0AD261
for <gentoo-commits@lists.gentoo.org>; Sun, 19 Dec 2021 04:53:14 +0000 (UTC)
From: "Matt Turner" <mattst88@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Matt Turner" <mattst88@gentoo.org>
Message-ID: <1639889585.282d191ddca3e9cccb6c5ed0c798e1e3feb44124.mattst88@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-settings-daemon/
X-VCS-Repository: repo/gentoo
X-VCS-Files: gnome-base/gnome-settings-daemon/Manifest gnome-base/gnome-settings-daemon/gnome-settings-daemon-41.0.ebuild
X-VCS-Directories: gnome-base/gnome-settings-daemon/
X-VCS-Committer: mattst88
X-VCS-Committer-Name: Matt Turner
X-VCS-Revision: 282d191ddca3e9cccb6c5ed0c798e1e3feb44124
X-VCS-Branch: master
Date: Sun, 19 Dec 2021 04:53:14 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: d8ebeff5-8ddd-4c90-b378-910d02c08f54
X-Archives-Hash: 10fa2d89b2cfe464965b5a0f879a2cbd
commit: 282d191ddca3e9cccb6c5ed0c798e1e3feb44124
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 19 04:08:00 2021 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Dec 19 04:53:05 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=282d191d
gnome-base/gnome-settings-daemon: Version bump to 41.0
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
gnome-base/gnome-settings-daemon/Manifest | 1 +
.../gnome-settings-daemon-41.0.ebuild | 147 +++++++++++++++++++++
2 files changed, 148 insertions(+)
diff --git a/gnome-base/gnome-settings-daemon/Manifest b/gnome-base/gnome-settings-daemon/Manifest
index 69056205c197..c6fd482bd5da 100644
--- a/gnome-base/gnome-settings-daemon/Manifest
+++ b/gnome-base/gnome-settings-daemon/Manifest
@@ -1 +1,2 @@
DIST gnome-settings-daemon-40.0.1.tar.xz 1443100 BLAKE2B 2615165e4b33b3ae4f9ceac73fdd298ad5288b5de03424ade70a0dfd64b7349ae759138c0c930ba4c78ff70ed52389b2f0a996333234755f793dc114870d2460 SHA512 d5b7235e097baded66cbbc2c4f05effcac722daa09413f495368555ad97830746415c4c8f1ecfe54dac262f3b75ab1a83863dc4b736b9854dcf86c94c14edd79
+DIST gnome-settings-daemon-41.0.tar.xz 1477876 BLAKE2B f17005b03cbee142434f0805e8f590d6d9edad0f09b3226bb40ab7e312ee13bcd46c211efb140303d4a351d8818238a28bd9aa3fe760fb617fb006e97eebde61 SHA512 2c6848a749f84fd0c3a9ade6f4a83ae3ff7464da429b2d73030c9dcbd278b070c40475c678c819e31464941f2bd38d81f11b96f24d0d1fb05271267c3a1ecc2a
diff --git a/gnome-base/gnome-settings-daemon/gnome-settings-daemon-41.0.ebuild b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-41.0.ebuild
new file mode 100644
index 000000000000..56a055786391
--- /dev/null
+++ b/gnome-base/gnome-settings-daemon/gnome-settings-daemon-41.0.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit gnome.org gnome2-utils python-any-r1 meson udev virtualx xdg
+
+DESCRIPTION="Gnome Settings Daemon"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+IUSE="+colord +cups debug elogind input_devices_wacom modemmanager networkmanager smartcard systemd test +udev wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+ ^^ ( elogind systemd )
+ input_devices_wacom? ( udev )
+ wayland? ( udev )
+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+DEPEND="
+ >=sci-geosciences/geocode-glib-3.10
+ >=dev-libs/glib-2.58:2
+ >=gnome-base/gnome-desktop-3.37.1:3=
+ >=gnome-base/gsettings-desktop-schemas-40
+ >=x11-libs/gtk+-3.15.3:3[X,wayland?]
+ >=dev-libs/libgweather-40:2=
+ colord? (
+ >=x11-misc/colord-1.4.5:=
+ >=media-libs/lcms-2.2:2
+ )
+ media-libs/libcanberra[gtk3]
+ >=app-misc/geoclue-2.3.1:2.0
+ >=x11-libs/libnotify-0.7.3
+ >=media-sound/pulseaudio-2[glib]
+ >=sys-auth/polkit-0.114
+ >=sys-power/upower-0.99.8:=
+ x11-libs/libX11
+ >=x11-libs/libXfixes-6.0.0
+ udev? ( dev-libs/libgudev:= )
+ wayland? ( dev-libs/wayland )
+ input_devices_wacom? (
+ >=dev-libs/libwacom-0.7
+ >=x11-libs/pango-1.20.0
+ x11-libs/gdk-pixbuf:2
+ )
+ smartcard? ( >=dev-libs/nss-3.11.2 )
+ cups? ( >=net-print/cups-1.4[dbus] )
+ modemmanager? (
+ >=app-crypt/gcr-3.7.5:=
+ >=net-misc/modemmanager-1.0:=
+ )
+ networkmanager? ( >=net-misc/networkmanager-1.0 )
+ media-libs/alsa-lib
+ x11-libs/libXi
+ x11-libs/libXext
+ media-libs/fontconfig
+ systemd? (
+ >=sys-apps/systemd-243
+ )
+"
+# logind needed for power and session management, bug #464944
+# gnome-session-3.33.90/gdm-3.33.90/gnome-shell-extensions-3.34.1/gnome-flashback-3.33.1 adapt to Clipboard and Mouse component removals (moved to mutter)
+RDEPEND="${DEPEND}
+ gnome-base/dconf
+ elogind? ( sys-auth/elogind )
+ !<gnome-base/gnome-session-3.33.90
+ !<gnome-base/gdm-3.33.90
+ !<gnome-extra/gnome-shell-extensions-3.34.1
+ !<gnome-base/gnome-flashback-3.33.1
+"
+# rfkill requires linux/rfkill.h (and USE=udev), thus linux-headers dep, not os-headers. If this package wants to work on other kernels, we need to make rfkill conditional instead
+BDEPEND="
+ sys-kernel/linux-headers
+ dev-util/glib-utils
+ dev-util/gdbus-codegen
+ x11-base/xorg-proto
+ ${PYTHON_DEPS}
+ test? (
+ $(python_gen_any_dep '
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ dev-python/python-dbusmock[${PYTHON_USEDEP}]
+ ')
+ gnome-base/gnome-session
+ )
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.38.1-build-Make-colord-and-wacom-optional-and-controllabl.patch
+ "${FILESDIR}"/${PN}-3.38.1-build-Allow-NM-optional-on-Linux.patch
+ "${FILESDIR}"/${PN}-3.38.1-Allow-udev-optional-on-Linux.patch
+)
+
+python_check_deps() {
+ if use test; then
+ has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" &&
+ has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+ fi
+}
+
+pkg_setup() {
+ python-any-r1_pkg_setup
+}
+
+src_configure() {
+ local emesonargs=(
+ #-Dnssdb_dir # TODO: Is the default /etc/pki/nssdb path correct for our nss?
+ -Dudev_dir="$(get_udevdir)"
+ $(meson_use systemd)
+ -Dalsa=true
+ $(meson_use udev gudev)
+ $(meson_use colord)
+ $(meson_use cups)
+ $(meson_use networkmanager network_manager)
+ $(meson_use udev rfkill)
+ $(meson_use smartcard)
+ $(meson_use input_devices_wacom wacom)
+ $(meson_use wayland)
+ $(meson_use modemmanager wwan)
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ # Don't auto-suspend by default on AC power
+ insinto /usr/share/glib-2.0/schemas
+ doins "${FILESDIR}"/org.gnome.settings-daemon.plugins.power.gschema.override
+}
+
+src_test() {
+ virtx meson_src_test
+}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}