[gentoo-commits] repo/gentoo:master commit in: media-gfx/gimp/

["Sam James" <sam@gentoo.org>]

commit:     dad3b69062ba4ff8c80e6314a34d5367b975174b
Author:     Sergey Torokhov <torokhov-s-a <AT> yandex <DOT> ru>
AuthorDate: Thu Oct 21 18:07:10 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Oct 22 02:47:01 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dad3b690

media-gfx/gimp: dev preview 2.99.8 version bump

Signed-off-by: Sergey Torokhov <torokhov-s-a <AT> yandex.ru>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-gfx/gimp/Manifest           |   1 +
 media-gfx/gimp/gimp-2.99.8.ebuild | 263 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 264 insertions(+)

diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index eeda595abf5..307ad92d12d 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -2,3 +2,4 @@ DIST gimp-2.10.22.tar.bz2 33152226 BLAKE2B d11b0ee8f0f24934383028a0b21820af30da6
 DIST gimp-2.10.24.tar.bz2 31546295 BLAKE2B e2b873313b41799cb9461f6cd2ec45dcb0d3f51fe3e2710e47be99be868fba962cb75afb47bc2f12e2d6090993d70f560f4d58d2614939a0d36cadc9191fa2a7 SHA512 828350ad5c53b8409463c24693821d78a1940f18c221249ae7b864ad9db5cf01ab41d6ec5bbefd96115f0e91809ecdc61451d71881b56b07920c442f4a514936
 DIST gimp-2.10.28.tar.bz2 31675862 BLAKE2B b491b55d5adf08221feb7cee8b3adc1d8b090901e8f43b93a4d2c3d935ce1ca45072b0ccd6840e06b329fbfafc8fe5e3d6056381c5129203fa3c5e781cab0453 SHA512 587f6f46741672f0700fd642a5b779694d2d8bc8ad70e7677ccdbfc2266dc62203ed347d6aaffaa4b8e7d84a84a25f7d5a51507dfd64b21b4c05970856d3ab94
 DIST gimp-2.99.6.tar.bz2 30663040 BLAKE2B ccbdc2baa9e99a94e85345ce90bcba6ca56c0f264d3248d198009b730a5c810997b76c7d7a3cf131374316298d719a3e70c81ee7bc0a5e34beda1b112921807a SHA512 51ada696693ac51624ba222d1fff54d39bdc72a06de54f7c244b89740b77f7205aab44f1cec90785ca4196cab32f817e7390b4287a30f5024606163f24222961
+DIST gimp-2.99.8.tar.bz2 30799403 BLAKE2B a67863f5e7d40beca80f931973759dc4523718ac2740cac4924dae8e1611491e59c43436ca670643be1878e1d9ff1575174a59c919b33103128a812e7eba6042 SHA512 c603d9a315c21c9da716cc1d8c0c784061e7d0eac4b3d28467aabc3c63c950da0a52649e498049e0b8475933ef93d721a2b8423811b47b00c9490485d316345e

