[gentoo-commits] repo/gentoo:master commit in: app-backup/dar/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     6cde09167f48803e3b1d3d29ed204df508a3188c
Author:     Viorel Munteanu <ceamac.paragon <AT> gmail <DOT> com>
AuthorDate: Tue Dec  7 08:39:44 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Dec  9 06:40:35 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6cde0916

app-backup/dar: drop v2.7.1

v2.7.2 is stable

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Viorel Munteanu <ceamac.paragon <AT> gmail.com>
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 app-backup/dar/Manifest         |  1 -
 app-backup/dar/dar-2.7.1.ebuild | 90 -----------------------------------------
 2 files changed, 91 deletions(-)

diff --git a/app-backup/dar/Manifest b/app-backup/dar/Manifest
index 79390a742e90..1cb8917dd81b 100644
--- a/app-backup/dar/Manifest
+++ b/app-backup/dar/Manifest
@@ -1,2 +1 @@
-DIST dar-2.7.1.tar.gz 2290659 BLAKE2B 89fa7ac208eb3009f5151f27022a7a449bb204cb035f320e33ff642588b5ab0389c2ed33b71b7a7c6240d205877073f26a04f0164ce05bb370db3bc3faf25fda SHA512 404e3281b2c420088623e4c6ba262d2a7a44848986e43d4c71aff77104395f1178445d560849a73e0dbacce6b8014df2bb20bc33471ae2d07d897bb6ad577bcc
 DIST dar-2.7.2.tar.gz 2294187 BLAKE2B 6422f40aea9fe07195359d9e8d5a947fe20d1ec4d6bd866eb8e9240c153d069b5df75018c25b9e8ce6b7acbf4ce4259b50b0768cd391d8b9b1c7be72f03a56b6 SHA512 7e41adc0102806c07d644da41960b1e5bcb6b7872e6a5789506c1f2a001ffb4e3607cae6f76ccc2339d90cf4387b7645e9de6dbc4eed1306827a46e4b7c9d09d

diff --git a/app-backup/dar/dar-2.7.1.ebuild b/app-backup/dar/dar-2.7.1.ebuild
deleted file mode 100644
index 76ce18d6253a..000000000000
--- a/app-backup/dar/dar-2.7.1.ebuild
+++ /dev/null
@@ -1,90 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit flag-o-matic
-
-DESCRIPTION="A full featured backup tool, aimed for disks"
-HOMEPAGE="http://dar.linux.free.fr/"
-SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ppc sparc x86 ~amd64-linux"
-IUSE="argon2 curl dar32 dar64 doc gcrypt gpg lzo nls rsync threads xattr"
-
-REQUIRED_USE="?? ( dar32 dar64 )
-		gpg? ( gcrypt )"
-
-RESTRICT="test" # need to be run as root
-
-RDEPEND="
-	app-arch/bzip2:=
-	app-arch/xz-utils:=
-	sys-libs/libcap
-	>=sys-libs/zlib-1.2.3:=
-	argon2? ( app-crypt/argon2 )
-	curl? ( net-misc/curl )
-	gcrypt? ( dev-libs/libgcrypt:0= )
-	gpg? ( app-crypt/gpgme )
-	lzo? ( dev-libs/lzo:= )
-	rsync? ( net-libs/librsync:= )
-	threads? ( dev-libs/libthreadar:= )
-	xattr? ( sys-apps/attr:= )
-"
-
-DEPEND="${RDEPEND}"
-
-BDEPEND="
-	doc? ( app-doc/doxygen )
-	nls? (
-		sys-devel/gettext
-		virtual/libintl
-	)
-"
-
-DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
-
-src_configure() {
-	# configure.ac is totally funked up regarding the AC_ARG_ENABLE
-	# logic.
-	# For example "--enable-dar-static" causes configure to DISABLE
-	# static builds of dar.
-	# Do _not_ use $(use_enable) until you have verified that the
-	# logic has been fixed by upstream.
-	local myconf=(
-		--disable-dar-static
-		--disable-python-binding
-		--disable-static
-		--disable-upx
-		$(usex argon2 '' --disable-libargon2-linking)
-		$(usex curl '' --disable-libcurl-linking)
-		$(usex dar32 --enable-mode=32 '')
-		$(usex dar64 --enable-mode=64 '')
-		$(usex doc '' --disable-build-html)
-		$(usex gcrypt '' --disable-libgcrypt-linking)
-		$(usex gpg '' --disable-gpgme-linking)
-		$(usex lzo '' --disable-liblzo2-linking)
-		$(usex nls '' --disable-nls)
-		$(usex rsync '' --disable-librsync-linking)
-		$(usex threads '' --disable-threadar)
-		$(usex xattr '' --disable-ea-support)
-	)
-
-	# Bug 103741
-	filter-flags -fomit-frame-pointer
-
-	econf "${myconf[@]}"
-}
-
-src_install() {
-	emake DESTDIR="${D}" pkgdatadir="${EPREFIX}"/usr/share/doc/${PF}/html install
-
-	einstalldocs
-
-	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
-
-	# Bug 729150
-	rm "${ED}/usr/share/doc/${PF}/html/samples/MyBackup.sh.tar.gz" || die
-}