[gentoo-commits] repo/gentoo:master commit in: net-analyzer/testssl/

["Michael Palimaka" <kensington@gentoo.org>]

commit:     d23fd520f9a6bb3a21bbfe27e64dbc141b27dbfb
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 26 07:54:21 2021 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Tue Oct 26 07:54:35 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d23fd520

net-analyzer/testssl: version bump 3.0.6

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Michael Palimaka <kensington <AT> gentoo.org>

 net-analyzer/testssl/Manifest             |  1 +
 net-analyzer/testssl/testssl-3.0.6.ebuild | 74 +++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/net-analyzer/testssl/Manifest b/net-analyzer/testssl/Manifest
index 18fa2afa1eb..dfe496e6db3 100644
--- a/net-analyzer/testssl/Manifest
+++ b/net-analyzer/testssl/Manifest
@@ -1 +1,2 @@
 DIST testssl-3.0.5.tar.gz 9224554 BLAKE2B fed4f02f4c5db3975f711e5e1fa0f0018b5e89f8a3afbd94763ec86dc4f739ee25504769b61fc1dd0000ce7ce400f4d3267116cd21d14b003d9b6fd5706a84cb SHA512 0f3fa081f047bf2d3fb2f3b65fcdbec976af54143a2d8ffbece6eff7545cc2a6e134247f9533fb1614d52d900fc66d7f50c97f02678b5dfb9842c3c69c0f81f0
+DIST testssl-3.0.6.tar.gz 9217988 BLAKE2B 840eb0027f6b3e9ae919c9d8765c138a10ef9789e14dadc7d1e6e27fef2e906e8182309b2ef504312fc7577fc84b25d4efa59121c4c641a6bbaf91ab14259f18 SHA512 a118cd3e6d8e560f6c739356551091e6186e87bdaec24c8bc987c3503b5c22276f69a5fafc1f73cfd65528844ca7c37f3ee473cfb1de0646067ee0a48089eb26

diff --git a/net-analyzer/testssl/testssl-3.0.6.ebuild b/net-analyzer/testssl/testssl-3.0.6.ebuild
new file mode 100644
index 00000000000..b55c96e8e4e
--- /dev/null
+++ b/net-analyzer/testssl/testssl-3.0.6.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN}.sh"
+MY_PV="${PV/_p/-}"
+
+DESCRIPTION="Tool to check TLS/SSL cipher support"
+HOMEPAGE="https://testssl.sh/"
+SRC_URI="https://github.com/drwetter/${MY_PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 bundled-openssl? ( openssl )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bundled-openssl kerberos"
+
+RDEPEND="
+	app-shells/bash[net]
+	net-dns/bind-tools
+	sys-apps/util-linux
+	sys-libs/ncurses:0
+	sys-process/procps
+	bundled-openssl? (
+		kerberos? (
+			sys-libs/zlib
+			virtual/krb5
+		)
+	)
+	!bundled-openssl? ( dev-libs/openssl:0 )
+"
+
+S=${WORKDIR}/${MY_PN}-${MY_PV}
+
+QA_PREBUILT="opt/${PN}/*"
+
+pkg_setup() {
+	if use amd64; then
+		if use kerberos; then
+			BUNDLED_OPENSSL="openssl.Linux.x86_64.krb5"
+		else
+			BUNDLED_OPENSSL="openssl.Linux.x86_64"
+		fi
+	elif use x86; then
+		BUNDLED_OPENSSL="openssl.Linux.i686"
+	fi
+}
+
+src_prepare() {
+	default
+	sed -i ${PN}.sh \
+		-e 's|TESTSSL_INSTALL_DIR="${TESTSSL_INSTALL_DIR:-""}"|TESTSSL_INSTALL_DIR="/"|' \
+		-e 's|$TESTSSL_INSTALL_DIR/etc/|&testssl/|g' || die
+
+	if use bundled-openssl; then
+		sed -i ${PN}.sh \
+			-e "/find_openssl_binary()/a OPENSSL=\"/opt/${PN}/${BUNDLED_OPENSSL}\"" || die
+	fi
+}
+
+src_install() {
+	dodoc CHANGELOG.md CREDITS.md Readme.md
+	dodoc openssl-iana.mapping.html
+
+	dobin ${PN}.sh
+
+	insinto /etc/${PN}
+	doins etc/*
+
+	if use bundled-openssl; then
+		exeinto /opt/${PN}
+		use amd64 && doexe bin/${BUNDLED_OPENSSL}
+	fi
+}