From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1336659-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (2048 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 23FDE158086
for <garchives@archives.gentoo.org>; Fri, 5 Nov 2021 13:36:23 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 2E7C3E08ED;
Fri, 5 Nov 2021 13:36:20 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 1C829E08ED
for <gentoo-commits@lists.gentoo.org>; Fri, 5 Nov 2021 13:36:19 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 11030342CB8
for <gentoo-commits@lists.gentoo.org>; Fri, 5 Nov 2021 13:36:17 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 5DA061AD
for <gentoo-commits@lists.gentoo.org>; Fri, 5 Nov 2021 13:36:15 +0000 (UTC)
From: "Mart Raudsepp" <leio@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Mart Raudsepp" <leio@gentoo.org>
Message-ID: <1636119187.ced4206c5fdc9af1644f71f2ae2b51fd311c3da5.leio@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: mail-client/evolution/
X-VCS-Repository: repo/gentoo
X-VCS-Files: mail-client/evolution/Manifest mail-client/evolution/evolution-3.42.1.ebuild
X-VCS-Directories: mail-client/evolution/
X-VCS-Committer: leio
X-VCS-Committer-Name: Mart Raudsepp
X-VCS-Revision: ced4206c5fdc9af1644f71f2ae2b51fd311c3da5
X-VCS-Branch: master
Date: Fri, 5 Nov 2021 13:36:15 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: c86bb411-f718-4af7-b5c7-9d7e79e772b0
X-Archives-Hash: fa600a1954f142b1382aa365be8b915e
commit: ced4206c5fdc9af1644f71f2ae2b51fd311c3da5
Author: Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Fri Nov 5 13:31:53 2021 +0000
Commit: Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Nov 5 13:33:07 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ced4206c
mail-client/evolution: bump to 3.42.1
Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>
mail-client/evolution/Manifest | 1 +
mail-client/evolution/evolution-3.42.1.ebuild | 151 ++++++++++++++++++++++++++
2 files changed, 152 insertions(+)
diff --git a/mail-client/evolution/Manifest b/mail-client/evolution/Manifest
index 81fbcaea5a6..3e2e231ce42 100644
--- a/mail-client/evolution/Manifest
+++ b/mail-client/evolution/Manifest
@@ -1,3 +1,4 @@
DIST evolution-3.40.3.tar.xz 12216768 BLAKE2B 7b146ee09abff566a5a0cbbda9dda6ce5cd26c076462fd511cbc02fa35352d1ab776c67c5c99990278963a6f96c2ea8410588925cce1c05300e34ad5252de618 SHA512 08fcfdafd78ee323a57355dec1c8755525eefb599b70e6fb60ed0e9963a538a4b3f172b78f03aecbd245741fad08363b01ada46c2e349a9ccdc080d28c286452
DIST evolution-3.40.4.tar.xz 12219300 BLAKE2B cbe56014252e8a23debbd4055be85d8bf89e25aa677b92880a6dba78d5d5fbb452403d5f9199b0257ca4c7ee10bff3bc5ca7601fa74390cf6d01d4d7cf099d1d SHA512 f6f08ab3cbc21397a0727b1edc5e37711294fdba6e537000d5a9f11f0142f69702fffad3922645fab256ccdee348b914a87abd0e6ed843c01762ccd32333518a
DIST evolution-3.42.0.tar.xz 12243112 BLAKE2B fc79c75b4a684da8d0c09fbc8b682095704d9446c93909d57947083fb5798b622efdb4dc52423bc10bdd392e8f05f4968cbf119dd3ffad737403934e9ef5f68a SHA512 435155a69ef324ff3b0f85c9f0ed3206a7dfe12bd8ad5e9a87dff5de839e837417147e81faa93c57f207dff4d92cdc36ac3856402493ff693055f267aed5cbeb
+DIST evolution-3.42.1.tar.xz 12274632 BLAKE2B b42984b4d5c8446e4a8714e3c7c92f0cf2baa53af05146df0449d41a587d968a3d91c707a797e09865f3fa03c0397b6fecf88552e53936b068215d5aac3ece48 SHA512 9db26d27c78997c3924b6627389b1a5c95a2f161219346fe45016b346a68c10679039fbde540220fc31769b0d3402c228ef7283b55ea3388cf66398a11cb0508
diff --git a/mail-client/evolution/evolution-3.42.1.ebuild b/mail-client/evolution/evolution-3.42.1.ebuild
new file mode 100644
index 00000000000..141bc4cc9c0
--- /dev/null
+++ b/mail-client/evolution/evolution-3.42.1.ebuild
@@ -0,0 +1,151 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake gnome2 flag-o-matic readme.gentoo-r1
+
+DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) CC-BY-SA-3.0 FDL-1.3+ OPENLDAP"
+SLOT="2.0"
+
+IUSE="archive +bogofilter geolocation gtk-doc highlight ldap spamassassin spell ssl +weather ytnef"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+# glade-3 support is for maintainers only per configure.ac
+# pst is not mature enough and changes API/ABI frequently
+# dconf explicitely needed for backup plugin
+# gnome-desktop support is optional with --enable-gnome-desktop
+# automagic libunity dep
+# >=gspell-1.8 to ensure it uses enchant:2 like webkit-gtk
+DEPEND="
+ >=app-crypt/gcr-3.4:=[gtk]
+ >=app-text/enchant-2.2.0:2
+ >=dev-libs/glib-2.56:2[dbus]
+ >=dev-libs/libxml2-2.7.3:2
+ >=gnome-base/gnome-desktop-2.91.3:3=
+ >=gnome-base/gsettings-desktop-schemas-2.91.92
+ >=gnome-extra/evolution-data-server-${PV}:=[gtk,weather?]
+ >=media-libs/libcanberra-0.25[gtk3]
+ >=net-libs/libsoup-2.42:2.4
+ >=net-libs/webkit-gtk-2.28.0:4[spell?]
+ >=x11-libs/cairo-1.9.15:=[glib]
+ >=x11-libs/gdk-pixbuf-2.24:2
+ >=x11-libs/gtk+-3.22:3
+ >=x11-libs/libnotify-0.7:=
+ >=x11-misc/shared-mime-info-0.22
+
+ >=app-text/iso-codes-0.49
+ dev-libs/atk
+ gnome-base/dconf
+ x11-libs/libSM
+ x11-libs/libICE
+
+ archive? ( >=app-arch/gnome-autoar-0.1.1[gtk] )
+ bogofilter? ( mail-filter/bogofilter )
+ geolocation? (
+ >=media-libs/libchamplain-0.12:0.12[gtk]
+ >=media-libs/clutter-1.0.0:1.0
+ >=media-libs/clutter-gtk-0.90:1.0
+ >=sci-geosciences/geocode-glib-3.10.0 )
+ ldap? ( >=net-nds/openldap-2:= )
+ spamassassin? ( mail-filter/spamassassin )
+ spell? ( >=app-text/gspell-1.8:= )
+ ssl? (
+ >=dev-libs/nspr-4.6.1:=
+ >=dev-libs/nss-3.11:= )
+ weather? ( >=dev-libs/libgweather-3.10:2= )
+ ytnef? ( net-mail/ytnef )
+"
+RDEPEND="${DEPEND}
+ highlight? ( app-text/highlight )
+"
+BDEPEND="
+ app-text/docbook-xml-dtd:4.1.2
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ dev-util/itstool
+ gtk-doc? ( dev-util/gtk-doc
+ app-text/docbook-xml-dtd:4.3 )
+ >=dev-util/intltool-0.40.0
+ >=sys-devel/gettext-0.18.3
+ virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="To change the default browser if you are not using GNOME, edit
+~/.local/share/applications/mimeapps.list so it includes the
+following content:
+
+[Default Applications]
+x-scheme-handler/http=firefox.desktop
+x-scheme-handler/https=firefox.desktop
+
+(replace firefox.desktop with the name of the appropriate .desktop
+file from /usr/share/applications if you use a different browser)."
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+
+src_prepare() {
+ cmake_src_prepare
+ gnome2_src_prepare
+}
+
+src_configure() {
+ # Use NSS/NSPR only if 'ssl' is enabled.
+ local mycmakeargs=(
+ -DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+ -DENABLE_SCHEMAS_COMPILE=OFF
+ -DENABLE_GTK_DOC=$(usex gtk-doc)
+ -DWITH_OPENLDAP=$(usex ldap)
+ -DENABLE_SMIME=$(usex ssl)
+ -DENABLE_GNOME_DESKTOP=ON
+ -DWITH_ENCHANT_VERSION=2
+ -DENABLE_CANBERRA=ON
+ -DENABLE_AUTOAR=$(usex archive)
+ -DWITH_HELP=ON
+ -DENABLE_YTNEF=OFF
+ -DWITH_BOGOFILTER=$(usex bogofilter)
+ -DWITH_SPAMASSASSIN=$(usex spamassassin)
+ -DENABLE_GSPELL=$(usex spell)
+ -DENABLE_TEXT_HIGHLIGHT=$(usex highlight)
+ -DENABLE_WEATHER=$(usex weather)
+ -DENABLE_CONTACT_MAPS=$(usex geolocation)
+ -DENABLE_YTNEF=$(usex ytnef)
+ -DENABLE_PST_IMPORT=OFF
+ -DWITH_GLADE_CATALOG=OFF
+ )
+
+ cmake_src_configure
+}
+
+src_compile() {
+ cmake_src_compile
+}
+
+src_test() {
+ cmake_src_test
+}
+
+src_install() {
+ cmake_src_install
+
+ # Problems with prelink:
+ # https://bugzilla.gnome.org/show_bug.cgi?id=731680
+ # https://bugzilla.gnome.org/show_bug.cgi?id=732148
+ # https://bugzilla.redhat.com/show_bug.cgi?id=1114538
+ echo PRELINK_PATH_MASK=/usr/bin/evolution > ${T}/99${PN}
+ doenvd "${T}"/99${PN}
+
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ gnome2_pkg_postinst
+ readme.gentoo_print_elog
+}