[gentoo-commits] repo/gentoo:master commit in: dev-util/diffoscope/

["Sam James" <sam@gentoo.org>]

commit:     f0e96e0e903d3b5531d620b75242c00acaa6f425
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 29 01:03:17 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Nov 29 01:03:38 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f0e96e0e

dev-util/diffoscope: add 194

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   1 +
 dev-util/diffoscope/diffoscope-194.ebuild | 110 ++++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 45b94f9eb2cd..8b9e344cd02a 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,3 +1,4 @@
 DIST diffoscope-190.tar.gz 2704083 BLAKE2B a2a0313f87fdb9c20b0dc696a1aea570857dd7005e0f69dc2dd139bca86a4b5711f98862b60f4d1a581bf3e0dfd38ef3be96991b96862584f289f1eb80415480 SHA512 646380d52730cf2efef57e3fa2995c7b2d5958d75597a59a24027bca1fc35c5b59dd96352faac9b7bd1d5bc053064f11760877651d52099f6b1ca0b3ad65d63c
 DIST diffoscope-192.tar.gz 2815127 BLAKE2B 61aaf7485452751196b1d50f5423deb332f362107a559e2b2fc807b5b00b75e49ce5a26d1e8d24b40e765d182f76f17523efa01333f78cf68395389e6dcdb028 SHA512 3db57b650b7dc02a144f995cc9fd481e8fc36470e1e2fbaf29269d229d300336f08ff3fae847340de48ea3be6873fb75b86b7a7be3c7efec958523d3110847dd
 DIST diffoscope-193.tar.gz 2704578 BLAKE2B c6d824b852e4ffd38e99d04fcbff8342616b47c6e71f0ca465677528d10bf56ed0b14f37a038a9697ef290c3f20a88ad22e94791ffcb9cf52550fd48a787d0db SHA512 3e6b013d7e0320680a686a00d21adabca0087641d708408653c0d611721eabc1302c46e0c391c457ea4cf5741cb2423995dd4df55ded9fa2da43b19aa0ba6fb3
+DIST diffoscope-194.tar.gz 2704634 BLAKE2B ca080f07ab23d48cd772302f47fff67c38ca3106d2fd96de37b9112aa316ec095acb07062316abf60ac3457de99b6e3f69adef166ab4b24943dff9e8a127f99f SHA512 cfdd30ea12326ca08f200a78fd77b5b681bbe31cd292fa22fcab294a64717a06f431bcc8c3def7c75f9fb554108e48b8043bc3901d5e57a2be3cc38d20a303e5

diff --git a/dev-util/diffoscope/diffoscope-194.ebuild b/dev-util/diffoscope/diffoscope-194.ebuild
new file mode 100644
index 000000000000..bd59e85cceb9
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-194.ebuild
@@ -0,0 +1,110 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+BDEPEND="test? (
+		app-text/docx2txt
+		media-libs/libcaca
+		virtual/imagemagick-tools[jpeg]
+	)"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local exclude=(
+		# test seems to use different tarball
+		tests/test_presenters.py::test_text_proper_indentation
+
+		# needs triage
+		tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+
+		# needs triage
+		tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+		# img2txt based failures, bug #797688
+		tests/comparators/test_ico_image.py::test_diff
+		tests/comparators/test_ico_image.py::test_diff_meta
+		tests/comparators/test_ico_image.py::test_diff_meta2
+		tests/comparators/test_ico_image.py::test_has_visuals
+		tests/comparators/test_jpeg_image.py::test_diff
+		tests/comparators/test_jpeg_image.py::test_compare_non_existing
+		tests/comparators/test_jpeg_image.py::test_diff_meta
+		tests/comparators/test_jpeg_image.py::test_has_visuals
+
+		# docx2txt based falures, bug #797688
+		tests/comparators/test_docx.py::test_diff
+	)
+	epytest ${exclude[@]/#/--deselect }
+}