[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-workspace/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     dccec76edfd1096700266bc85dfbe026d4b5b99d
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Nov  9 14:37:19 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Nov  9 17:15:16 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dccec76e

kde-plasma/plasma-workspace: drop 5.23.2*

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-workspace/Manifest               |   1 -
 .../plasma-workspace-5.23.2.ebuild                 | 207 ---------------------
 2 files changed, 208 deletions(-)

diff --git a/kde-plasma/plasma-workspace/Manifest b/kde-plasma/plasma-workspace/Manifest
index de1b2b42487..7d5cecf5655 100644
--- a/kde-plasma/plasma-workspace/Manifest
+++ b/kde-plasma/plasma-workspace/Manifest
@@ -1,3 +1,2 @@
 DIST plasma-workspace-5.22.5.tar.xz 8401412 BLAKE2B 3479549ffb302f8beca8f37853540bd71cc03a02183826435ec47ded0df69f4b19e103d8b6e2cd16af001a9c04a34e2f37a98a461f40fb8837ed7e7128a6fcba SHA512 753ba35c3f0c3a5affe10d3a6149f1ebca7ed51b0710c079606e33ceada94a50eee1c1bafbb465fcc194038915c33edef1d79e0865e5702aab7a334d6d508c47
-DIST plasma-workspace-5.23.2.tar.xz 9005008 BLAKE2B 07b63db2c57032fbb85499dc2b1972316e5b42a900470c56c6b0821fd45b3e189b9a0684114f9f51d110a860f1f3b4aebd2b782cb372e8634d9660c512b06073 SHA512 18ff49d90b9232e5539c8dd274e9536f0965e4dd1725c3ba6c8f98e264d926d2bfc8cd5f2da7bdd643b45691b1b92dbf68197d8e85be534b18df5a9d70b2e799
 DIST plasma-workspace-5.23.3.tar.xz 9006500 BLAKE2B 651780480736ae0478b059e8dcff40d5411310693d3b0b24b9a8a5c442c45c555e69a99c3e0f20d82a4e0dc3a099537c172589e17afa2b34c68d314164913e73 SHA512 34f8835d35063b582b12b343475474b2c7b338ecef148871f28348fe73f2b1ea36d938553c8e97fd108ce441cbb7c97b450590b186c788608c9cf29c82d8c786

diff --git a/kde-plasma/plasma-workspace/plasma-workspace-5.23.2.ebuild b/kde-plasma/plasma-workspace/plasma-workspace-5.23.2.ebuild
deleted file mode 100644
index 442c97629ce..00000000000
--- a/kde-plasma/plasma-workspace/plasma-workspace-5.23.2.ebuild
+++ /dev/null
@@ -1,207 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-ECM_HANDBOOK="forceoptional"
-ECM_TEST="forceoptional"
-KFMIN=5.86.0
-PVCUT=$(ver_cut 1-3)
-QTMIN=5.15.2
-VIRTUALX_REQUIRED="test"
-inherit ecm kde.org
-
-DESCRIPTION="KDE Plasma workspace"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
-IUSE="appstream +calculator +calendar +fontconfig geolocation gps screencast
-+semantic-desktop systemd telemetry"
-
-REQUIRED_USE="gps? ( geolocation )"
-RESTRICT="test"
-
-# slot op: various private QtWaylandClient headers
-COMMON_DEPEND="
-	>=dev-libs/wayland-1.15
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
-	>=dev-qt/qtgui-${QTMIN}:5=[jpeg,libinput]
-	>=dev-qt/qtnetwork-${QTMIN}:5
-	>=dev-qt/qtsql-${QTMIN}:5
-	>=dev-qt/qtsvg-${QTMIN}:5
-	>=dev-qt/qtwayland-${QTMIN}:5=
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtx11extras-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	>=kde-frameworks/kactivities-${KFMIN}:5
-	>=kde-frameworks/kactivities-stats-${KFMIN}:5
-	>=kde-frameworks/karchive-${KFMIN}:5
-	>=kde-frameworks/kauth-${KFMIN}:5
-	>=kde-frameworks/kbookmarks-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/kdeclarative-${KFMIN}:5
-	>=kde-frameworks/kded-${KFMIN}:5
-	>=kde-frameworks/kglobalaccel-${KFMIN}:5
-	>=kde-frameworks/kguiaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kidletime-${KFMIN}:5
-	>=kde-frameworks/kinit-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemmodels-${KFMIN}:5
-	>=kde-frameworks/kitemviews-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/knewstuff-${KFMIN}:5
-	>=kde-frameworks/knotifications-${KFMIN}:5
-	>=kde-frameworks/knotifyconfig-${KFMIN}:5
-	>=kde-frameworks/kpackage-${KFMIN}:5
-	>=kde-frameworks/kpeople-${KFMIN}:5
-	>=kde-frameworks/krunner-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/ktextwidgets-${KFMIN}:5
-	>=kde-frameworks/kunitconversion-${KFMIN}:5
-	>=kde-frameworks/kwallet-${KFMIN}:5
-	>=kde-frameworks/kwayland-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kwindowsystem-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	>=kde-frameworks/plasma-${KFMIN}:5
-	>=kde-frameworks/prison-${KFMIN}:5[qml]
-	>=kde-frameworks/solid-${KFMIN}:5
-	>=kde-plasma/breeze-${PVCUT}:5
-	>=kde-plasma/kscreenlocker-${PVCUT}:5
-	>=kde-plasma/kwin-${PVCUT}:5
-	>=kde-plasma/layer-shell-qt-${PVCUT}:5
-	>=kde-plasma/libkscreen-${PVCUT}:5
-	>=kde-plasma/libksysguard-${PVCUT}:5
-	>=kde-plasma/libkworkspace-${PVCUT}:5
-	>=media-libs/phonon-4.11.0
-	sys-libs/zlib
-	x11-libs/libICE
-	x11-libs/libSM
-	x11-libs/libX11
-	x11-libs/libXau
-	x11-libs/libxcb
-	x11-libs/libXcursor
-	x11-libs/libXfixes
-	x11-libs/libXrender
-	x11-libs/libXtst
-	x11-libs/xcb-util
-	x11-libs/xcb-util-image
-	appstream? ( dev-libs/appstream[qt5] )
-	calculator? ( sci-libs/libqalculate:= )
-	calendar? ( >=kde-frameworks/kholidays-${KFMIN}:5 )
-	fontconfig? (
-		>=dev-qt/qtprintsupport-${QTMIN}:5
-		media-libs/fontconfig
-		x11-libs/libXft
-		x11-libs/xcb-util-image
-	)
-	geolocation? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
-	gps? ( sci-geosciences/gpsd )
-	screencast? (
-		>=dev-qt/qtgui-${QTMIN}:5=[egl]
-		media-libs/libglvnd
-		>=media-video/pipewire-0.3:=
-		x11-libs/libdrm
-	)
-	semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
-	telemetry? ( dev-libs/kuserfeedback:5 )
-"
-DEPEND="${COMMON_DEPEND}
-	>=dev-libs/plasma-wayland-protocols-1.1.1
-	>=dev-qt/qtconcurrent-${QTMIN}:5
-	>=dev-util/wayland-scanner-1.19.0
-	x11-base/xorg-proto
-	fontconfig? ( x11-libs/libXrender )
-"
-RDEPEND="${COMMON_DEPEND}
-	app-text/iso-codes
-	>=dev-qt/qdbus-${QTMIN}:5
-	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
-	>=dev-qt/qtpaths-${QTMIN}:5
-	>=dev-qt/qtquickcontrols-${QTMIN}:5[widgets]
-	>=dev-qt/qtquickcontrols2-${QTMIN}:5
-	kde-apps/kio-extras:5
-	>=kde-frameworks/kdesu-${KFMIN}:5
-	>=kde-frameworks/kirigami-${KFMIN}:5
-	>=kde-frameworks/kquickcharts-${KFMIN}:5
-	>=kde-plasma/milou-${PVCUT}:5
-	>=kde-plasma/plasma-integration-${PVCUT}:5
-	x11-apps/xmessage
-	x11-apps/xprop
-	x11-apps/xrdb
-	x11-apps/xsetroot
-	systemd? ( sys-apps/dbus[user-session] )
-	!systemd? ( sys-apps/dbus )
-	!<kde-plasma/breeze-5.22.90:5
-	!<kde-plasma/plasma-desktop-5.21.90:5
-"
-BDEPEND="virtual/pkgconfig"
-PDEPEND=">=kde-plasma/kde-cli-tools-${PVCUT}:5"
-
-PATCHES=( "${FILESDIR}/${PN}-5.21.5-split-libkworkspace.patch" ) # downstream
-
-src_prepare() {
-	ecm_src_prepare
-
-	cmake_comment_add_subdirectory libkworkspace
-	# delete colliding libkworkspace translations
-	if [[ ${KDE_BUILD_TYPE} = release ]]; then
-		find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
-	fi
-
-	# TODO: try to get a build switch upstreamed
-	if ! use screencast; then
-		sed -e "s/^pkg_check_modules.*PipeWire/#&/" -i CMakeLists.txt || die
-	fi
-
-	# KDE-bug: 433730
-	use calculator ||
-		cmake_run_in runners cmake_comment_add_subdirectory calculator
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_xembed-sni-proxy=OFF
-		-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON
-		$(cmake_use_find_package appstream AppStreamQt)
-		$(cmake_use_find_package calendar KF5Holidays)
-		$(cmake_use_find_package fontconfig Fontconfig)
-		$(cmake_use_find_package geolocation KF5NetworkManagerQt)
-		$(cmake_use_find_package semantic-desktop KF5Baloo)
-		$(cmake_use_find_package telemetry KUserFeedback)
-	)
-
-	use geolocation && mycmakeargs+=( $(cmake_use_find_package gps libgps) )
-
-	ecm_src_configure
-}
-
-src_install() {
-	ecm_src_install
-
-	# default startup and shutdown scripts
-	insinto /etc/xdg/plasma-workspace/env
-	doins "${FILESDIR}"/10-agent-startup.sh
-
-	insinto /etc/xdg/plasma-workspace/shutdown
-	doins "${FILESDIR}"/10-agent-shutdown.sh
-	fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
-}
-
-pkg_postinst () {
-	ecm_pkg_postinst
-
-	elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
-	elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
-	elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
-}