[gentoo-commits] repo/gentoo:master commit in: games-arcade/jumpnbump/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     74f54c8e5622e307705505e280b94e2aaf93f006
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 18 18:23:06 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Nov 18 19:08:07 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=74f54c8e

games-arcade/jumpnbump: add 1.61_p20210421

* EAPI7->8
* enable py3.10
* drop -fcommon workaround wrt bug #794970 (fixed upstream)
* add zlib/bzip2/pillow missing deps.
* IUSE=gtk->gui (IUSE=launcher or =menu may make more sense
  but didn't see a major need for non-generic flags here)
* move icon to right location

Closes: https://bugs.gentoo.org/794970
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-arcade/jumpnbump/Manifest                    |  1 +
 .../jumpnbump/jumpnbump-1.61_p20210421.ebuild      | 69 ++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/games-arcade/jumpnbump/Manifest b/games-arcade/jumpnbump/Manifest
index 98b961d211e2..5da33430f393 100644
--- a/games-arcade/jumpnbump/Manifest
+++ b/games-arcade/jumpnbump/Manifest
@@ -1 +1,2 @@
 DIST jumpnbump-1.61.tar.xz 309072 BLAKE2B 057f597aedfcacb5c45e2980d670109c6ed1d9508a17ff467f44e10190d84d19609fded416c30512a59385a6c59221da98af90069adc993f0cc4c9332d248321 SHA512 1c5999c6d0d00770416a61803e5dac4742e23d787ba6bec3742517e3eab006efe9448e59f3e84278e224e184a8ac8444c7c766b74374761b1aec7cffdc1708c1
+DIST jumpnbump-1.61_p20210421.tar.gz 436105 BLAKE2B 3546c3c1d625b2560acbd39cf4a1a0b1fc022254c8b99913ead856d90a9354426220c2cae57ea991e4133287bc9e10d2b7b8d621f70eaa8c0baf93ee3d419a30 SHA512 ae5a7173fe43c3674ab6883d5daf3758680e53b4b33ada4c998831fcd52b6769683e72b484d01e976e3358dc1992a46e764b75d7cbe1632c48b00b570a03e03b

diff --git a/games-arcade/jumpnbump/jumpnbump-1.61_p20210421.ebuild b/games-arcade/jumpnbump/jumpnbump-1.61_p20210421.ebuild
new file mode 100644
index 000000000000..7b0afcd18e3f
--- /dev/null
+++ b/games-arcade/jumpnbump/jumpnbump-1.61_p20210421.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit desktop python-single-r1 toolchain-funcs
+
+MY_COMMIT="73c5fe86fd831dec45a22077e8d63dd2b6a6349e"
+
+DESCRIPTION="Funny multiplayer game about cute little fluffy bunnies"
+HOMEPAGE="https://libregames.gitlab.io/jumpnbump"
+SRC_URI="https://gitlab.com/LibreGames/jumpnbump/-/archive/${MY_COMMIT}/${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_COMMIT}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gui"
+REQUIRED_USE="gui? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	app-arch/bzip2:=
+	media-libs/libsdl2[joystick,sound,video]
+	media-libs/sdl2-mixer[mod]
+	media-libs/sdl2-net
+	sys-libs/zlib:="
+RDEPEND="
+	${DEPEND}
+	gui? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/pillow[${PYTHON_USEDEP}]
+			dev-python/pygobject[${PYTHON_USEDEP}]
+		')
+		x11-libs/gdk-pixbuf:2[introspection]
+		x11-libs/gtk+:3[introspection]
+	)"
+BDEPEND="gui? ( ${PYTHON_DEPS} )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.61-ranlib.patch
+)
+
+pkg_setup() {
+	use gui && python-single-r1_pkg_setup
+}
+
+src_compile() {
+	tc-export AR CC RANLIB
+
+	emake PREFIX="${EPREFIX}"/usr
+
+	if use gui; then
+		emake PREFIX="${EPREFIX}"/usr jnbmenu
+		python_fix_shebang menu/jumpnbump_menu.py
+	fi
+}
+
+src_install() {
+	emake PREFIX="${ED}"/usr install
+
+	use gui && emake -C menu PREFIX="${ED}"/usr install
+
+	doicon dist/${PN}.png
+	rm "${ED}"/usr/share/icons/${PN}.png || die
+
+	einstalldocs
+}