[gentoo-commits] repo/gentoo:master commit in: games-puzzle/gemdropx/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     63c80c5955c292656d90663c9b0a949569884d1b
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Fri Oct  1 15:01:01 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Oct  4 16:52:40 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=63c80c59

games-puzzle/gemdropx: EAPI8 bump, ebuild improvements

Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-puzzle/gemdropx/gemdropx-0.9-r3.ebuild | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/games-puzzle/gemdropx/gemdropx-0.9-r3.ebuild b/games-puzzle/gemdropx/gemdropx-0.9-r3.ebuild
new file mode 100644
index 00000000000..81cfe01a560
--- /dev/null
+++ b/games-puzzle/gemdropx/gemdropx-0.9-r3.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Puzzle game where it's your job to clear the screen of gems"
+HOMEPAGE="http://www.newbreedsoftware.com/gemdropx/"
+SRC_URI="ftp://ftp.tuxpaint.org/unix/x/gemdropx/src/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	media-libs/libsdl[joystick,sound,video]
+	media-libs/sdl-mixer[mod]"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	sed -i \
+		-e 's/$(CFLAGS) -o/$(LDFLAGS) -o/' \
+		Makefile || die
+	rm -r data/images/.xvpics || die
+}
+
+src_compile() {
+	local myemakeargs=(
+		CC="$(tc-getCC)"
+		CXX="$(tc-getCC)"
+		DATA_PREFIX="${EPREFIX}/usr/share/${PN}"
+		XTRA_FLAGS="${CFLAGS}"
+	)
+	emake "${myemakeargs[@]}"
+}
+
+src_install() {
+	dobin ${PN}
+
+	insinto /usr/share/${PN}
+	doins -r data/.
+
+	dodoc AUTHORS.txt CHANGES.txt ICON.txt README.txt TODO.txt
+
+	newicon data/images/${PN}-icon.xpm ${PN}.xpm
+	make_desktop_entry ${PN} "Gem Drop X"
+}