[gentoo-commits] repo/gentoo:master commit in: dev-libs/hidapi/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     526f44b19300099f23377e8233b4ac3e2fc0e94c
Author:     Andrew Udvare <audvare <AT> gmail <DOT> com>
AuthorDate: Tue Oct 12 18:01:59 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Nov 10 09:10:47 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=526f44b1

dev-libs/hidapi: add version 0.11.0

Use EAPI 8
Update homepage
Build documentation in correct phases

Package-Manager: Portage-3.0.28, Repoman-3.0.3

Signed-off-by: Andrew Udvare <audvare <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/22567
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-libs/hidapi/Manifest             |  1 +
 dev-libs/hidapi/hidapi-0.11.0.ebuild | 70 ++++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/dev-libs/hidapi/Manifest b/dev-libs/hidapi/Manifest
index df86bf7b54d..6de08b4220b 100644
--- a/dev-libs/hidapi/Manifest
+++ b/dev-libs/hidapi/Manifest
@@ -1 +1,2 @@
+DIST hidapi-0.11.0.tgz 232631 BLAKE2B 770c0663b007aa36580af217d0d38be72923e0ad84cee137594ca3e174e589cebb9188003a50999e1c561b0e4e9ca68bd1af29029b89fde2b0a46020b12f9744 SHA512 0de4abc963600d159ce231416c468b9e81a8361e4d2c2202988d6eb2e58a923700e9b9be639fbddc6bc14625131848409e2e88dbc4b34a1f8a726c8fa4692d92
 DIST hidapi-0.8.0_rc1_p20140719.tgz 103079 BLAKE2B f40a4c17cb8c5eed41f4eea84fac46a879ec2057f28212aa43c8fd718ceea68d760785cb4f4e2ea3bcd2a4345b65d75d0d278b93697ec61963be9270684a15cb SHA512 204934a707da4e67b834823650b0cfd9be7b413972071129cc5aeeb93465834dde2f5ee23283c55d35b56e3aed8b7ad5fe947399839081f4d895fb65c8cd3e3d

diff --git a/dev-libs/hidapi/hidapi-0.11.0.ebuild b/dev-libs/hidapi/hidapi-0.11.0.ebuild
new file mode 100644
index 00000000000..403cb345499
--- /dev/null
+++ b/dev-libs/hidapi/hidapi-0.11.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="A multi-platform library for USB and Bluetooth HID-Class devices"
+HOMEPAGE="https://github.com/libusb/hidapi"
+SRC_URI="https://github.com/libusb/hidapi/archive/${P}.tar.gz -> ${P}.tgz"
+
+LICENSE="|| ( BSD GPL-3 HIDAPI )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc fox"
+
+RDEPEND="
+	virtual/libusb:1[${MULTILIB_USEDEP}]
+	virtual/libudev:0[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}
+	fox? ( x11-libs/fox )"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S="${WORKDIR}/${PN}-${PN}-${PV}"
+
+src_prepare() {
+	default
+
+	if ! use fox; then
+		sed -i -e 's:PKG_CHECK_MODULES(\[fox\], .*):AC_SUBST(fox_CFLAGS,[ ])AC_SUBST(fox_LIBS,[ ]):' configure.ac || die
+	fi
+
+	# Fix bashisms in the configure.ac file.
+	sed -i -e 's:\([A-Z_]\+\)+="\(.*\)":\1="${\1}\2":g' \
+		-e 's:\([A-Z_]\+\)+=`\(.*\)`:\1="${\1}\2":g' configure.ac || die
+
+	# Portage handles license texts itself, no need to install them
+	sed -i -e 's/LICENSE.*/ # blank/' Makefile.am || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		--disable-static \
+		$(multilib_native_use_enable fox testgui)
+}
+
+multilib_src_compile() {
+	default
+	if use doc && multilib_is_native_abi; then
+		doxygen "${S}/doxygen/Doxyfile" || die
+	fi
+}
+
+multilib_src_install() {
+	default
+	local HTML_DOCS
+	if use doc && multilib_is_native_abi; then
+		HTML_DOCS=( html/. )
+	fi
+	einstalldocs
+}
+
+multilib_src_install_all() {
+	# no static archives
+	find "${ED}" -name '*.la' -delete || die
+}