[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-calculator/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     9328d0d3830d6c7cab725e402aff5fef8032bc23
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Dec 11 17:43:45 2021 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Dec 11 18:41:54 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9328d0d3

gnome-extra/gnome-calculator: bump to 41.1

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/gnome-calculator/Manifest              |  1 +
 .../gnome-calculator/gnome-calculator-41.1.ebuild  | 74 ++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/gnome-extra/gnome-calculator/Manifest b/gnome-extra/gnome-calculator/Manifest
index a7971bd6daa3..501fe648d012 100644
--- a/gnome-extra/gnome-calculator/Manifest
+++ b/gnome-extra/gnome-calculator/Manifest
@@ -1 +1,2 @@
 DIST gnome-calculator-40.1.tar.xz 1023164 BLAKE2B 977fc227adaa50efa271776035a11ca79166a703c9c8d618c13af477056622a9faa42c3a8876257a117486399e91fceec7a19b930293883078846a645db912fe SHA512 f46acc802ef130ec59e4376a02032ab683e6d166d691d7c5f626e2a978f017f171c0e8ad50991d1828cb325b1bd53f63ef256b9b24860842224fa3dd7e27f4da
+DIST gnome-calculator-41.1.tar.xz 1046092 BLAKE2B 2c9a8757adcb9858f826f303ebcec44b869e3be95f49d2722e57765f187d725f82dda6b1cac1302640d686fdccebbf5c8565c5bbd064d1d647bc5d23434d55ba SHA512 fc0d5c0744c52cd68f076afa29e3028f4998fe04e2e253d267b0350514ebae72172e90a345db69bc13d4ead2c7679416529d7192a34cfd970c7b2773870b9604

diff --git a/gnome-extra/gnome-calculator/gnome-calculator-41.1.ebuild b/gnome-extra/gnome-calculator/gnome-calculator-41.1.ebuild
new file mode 100644
index 000000000000..037952ba22f8
--- /dev/null
+++ b/gnome-extra/gnome-calculator/gnome-calculator-41.1.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+VALA_MIN_API_VERSION="0.40"
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala virtualx xdg
+
+DESCRIPTION="A calculator application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection test"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
+# altogether, thus we need them installed by gtksourceview[vala]
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	>=dev-libs/libgee-0.20.0:0.8
+	dev-libs/mpc:=
+	dev-libs/mpfr:0=
+	>=x11-libs/gtk+-3.24.1:3
+	>=gui-libs/libhandy-1.0.0:1=
+	>=x11-libs/gtksourceview-4.0.2:4
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	net-libs/libsoup:2.4[vala]
+	x11-libs/gtksourceview:4[vala]
+	gui-libs/libhandy:1[vala]
+"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+	# Automagic dep on valadoc - don't bother for now
+	sed -e '/subdir.*doc/d' -i meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-ui=false
+		#-Dvala-version # doesn't do anything in 3.34
+		$(meson_use !introspection disable-introspection)
+		$(meson_use test ui-tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}