[gentoo-commits] repo/gentoo:master commit in: dev-scheme/stklos/

["Akinori Hattori" <hattya@gentoo.org>]

commit:     9d703f43293f148219ceca108ab602083b417c03
Author:     Akinori Hattori <hattya <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 27 06:32:16 2021 +0000
Commit:     Akinori Hattori <hattya <AT> gentoo <DOT> org>
CommitDate: Sat Nov 27 06:39:04 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9d703f43

dev-scheme/stklos: update to EAPI 8

Closes: https://bugs.gentoo.org/423823
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Akinori Hattori <hattya <AT> gentoo.org>

 dev-scheme/stklos/stklos-1.10-r1.ebuild | 35 -----------------------
 dev-scheme/stklos/stklos-1.10-r2.ebuild | 49 +++++++++++++++++++++++++++++++++
 2 files changed, 49 insertions(+), 35 deletions(-)

diff --git a/dev-scheme/stklos/stklos-1.10-r1.ebuild b/dev-scheme/stklos/stklos-1.10-r1.ebuild
deleted file mode 100644
index e1342e7a0c12..000000000000
--- a/dev-scheme/stklos/stklos-1.10-r1.ebuild
+++ /dev/null
@@ -1,35 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-DESCRIPTION="fast and light Scheme implementation"
-HOMEPAGE="https://www.stklos.net/"
-SRC_URI="https://www.${PN}.net/download/${P}.tar.gz"
-LICENSE="GPL-2+"
-
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="threads"
-DEPEND="dev-libs/gmp:= dev-libs/libpcre dev-libs/libffi dev-libs/boehm-gc[threads?]"
-RDEPEND="${DEPEND}"
-
-#parallel build failure reported upstream
-MAKEOPTS=-j1
-
-src_prepare() {
-	# kill bundled libs
-	rm -rf "${S}"/{ffi,gc,gmp,pcre} || die
-	default
-}
-
-src_configure() {
-	econf --enable-threads=$(if use threads; then echo pthreads; else echo none; fi) \
-		--without-gmp-light --without-provided-gc \
-		--without-provided-regexp --without-provided-ffi
-}
-
-src_install() {
-	emake DESTDIR="${D}" install
-	dodoc AUTHORS ChangeLog NEWS PACKAGES-USED PORTING-NOTES README SUPPORTED-SRFIS
-}

diff --git a/dev-scheme/stklos/stklos-1.10-r2.ebuild b/dev-scheme/stklos/stklos-1.10-r2.ebuild
new file mode 100644
index 000000000000..6fd3a1acef34
--- /dev/null
+++ b/dev-scheme/stklos/stklos-1.10-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+DESCRIPTION="fast and light Scheme implementation"
+HOMEPAGE="https://www.stklos.net/"
+SRC_URI="https://www.${PN}.net/download/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="threads"
+
+RDEPEND="dev-libs/boehm-gc[threads?]
+	dev-libs/gmp:=
+	dev-libs/libffi:=
+	dev-libs/libpcre"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS ChangeLog NEWS PACKAGES-USED PORTING-NOTES README SUPPORTED-SRFIS )
+
+src_prepare() {
+	rm -rf {ffi,gc,gmp,pcre}
+
+	default
+}
+
+src_configure() {
+	econf \
+		--enable-threads=$(usex threads pthreads none) \
+		--without-gmp-light \
+		--without-provided-ffi \
+		--without-provided-gc \
+		--without-provided-regexp
+}
+
+src_compile() {
+	emake -j1
+}
+
+src_test() {
+	emake -j1 check
+}
+
+src_install() {
+	default
+	einstalldocs
+}