[gentoo-commits] repo/gentoo:master commit in: app-text/libmwaw/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     1d7159ff3f3b42c5f5fa2363c96140c1c3e273f8
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Dec  8 11:53:25 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Dec  8 15:07:46 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1d7159ff

app-text/libmwaw: 0.3.21 version bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-text/libmwaw/Manifest              |  1 +
 app-text/libmwaw/libmwaw-0.3.21.ebuild | 55 ++++++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/app-text/libmwaw/Manifest b/app-text/libmwaw/Manifest
index 148a7da2b6c3..4f031f4856f5 100644
--- a/app-text/libmwaw/Manifest
+++ b/app-text/libmwaw/Manifest
@@ -1 +1,2 @@
 DIST libmwaw-0.3.20.tar.xz 1425812 BLAKE2B a708ce4a28a0d5a5a5ee9d178c67119189add0180e61d67af6821c509d95b9f8bfb60eeb1afcdf8e2da5bed26053108b12db57db98912d97dc7e0ef0f7121f18 SHA512 d6cd28629b6482dd61e070036e94568ecc44d9064dddd9c699c7362caa8ef36652ce84cf0f199813854636f2e39ab19d47f4e148990822791b88cd3f17f68b3b
+DIST libmwaw-0.3.21.tar.xz 1457212 BLAKE2B 19e0893c186f273f5743a397da895f653cca1300febcac90353951c6ca66405c2481aac6083017f4ec00a31ee0f08e8e77dc579019396e23930a091de2d8903a SHA512 1b6aab4f3e76d1d7a3c15cc175642c62f826172c9fdef558617b87a98d056a05d817caaccdc199197670f84ada448b65cce61f5254ed8e1d7634a637d3367384

diff --git a/app-text/libmwaw/libmwaw-0.3.21.ebuild b/app-text/libmwaw/libmwaw-0.3.21.ebuild
new file mode 100644
index 000000000000..4c609720e0df
--- /dev/null
+++ b/app-text/libmwaw/libmwaw-0.3.21.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.code.sf.net/p/libmwaw/libmwaw"
+	inherit git-r3
+else
+	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Library parsing many pre-OSX MAC text formats"
+HOMEPAGE="https://sourceforge.net/p/libmwaw/wiki/Home/"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc tools"
+
+DEPEND="
+	dev-libs/librevenge
+	sys-libs/zlib
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	default
+
+	# Refresh stale libtool, bug #814512
+	eautoreconf
+}
+
+src_configure() {
+	# zip is hard enabled as the zlib is dep on the rdeps anyway
+	local myeconfargs=(
+		--enable-zip
+		--disable-werror
+		$(use_with doc docs)
+		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}