[gentoo-commits] repo/gentoo:master commit in: media-gfx/imv/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     f13d259b14e6a601d7fedee883c6b5fe586884b7
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 15 10:34:53 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Wed Dec 15 10:39:14 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f13d259b

media-gfx/imv: add 4.3.1

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-gfx/imv/Manifest         |  1 +
 media-gfx/imv/imv-4.3.1.ebuild | 81 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/media-gfx/imv/Manifest b/media-gfx/imv/Manifest
index 2891222742f2..4fdc2c890216 100644
--- a/media-gfx/imv/Manifest
+++ b/media-gfx/imv/Manifest
@@ -1 +1,2 @@
 DIST imv-4.3.0.tar.gz 79031 BLAKE2B f620e1d05827f93eae03a01f62cbb1426a623b4ef2e758a5fea2539193292fada0b8bf34276443d787b5a1537e92cd66e94b574a646319c3c37fbf2557bda4eb SHA512 1735c03c48888004b11b3aaf0215a9530c035468a8efdb210d856551ebb75030c906eee2b6ab80e5d3646206e6051a73a8c5e15c010dd09bca7f9e90f9b0e34b
+DIST imv-4.3.1.tar.gz 79123 BLAKE2B 9c818a5a29457313c3d0ed1a8558555b2069aec837939dc1d2b71668ec2fd39867c8ad4fcf8605243ded96e27d346af4307d83c8854538981b62c968e9ec0ede SHA512 f70b95f3f99d7d6a9276370650cef0885938464e3a40ab1768231292ba35d9040f7196a5853ea1268fe6d47cf08d129b3fbae1ca215df96d12ccd85b7efd1ee6

diff --git a/media-gfx/imv/imv-4.3.1.ebuild b/media-gfx/imv/imv-4.3.1.ebuild
new file mode 100644
index 000000000000..55cdc69ad90e
--- /dev/null
+++ b/media-gfx/imv/imv-4.3.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~exec64/imv/"
+else
+	SRC_URI="https://git.sr.ht/~exec64/imv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-v${PV}"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Minimal image viewer designed for tiling window manager users"
+HOMEPAGE="https://sr.ht/~exec64/imv/"
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+IUSE="+X +freeimage gif heif jpeg png svg test tiff wayland"
+REQUIRED_USE="|| ( X wayland )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/icu:=
+	dev-libs/inih
+	media-libs/libglvnd[X?]
+	x11-libs/cairo
+	x11-libs/libxkbcommon[X?]
+	x11-libs/pango
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb:=
+	)
+	freeimage? ( media-libs/freeimage )
+	gif? ( media-libs/libnsgif )
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( media-libs/libpng:= )
+	svg? ( >=gnome-base/librsvg-2.44:2 )
+	tiff? ( media-libs/tiff )
+	wayland? ( dev-libs/wayland )
+	!sys-apps/renameutils"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	test? ( dev-util/cmocka )"
+BDEPEND="
+	app-text/asciidoc
+	wayland? ( dev-util/wayland-scanner )"
+
+src_prepare() {
+	default
+
+	# if wayland-only, don't automagic on libGL and force libOpenGL
+	if ! use X; then
+		sed -i "/dependency('gl'/{s/'gl'/'opengl'/;s/false/true/}" meson.build || die
+	fi
+
+	# glu isn't used by anything
+	sed -i "/dependency('glu')/d" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature freeimage)
+		$(meson_feature gif libnsgif)
+		$(meson_feature heif libheif)
+		$(meson_feature jpeg libjpeg)
+		$(meson_feature png libpng)
+		$(meson_feature svg librsvg)
+		$(meson_feature test)
+		$(meson_feature tiff libtiff)
+		-Dwindows=$(usex X $(usex wayland all x11) wayland)
+	)
+
+	meson_src_configure
+}