[gentoo-commits] repo/gentoo:master commit in: www-apache/mod_auth_kerb/

["Marek Szuba" <marecki@gentoo.org>]

commit:     a0aa837bf394e2564c7a417e8d4761d783f955bb
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 27 12:24:41 2021 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Sat Nov 27 13:04:11 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a0aa837b

www-apache/mod_auth_kerb: update EAPI 5 -> 7

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 .../mod_auth_kerb/mod_auth_kerb-5.4-r3.ebuild      | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/www-apache/mod_auth_kerb/mod_auth_kerb-5.4-r3.ebuild b/www-apache/mod_auth_kerb/mod_auth_kerb-5.4-r3.ebuild
new file mode 100644
index 000000000000..0a59d3214ff2
--- /dev/null
+++ b/www-apache/mod_auth_kerb/mod_auth_kerb-5.4-r3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit apache-module depend.apache tmpfiles
+
+DESCRIPTION="An Apache authentication module using Kerberos"
+HOMEPAGE="http://modauthkerb.sourceforge.net/"
+SRC_URI="mirror://sourceforge/project/modauthkerb/${PN}/${P}/${P}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/${P}-gentoo-patchset.tar.bz2"
+
+LICENSE="BSD openafs-krb5-a HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="virtual/krb5"
+RDEPEND="${DEPEND}"
+
+APACHE2_MOD_CONF="11_${PN}"
+APACHE2_MOD_DEFINE="AUTH_KERB"
+
+DOCFILES="INSTALL README"
+
+need_apache2
+
+PATCHES=(
+	"${WORKDIR}/${P}-gentoo-patchset"/${P}-rcopshack.patch
+	"${WORKDIR}/${P}-gentoo-patchset"/${P}-fixes.patch
+	"${WORKDIR}/${P}-gentoo-patchset"/${P}-s4u2proxy.patch
+	"${WORKDIR}/${P}-gentoo-patchset"/${P}-httpd24.patch
+	"${WORKDIR}/${P}-gentoo-patchset"/${P}-delegation.patch
+	"${WORKDIR}/${P}-gentoo-patchset"/${P}-cachedir.patch
+	"${WORKDIR}/${P}-gentoo-patchset"/${P}-longuser.patch
+	"${WORKDIR}/${P}-gentoo-patchset"/${P}-handle-continue.patch
+	"${WORKDIR}/${P}-gentoo-patchset"/${P}-heimdal.patch
+)
+
+# Work around Bug #616612
+pkg_setup() {
+	_init_apache2
+	_init_apache2_late
+}
+
+src_configure() {
+	CFLAGS="" APXS="${APXS}" econf --with-krb5=/usr --without-krb4
+}
+
+src_compile() {
+	emake
+}
+
+src_install() {
+	apache-module_src_install
+	dotmpfiles "${FILESDIR}/${PN}.conf"
+}
+
+pkg_postinst() {
+	tmpfiles_process ${PN}.conf
+}