[gentoo-commits] repo/gentoo:master commit in: sys-fs/encfs/

["Sam James" <sam@gentoo.org>]

commit:     5d2b69ad3b74a4b44b160e8ac93c8d6fa426624d
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Tue Dec  7 06:55:27 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Tue Dec  7 06:56:52 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5d2b69ad

sys-fs/encfs: install libencfs, link dynamically

We need to install libencfs if we're going to link dynamically
against it.

Closes: https://bugs.gentoo.org/701698
Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-fs/encfs/encfs-1.9.5-r2.ebuild | 43 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

diff --git a/sys-fs/encfs/encfs-1.9.5-r2.ebuild b/sys-fs/encfs/encfs-1.9.5-r2.ebuild
new file mode 100644
index 000000000000..c26268474a9d
--- /dev/null
+++ b/sys-fs/encfs/encfs-1.9.5-r2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="An implementation of encrypted filesystem in user-space using FUSE"
+HOMEPAGE="https://vgough.github.io/encfs/"
+SRC_URI="https://github.com/vgough/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~sparc ~x86"
+IUSE="nls"
+
+RDEPEND="dev-libs/openssl:=
+	dev-libs/tinyxml2:=
+	sys-fs/fuse:0=
+	sys-libs/zlib"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-lang/perl
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+# Build dir is hardcoded in test suite, but we restrict them
+# because they can lead to false negatives, bug #630486
+RESTRICT="test"
+
+BUILD_DIR="${S}/build"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_NLS="$(usex nls)"
+		-DUSE_INTERNAL_TINYXML=OFF
+		-DBUILD_UNIT_TESTS=OFF
+		-DBUILD_SHARED_LIBS=ON
+		# Needed with BUILD_SHARED_LIBS=ON
+		-DINSTALL_LIBENCFS=ON
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+	)
+	cmake_src_configure
+}