[gentoo-commits] repo/gentoo:master commit in: dev-libs/libdazzle/

["Matt Turner" <mattst88@gentoo.org>]

commit:     cde065a2460749adb0986cd2b759d55359b1c948
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 18 22:47:15 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Dec 18 23:39:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cde065a2

dev-libs/libdazzle: Version bump to 3.42.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-libs/libdazzle/Manifest                |  1 +
 dev-libs/libdazzle/libdazzle-3.42.0.ebuild | 61 ++++++++++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/dev-libs/libdazzle/Manifest b/dev-libs/libdazzle/Manifest
index d7abcd081029..3b76c88f08d0 100644
--- a/dev-libs/libdazzle/Manifest
+++ b/dev-libs/libdazzle/Manifest
@@ -1 +1,2 @@
 DIST libdazzle-3.40.0.tar.xz 447648 BLAKE2B fb7916fd7812c03ec63bc804974574bbf6d029596e8364f5f13cde22be330a9356ee250c0d5bfc8742545d410c94b1ad7a1fa0bd5e2f473f67d6c45fe55e8e93 SHA512 23bf0a176fb847ee46a22a96594e9ed60921f104875fd102375445f364b552167778a56dd4929a18b2a7bee1144fd5e07d5cadac3355ac4877cd56838cb5deb2
+DIST libdazzle-3.42.0.tar.xz 450636 BLAKE2B 0a77a9ceeca2af8a001b75dbffa04cd385be89d9fac898e6b90111d240b409a54357d9668ca33e494dbb0ed932f16605f363aa69b92c548981be0db971b67dfe SHA512 db6ac54deba034627726747b8c15472aa2f640617473825698e23ca6527d5b69e9103dd82141e82b7dd7fa8bd57eadf054cdd300d46e1b65ced0fffcbc55a301

diff --git a/dev-libs/libdazzle/libdazzle-3.42.0.ebuild b/dev-libs/libdazzle/libdazzle-3.42.0.ebuild
new file mode 100644
index 000000000000..0bed8faf85a5
--- /dev/null
+++ b/dev-libs/libdazzle/libdazzle-3.42.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org meson xdg vala virtualx
+
+DESCRIPTION="Experimental new features for GTK+ and GLib"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdazzle"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="gtk-doc +introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+# We keep newer glib/gtk+ deps to avoid GtkEventControllerMotion backports gettings used
+RDEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=x11-libs/gtk+-3.24.0:3[introspection?]
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="${RDEPEND}"
+# libxml2 required for glib-compile-resources; glib-utils for glib-mkenums
+BDEPEND="
+	>=dev-util/meson-0.49.0
+	vala? ( $(vala_depend) )
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable_tracing=false # extra trace debugging that would make things slower
+		-Denable_profiling=false # -pg passing
+		# On linux it'll always use a vdso based implementation that is even faster
+		# than rdtscp insn, thus never build with rdtscp until we don't support non-linux
+		# as the rdtscp using function will never get called anyways.
+		-Denable_rdtscp=false
+		-Denable_tools=true # /usr/bin/dazzle-list-counters
+		$(meson_use introspection with_introspection)
+		$(meson_use vala with_vapi)
+		$(meson_use gtk-doc enable_gtk_doc)
+		$(meson_use test enable_tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}