[gentoo-commits] repo/gentoo:master commit in: sci-chemistry/gnome-chemistry-utils/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     1250be122d5f8d1a3787d94e4b99b7ac3da7713c
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu Dec 16 18:22:18 2021 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Dec 16 18:22:49 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1250be12

sci-chemistry/gnome-chemistry-utils: Fix compat with openbabel

Bump eapi too

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 .../gnome-chemistry-utils-0.14.17_p6-r1.ebuild     | 76 ++++++++++++++++++++++
 1 file changed, 76 insertions(+)

diff --git a/sci-chemistry/gnome-chemistry-utils/gnome-chemistry-utils-0.14.17_p6-r1.ebuild b/sci-chemistry/gnome-chemistry-utils/gnome-chemistry-utils-0.14.17_p6-r1.ebuild
new file mode 100644
index 000000000000..28d4cf3e6b85
--- /dev/null
+++ b/sci-chemistry/gnome-chemistry-utils/gnome-chemistry-utils-0.14.17_p6-r1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic xdg
+
+DESCRIPTION="Programs and library containing GTK widgets and C++ classes related to chemistry"
+HOMEPAGE="http://gchemutils.nongnu.org/"
+SRC_URI="
+	http://download.savannah.gnu.org/releases/gchemutils/$(ver_cut 1-2)/${P/_p*}.tar.xz
+	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV/_p*}-${PV/*_p}.debian.tar.xz
+"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-3"
+IUSE="gnumeric"
+
+RDEPEND="
+	>=dev-libs/glib-2.36.0:2
+	>=dev-libs/libxml2-2.4.16:2
+	>=gnome-extra/libgsf-1.14.9
+	>=sci-chemistry/bodr-5
+	>=sci-chemistry/chemical-mime-data-0.1.94
+	>=sci-chemistry/openbabel-2.3.0:0=
+	>=x11-libs/cairo-1.6.0
+	>=x11-libs/gdk-pixbuf-2.22.0
+	>=x11-libs/goffice-0.10.12
+	x11-libs/gtk+:3
+	>=x11-libs/libX11-1.0.0
+	virtual/glu
+	gnumeric? ( >=app-office/gnumeric-1.12.42:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-doc/doxygen
+	app-text/yelp-tools
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${P/_p*}"
+
+src_prepare() {
+	default
+
+	if has_version '<sci-chemistry/openbabel-3'; then
+		sed -i -e '/openbabel-v3/d' "${WORKDIR}"/debian/patches/series || die
+	fi
+
+	# Debian patches
+	for p in $(<"${WORKDIR}"/debian/patches/series) ; do
+		eapply -p1 "${WORKDIR}/debian/patches/${p}"
+	done
+
+	eautoreconf
+}
+
+src_configure() {
+	# bug #790023
+	append-cxxflags -std=c++14
+
+	# lasem is not in the tree
+	econf \
+		--without-lasem \
+		--disable-mozilla-plugin \
+		--disable-update-databases
+}
+
+src_install() {
+	default
+
+	mv "${ED}"/usr/share/appdata "${ED}"/usr/share/metainfo || die
+	rm -rf "${ED}"/usr/share/mimelnk/ || die
+
+	find "${D}" -name '*.la' -type f -delete || die
+}