diff --git a/media-gfx/gimp/gimp-2.99.8.ebuild b/media-gfx/gimp/gimp-2.99.8.ebuild
new file mode 100644
index 00000000000..2775f260310
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.99.8.ebuild
@@ -0,0 +1,263 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( luajit )
+PYTHON_COMPAT=( python3_{8..10} )
+GNOME2_EAUTORECONF=yes
+VALA_MIN_API_VERSION="0.44"
+VALA_USE_DEPEND=vapigen
+
+inherit gnome2 lua-single python-single-r1 toolchain-funcs vala virtualx
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="https://www.gimp.org/"
+SRC_URI="mirror://gimp/v2.99/${P}.tar.bz2"
+LICENSE="GPL-3 LGPL-3"
+SLOT="0/3"
+
+IUSE="aalib alsa aqua doc gnome heif javascript jpeg2k lua mng openexr postscript python udev unwind vala vector-icons webp wmf xpm cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse"
+REQUIRED_USE="
+	lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RESTRICT="!test? ( test )"
+
+# media-libs/{babl,gegl} are required to be built with USE="introspection"
+# to fix the compilation checking of /usr/share/gir-1.0/{Babl-0.1gir,Gegl-0.4.gir}
+COMMON_DEPEND="
+	>=app-text/poppler-0.90.1[cairo]
+	>=app-text/poppler-data-0.4.9
+	>=dev-libs/atk-2.34.1
+	>=dev-libs/glib-2.68.0:2
+	>=dev-libs/json-glib-1.4.4
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=gnome-base/librsvg-2.40.21:2
+	>=media-gfx/mypaint-brushes-2.0.2:=
+	>=media-libs/babl-0.1.86[introspection,lcms,vala?]
+	>=media-libs/fontconfig-2.12.6
+	>=media-libs/freetype-2.10.2
+	>=media-libs/gegl-0.4.32:0.4[cairo,introspection,lcms,vala?]
+	>=media-libs/gexiv2-0.10.10
+	>=media-libs/harfbuzz-2.6.5:=
+	>=media-libs/lcms-2.9:2
+	>=media-libs/libmypaint-1.6.1:=
+	>=media-libs/libpng-1.6.37:0=
+	>=media-libs/tiff-4.1.0:0
+	net-libs/glib-networking[ssl]
+	sys-libs/zlib
+	virtual/jpeg
+	>=x11-libs/cairo-1.16.0
+	>=x11-libs/gdk-pixbuf-2.40.0:2
+	>=x11-libs/gtk+-3.24.16:3
+	x11-libs/libXcursor
+	>=x11-libs/pango-1.44.7
+	aalib? ( media-libs/aalib )
+	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	aqua? ( >=x11-libs/gtk-mac-integration-2.0.0 )
+	heif? ( >=media-libs/libheif-1.9.1:= )
+	javascript? ( dev-libs/gjs )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.1:2= )
+	lua? (
+		${LUA_DEPS}
+		$(lua_gen_cond_dep '
+			dev-lua/lgi[${LUA_USEDEP}]
+		')
+	)
+	mng? ( media-libs/libmng:= )
+	openexr? ( >=media-libs/openexr-2.3.0:= )
+	postscript? ( app-text/ghostscript-gpl )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-3.0:3[${PYTHON_USEDEP}]
+		')
+	)
+	udev? ( >=dev-libs/libgudev-167:= )
+	unwind? ( >=sys-libs/libunwind-1.1.0:= )
+	webp? ( >=media-libs/libwebp-0.6.0:= )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	xpm? ( x11-libs/libXpm )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/hicolor-icon-theme
+	gnome? ( gnome-base/gvfs )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	>=dev-lang/perl-5.30.3
+	>=dev-libs/appstream-glib-0.7.16
+	dev-util/gdbus-codegen
+	dev-util/gtk-update-icon-cache
+	>=dev-util/intltool-0.51.0
+	sys-apps/findutils
+	>=sys-devel/autoconf-2.54
+	>=sys-devel/automake-1.11
+	>=sys-devel/gettext-0.21
+	>=sys-devel/libtool-2.4.6
+	doc? (
+		app-text/yelp-tools
+		dev-libs/gobject-introspection[doctool]
+		>=dev-util/gtk-doc-1.32
+		dev-util/gtk-doc-am
+	)
+	vala? ( $(vala_depend) )
+"
+
+# TODO: there are probably more atoms in DEPEND which should be in BDEPEND now
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "AUTHORS" "HACKING" "NEWS" "README" "README.i18n" )
+
+# Bugs 685210 (and duplicate 691070)
+PATCHES=(
+	"${FILESDIR}/${PN}-2.10_fix_test-appdata.patch"
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' configure.ac || die #737794
+
+	sed -i -e 's/== "xquartz"/= "xquartz"/' configure.ac || die #494864
+	sed 's:-DGIMP_DISABLE_DEPRECATED:-DGIMP_protect_DISABLE_DEPRECATED:g' -i configure.ac || die #615144
+
+	gnome2_src_prepare  # calls eautoreconf
+
+	use vala && vala_src_prepare
+
+	sed 's:-DGIMP_protect_DISABLE_DEPRECATED:-DGIMP_DISABLE_DEPRECATED:g' -i configure || die #615144
+	fgrep -q GIMP_DISABLE_DEPRECATED configure || die #615144, self-test
+
+	export CC_FOR_BUILD="$(tc-getBUILD_CC)"
+}
+
+_adjust_sandbox() {
+	# Bugs #569738 and #591214
+	local nv
+	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
+		# We do not check for existence as they may show up later
+		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
+		addwrite "${nv}"
+	done
+
+	addwrite /dev/dri/  # bugs #574038 and #684886
+	addwrite /dev/ati/  # bug #589198
+	addwrite /proc/mtrr  # bug #589198
+}
+
+src_configure() {
+	_adjust_sandbox
+
+	local myconf=(
+		GEGL="${EPREFIX}"/usr/bin/gegl-0.4
+		GDBUS_CODEGEN="${EPREFIX}"/usr/bin/gdbus-codegen
+
+		--enable-default-binary
+
+		--disable-check-update
+		--enable-mp
+		--with-appdata-test
+		--with-bug-report-url=https://bugs.gentoo.org/
+		--with-xmc
+		--without-libbacktrace
+		--without-webkit
+		--without-xvfb-run
+		$(use_enable cpu_flags_ppc_altivec altivec)
+		$(use_enable cpu_flags_x86_mmx mmx)
+		$(use_enable cpu_flags_x86_sse sse)
+		$(use_enable doc gtk_doc)
+		$(use_enable doc g-ir-doc)
+		$(use_enable vector-icons)
+		$(use_with aalib aa)
+		$(use_with alsa)
+		$(use_with !aqua x)
+		$(use_with heif libheif)
+		$(use_with javascript)
+		$(use_with jpeg2k jpeg2000)
+		$(use_with lua)
+		$(use_with mng libmng)
+		$(use_with openexr)
+		$(use_with postscript gs)
+		$(use_with python)
+		$(use_with udev gudev)
+		$(use_with unwind libunwind)
+		$(use_with vala)
+		$(use_with webp)
+		$(use_with wmf)
+		$(use_with xpm libxpm)
+	)
+
+	gnome2_src_configure "${myconf[@]}"
+}
+
+src_compile() {
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
+	gnome2_src_compile
+}
+
+# for https://bugs.gentoo.org/664938
+_rename_plugins() {
+	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
+	local prepend=gimp-org-
+	(
+		cd "${ED}"/usr/$(get_libdir)/gimp/2.99/plug-ins || exit 1
+		for plugin_slash in $(ls -d1 */); do
+		    plugin=${plugin_slash%/}
+		    if [[ -f ${plugin}/${plugin} ]]; then
+			# NOTE: Folder and file name need to match for Gimp to load that plug-in
+			#       so "file-svg/file-svg" becomes "${prepend}file-svg/${prepend}file-svg"
+			mv ${plugin}/{,${prepend}}${plugin} || exit 1
+			mv {,${prepend}}${plugin} || exit 1
+		    fi
+		done
+	)
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python; then
+		python_optimize
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${ED}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	find "${D}" -name '*.la' -type f -delete || die
+
+	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
+	mv "${ED}"/usr/share/man/man1/gimp-console{-*,}.1 || die
+
+	_rename_plugins || die
+
+	if use doc; then
+		mkdir "${ED}/usr/share/gtk-doc/html/gimp3_g-ir-docs" || die
+		cp -r "${S}/devel-docs/g-ir-docs/html/"{gjs,python} "${ED}/usr/share/gtk-doc/html/gimp3_g-ir-docs/" || die
+	fi
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+}