[gentoo-commits] repo/gentoo:master commit in: media-sound/kid3/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     fa7c41c62eeec67c3fc5d8470ace451214ce68cc
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 18 16:21:35 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Dec 18 16:54:34 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fa7c41c6

media-sound/kid3: 3.9.0 version bump

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-sound/kid3/Manifest          |   1 +
 media-sound/kid3/kid3-3.9.0.ebuild | 100 +++++++++++++++++++++++++++++++++++++
 2 files changed, 101 insertions(+)

diff --git a/media-sound/kid3/Manifest b/media-sound/kid3/Manifest
index e839151be4c8..a8195ad7129e 100644
--- a/media-sound/kid3/Manifest
+++ b/media-sound/kid3/Manifest
@@ -1 +1,2 @@
 DIST kid3-3.8.7.tar.gz 3356781 BLAKE2B 967a7af8f3ca5413716b1f246d07fa1723f57113369f466f853c00106e81648efb19c54abbb27b802ca9dae308c44683764356ebbbc708c7454e9669ae0201f4 SHA512 9d1a2c64d05e19c7a8c33f5447f896043ffd68ec95387dc04502549d59cb0398dd6946d17bfce12ed57ea445e0b39c8b3769918069ee9f1862f2480482bf2a01
+DIST kid3-3.9.0.tar.xz 1778964 BLAKE2B 946d4bed60de8774460d26d54de69df6a208e4a0eb25f5d7f54a66c31716a4ba479d1a75979f2febb9a398c5a1429d1822230dad7d9eed77e3e5c912c65fb1c3 SHA512 276a1e564b82cb2091008a8a532fc2b86a522ac3a5d83e8388b22c1172d88422555cb330ab51037e04d674dfb172f994d2494d4f6527b5c9ab635346531b4f7c

diff --git a/media-sound/kid3/kid3-3.9.0.ebuild b/media-sound/kid3/kid3-3.9.0.ebuild
new file mode 100644
index 000000000000..417c35f22d21
--- /dev/null
+++ b/media-sound/kid3/kid3-3.9.0.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake kde.org python-any-r1 xdg
+
+DESCRIPTION="Simple tag editor based on Qt"
+HOMEPAGE="https://kid3.kde.org/"
+
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+"
+SLOT="5"
+IUSE="acoustid flac kde mp3 mp4 +mpris +taglib test vorbis"
+
+REQUIRED_USE="flac? ( vorbis )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-libs/readline:0=
+	acoustid? (
+		media-libs/chromaprint
+		media-video/ffmpeg
+	)
+	flac? (
+		media-libs/flac[cxx]
+		media-libs/libvorbis
+	)
+	kde? (
+		kde-frameworks/kconfig:5
+		kde-frameworks/kconfigwidgets:5
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+		kde-frameworks/kwidgetsaddons:5
+		kde-frameworks/kxmlgui:5
+	)
+	mp3? ( media-libs/id3lib )
+	mp4? ( media-libs/libmp4v2:0 )
+	mpris? ( dev-qt/qtdbus:5 )
+	taglib? ( >=media-libs/taglib-1.9.1 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+"
+BDEPEND="${PYTHON_DEPS}
+	dev-qt/linguist-tools:5
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# overengineered upstream build system
+	cmake_src_prepare
+	# applies broken python hacks, bug #614950
+	cmake_comment_add_subdirectory doc
+
+	sed -e "/^find_package.*QT NAMES/s/Qt6 //" \
+		-i CMakeLists.txt || die # ensure Qt5 build
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DWITH_CHROMAPRINT=$(usex acoustid)
+		-DWITH_DBUS=$(usex mpris)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_ID3LIB=$(usex mp3)
+		-DWITH_MP4V2=$(usex mp4)
+		-DWITH_TAGLIB=$(usex taglib)
+		-DBUILD_TESTING=$(usex test)
+		-DWITH_VORBIS=$(usex vorbis)
+	)
+
+	if use kde ; then
+		mycmakeargs+=( "-DWITH_APPS=KDE;CLI" )
+	else
+		mycmakeargs+=( "-DWITH_APPS=Qt;CLI" )
+	fi
+
+	cmake_src_configure
+}