[gentoo-commits] repo/gentoo:master commit in: net-libs/libwebsockets/

["Jakov Smolić" <jsmolic@gentoo.org>]

commit:     b4952e6b63db809c652d42e81a00ef2c9f0b1e51
Author:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
AuthorDate: Thu Oct  7 08:00:07 2021 +0000
Commit:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
CommitDate: Thu Oct  7 08:00:14 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b4952e6b

net-libs/libwebsockets: add 4.3.0

Signed-off-by: Jakov Smolić <jsmolic <AT> gentoo.org>

 net-libs/libwebsockets/Manifest                   |  1 +
 net-libs/libwebsockets/libwebsockets-4.3.0.ebuild | 81 +++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/net-libs/libwebsockets/Manifest b/net-libs/libwebsockets/Manifest
index c1045a361eb..5b2a7648556 100644
--- a/net-libs/libwebsockets/Manifest
+++ b/net-libs/libwebsockets/Manifest
@@ -1 +1,2 @@
 DIST libwebsockets-4.2.2.tar.gz 14589100 BLAKE2B 371bae4790e92aa4f48e51b40fbe2e4efc3b885e07740db14c96146eb857616fd3f7a1b6c83c11fded2791b1db59cb1f6761bc4eebaee918ada7e9bcf4be52d0 SHA512 52d9b4511fc484781108a3036f870905d4427fcbab02f3e84ee38f534ae7d1979c2cc3eec0719f4609226d4aae788a79fe7d99a8506537bbcf8fc3d9b8a7b478
+DIST libwebsockets-4.3.0.tar.gz 15605272 BLAKE2B 6ea48fedf3755f55885f32bc289513182cf735472c161f15d720a76ddfa54e5e2c2d93a343f98d941d14b88f8ca8a13039922f8669b85562c5c0c4312f878b98 SHA512 7f183cb0417a902cb18e76431a8580d87db09c973483f3a129e138e4644b9d0e78e0539e985dc6286d9fe429edea7f63147864dc0413cf8e40fca3d67f9c3c42

diff --git a/net-libs/libwebsockets/libwebsockets-4.3.0.ebuild b/net-libs/libwebsockets/libwebsockets-4.3.0.ebuild
new file mode 100644
index 00000000000..e2cb3c1838c
--- /dev/null
+++ b/net-libs/libwebsockets/libwebsockets-4.3.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="A flexible pure-C library for implementing network protocols"
+HOMEPAGE="https://libwebsockets.org/"
+SRC_URI="https://github.com/warmcat/libwebsockets/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/18" # libwebsockets.so.18
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="access-log caps cgi client dbus generic-sessions http-proxy http2 ipv6
+	+lejp libev libevent libuv mbedtls peer-limits server-status smtp socks5
+	sqlite3 ssl threads zip"
+
+REQUIRED_USE="
+	access-log? ( http2 )
+	generic-sessions? ( smtp sqlite3 )
+	http-proxy? ( client )
+	mbedtls? ( ssl )
+	smtp? ( libuv )
+	socks5? ( client http-proxy )
+	?? ( libev libevent )"
+
+RDEPEND="
+	sys-libs/zlib
+	caps? ( sys-libs/libcap )
+	dbus? ( sys-apps/dbus )
+	http-proxy? ( net-libs/libhubbub )
+	libev? ( dev-libs/libev )
+	libevent? ( dev-libs/libevent:= )
+	libuv? ( dev-libs/libuv:= )
+	sqlite3? ( dev-db/sqlite:= )
+	ssl? (
+		!mbedtls? ( dev-libs/openssl:0= )
+		mbedtls? ( net-libs/mbedtls:= )
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Git=ON
+		-DDISABLE_WERROR=ON
+		-DLWS_BUILD_HASH="unknown"
+		-DLWS_HAVE_LIBCAP=$(usex caps)
+		-DLWS_IPV6=$(usex ipv6)
+		-DLWS_ROLE_DBUS=$(usex dbus)
+		-DLWS_WITHOUT_CLIENT=$(usex !client)
+		-DLWS_WITHOUT_TEST_CLIENT=$(usex !client)
+		-DLWS_WITH_ACCESS_LOG=$(usex access-log)
+		-DLWS_WITH_CGI=$(usex cgi)
+		-DLWS_WITH_GENERIC_SESSIONS=$(usex generic-sessions)
+		-DLWS_WITH_HTTP2=$(usex http2)
+		-DLWS_WITH_HTTP_PROXY=$(usex http-proxy)
+		-DLWS_WITH_HUBBUB=$(usex http-proxy)
+		-DLWS_WITH_LEJP=$(usex lejp)
+		-DLWS_WITH_LIBEV=$(usex libev)
+		-DLWS_WITH_LIBEVENT=$(usex libevent)
+		-DLWS_WITH_LIBUV=$(usex libuv)
+		-DLWS_WITH_MBEDTLS=$(usex mbedtls)
+		-DLWS_WITH_PEER_LIMITS=$(usex peer-limits)
+		-DLWS_WITH_SERVER_STATUS=$(usex server-status)
+		-DLWS_WITH_SMTP=$(usex smtp)
+		-DLWS_WITH_SOCKS5=$(usex socks5)
+		-DLWS_WITH_SQLITE3=$(usex sqlite3)
+		-DLWS_WITH_SSL=$(usex ssl)
+		-DLWS_WITH_STATIC=OFF
+		-DLWS_WITH_STRUCT_JSON=$(usex lejp)
+		-DLWS_WITH_THREADPOOL=$(usex threads)
+		-DLWS_WITH_ZIP_FOPS=$(usex zip)
+		-DLWS_WITHOUT_TESTAPPS=ON
+	)
+
+	cmake_src_configure
+}