[gentoo-commits] repo/gentoo:master commit in: media-video/obs-studio/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     ca33a7dc5e3a9ab71717769051ac4d9d67b5f117
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 29 19:53:21 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Sat Oct  2 23:58:18 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ca33a7dc

media-video/obs-studio: add version 27.1.1

Package-Manager: Portage-3.0.24, Repoman-3.0.3
Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-video/obs-studio/Manifest                 |   2 +
 media-video/obs-studio/obs-studio-27.1.1.ebuild | 214 ++++++++++++++++++++++++
 2 files changed, 216 insertions(+)

diff --git a/media-video/obs-studio/Manifest b/media-video/obs-studio/Manifest
index a79204b6be8..99613fc54b2 100644
--- a/media-video/obs-studio/Manifest
+++ b/media-video/obs-studio/Manifest
@@ -1,4 +1,6 @@
 DIST cef_binary_4280_linux64.tar.bz2 79740715 BLAKE2B c648a9a4205094450f9eae407e98cbc3da2b7cd81b3c19c4f52cfa3efcca01dce40528018996c65f026eb97520d78040165d1906b0d19236a86e76ec39c58c26 SHA512 060a5a8716a75b4b96dfb6ac28c132e22b93107915d680311c1b9d4fd12c7712a9e3497338eac6d2b9f4e74f2dc005a75d195c597bba049e4731fe3724f519ba
+DIST obs-browser-2a338b7c76d5dd0a6b23f1d49affefd40213b0e9.tar.gz 89474 BLAKE2B ff76a884ffbb7765430a14a7de2955164e9d8823f5dd48bd85e6d0452022b706517e935d813ad78a45adf5eca95fda02e17ae81dbd721145d3ecd169c5a70537 SHA512 bcc8e38505b3cabd7c0e3edcd34ed21141efaa09a9bb0af79fefb57e315531f0ee089b79696802fa052659f66e0becf304286ef82afcf16283ed6664cb5cedd4
 DIST obs-browser-f1a61c5a2579e5673765c31a47c2053d4b502d4b.tar.gz 79259 BLAKE2B 28cfa46928de0b5e626b384673f7b92b3a48cb631066dda06288c51df78f06b913707a1295a5142d4521505b0678a6c639bfbb5b8a066d585fa12849578a382e SHA512 3ecab39bfb36774ac501de087ca70ecde12f408cfd54cdf12539a92e89d0cf531767a066ff77139389158c46beee423cf1848081ed187890b86241aa96f7b179
 DIST obs-studio-26.1.2.tar.gz 16624899 BLAKE2B 655a6c71d3a0ae6ae1fc2d166a148002bb17d6eaec06d5633a10fdbfe7f42e073526ede83cd36ad21c440debe870b41b43724caa00633733f1e196d918304adc SHA512 cd95fbf587f7edfe415cae75299d65c1d771bb118649fb839ae43d77145d87725c23df3360aa7b8c35ab8b62e5ec7983a8b02f8b102caa78f768eb58b4263417
 DIST obs-studio-27.0.1.tar.gz 15787807 BLAKE2B c2ea571f06a81b2e87ce5d9fd010610ea6cc2753223e6373025f0389972d4638a5f3ff1802f9f0af2c631d71ebcf4603e064da804e8c89eb032b1ad5743d1bd4 SHA512 c15dda62c1f212f623914e61a90c6b1e035720fb84d64726c14f43d77ae7569777a23d04221db34347ce610e7c3407c29e726ae36412e98e34ea2ddb2072b7f3
+DIST obs-studio-27.1.1.tar.gz 15994581 BLAKE2B 43ec33b36e9d63636c9b9b750788795cb2e31866e2572d18e405836c569e24a375108b0fda5826b56c9a13839210c8a51cf3fef22d589f816c189c6bb76b826e SHA512 911fec2168ea0d378dfc295e10851ab436fb9f94ea7bb6aef6d00d32ea427b34e4929c955b138973b3f635e55ef17aa9272faaff4f9ba2c1c3c97c082318d59c

diff --git a/media-video/obs-studio/obs-studio-27.1.1.ebuild b/media-video/obs-studio/obs-studio-27.1.1.ebuild
new file mode 100644
index 00000000000..6e23d6b2b47
--- /dev/null
+++ b/media-video/obs-studio/obs-studio-27.1.1.ebuild
@@ -0,0 +1,214 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
+LUA_COMPAT=( luajit )
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit cmake lua-single python-single-r1 xdg
+
+OBS_BROWSER_COMMIT="2a338b7c76d5dd0a6b23f1d49affefd40213b0e9"
+CEF_DIR="cef_binary_4280_linux64"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/obsproject/obs-studio.git"
+	EGIT_SUBMODULES=( plugins/obs-browser )
+else
+	SRC_URI="https://github.com/obsproject/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI+=" browser? ( https://github.com/obsproject/obs-browser/archive/${OBS_BROWSER_COMMIT}.tar.gz -> obs-browser-${OBS_BROWSER_COMMIT}.tar.gz )"
+	KEYWORDS="~amd64 ~ppc64 ~x86"
+fi
+SRC_URI+=" browser? ( https://cdn-fastly.obsproject.com/downloads/${CEF_DIR}.tar.bz2 )"
+
+DESCRIPTION="Software for Recording and Streaming Live Video Content"
+HOMEPAGE="https://obsproject.com"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="
+	+alsa browser decklink fdk jack lua nvenc pipewire
+	pulseaudio python speex +ssl truetype v4l vlc wayland
+"
+REQUIRED_USE="
+	browser? ( || ( alsa pulseaudio ) )
+	lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+BDEPEND="
+	lua? ( dev-lang/swig )
+	python? ( dev-lang/swig )
+"
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/jansson:=
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5[wayland?]
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtquickcontrols:5
+	dev-qt/qtsql:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	media-libs/libglvnd
+	media-libs/x264:=
+	media-video/ffmpeg:=[x264]
+	net-misc/curl
+	sys-apps/dbus
+	sys-libs/zlib:=
+	virtual/udev
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXfixes
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libxcb:=
+	alsa? ( media-libs/alsa-lib )
+	browser? (
+		app-accessibility/at-spi2-atk
+		app-accessibility/at-spi2-core:2
+		dev-libs/atk
+		dev-libs/expat
+		dev-libs/glib
+		dev-libs/nspr
+		dev-libs/nss
+		media-libs/alsa-lib
+		media-libs/fontconfig
+		media-libs/mesa[gbm(+)]
+		net-print/cups
+		x11-libs/libdrm
+		x11-libs/libXScrnSaver
+		x11-libs/libXcursor
+		x11-libs/libXdamage
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)
+	fdk? ( media-libs/fdk-aac:= )
+	jack? ( virtual/jack )
+	lua? ( ${LUA_DEPS} )
+	nvenc? ( >=media-video/ffmpeg-4[video_cards_nvidia] )
+	pipewire? ( media-video/pipewire:= )
+	pulseaudio? ( media-sound/pulseaudio )
+	python? ( ${PYTHON_DEPS} )
+	speex? ( media-libs/speexdsp )
+	ssl? ( net-libs/mbedtls:= )
+	truetype? (
+		media-libs/fontconfig
+		media-libs/freetype
+	)
+	v4l? ( media-libs/libv4l )
+	vlc? ( media-video/vlc:= )
+	wayland? ( dev-libs/wayland )
+"
+RDEPEND="${DEPEND}"
+
+QA_PREBUILT="
+	usr/lib*/obs-plugins/chrome-sandbox
+	usr/lib*/obs-plugins/libEGL.so
+	usr/lib*/obs-plugins/libGLESv2.so
+	usr/lib*/obs-plugins/libcef.so
+	usr/lib*/obs-plugins/swiftshader/libEGL.so
+	usr/lib*/obs-plugins/swiftshader/libGLESv2.so
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-26.1.2-python-3.8.patch"
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	default
+
+	if [[ ${PV} == 9999 ]]; then
+		git-r3_src_unpack
+	elif use browser; then
+		rm -d ${P}/plugins/obs-browser || die
+		mv obs-browser-${OBS_BROWSER_COMMIT} ${P}/plugins/obs-browser || die
+	fi
+}
+
+src_configure() {
+	local libdir=$(get_libdir)
+	local mycmakeargs=(
+		$(usev browser -DCEF_ROOT_DIR=../${CEF_DIR})
+		-DBUILD_BROWSER=$(usex browser)
+		-DBUILD_VST=no
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DDISABLE_ALSA=$(usex !alsa)
+		-DDISABLE_DECKLINK=$(usex !decklink)
+		-DDISABLE_FREETYPE=$(usex !truetype)
+		-DDISABLE_JACK=$(usex !jack)
+		-DDISABLE_LIBFDK=$(usex !fdk)
+		-DENABLE_PIPEWIRE=$(usex pipewire)
+		-DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
+		$(cmake_use_find_package pulseaudio PulseAudio)
+		-DDISABLE_SPEEXDSP=$(usex !speex)
+		-DDISABLE_V4L2=$(usex !v4l)
+		-DDISABLE_VLC=$(usex !vlc)
+		-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
+		-DUNIX_STRUCTURE=1
+		-DWITH_RTMPS=$(usex ssl)
+
+		# deprecated and currently cause issues
+		# https://github.com/obsproject/obs-studio/pull/4560#issuecomment-826345608
+		-DLIBOBS_PREFER_IMAGEMAGICK=no
+	)
+
+	if [[ ${PV} != 9999 ]]; then
+		mycmakeargs+=(
+			-DOBS_VERSION_OVERRIDE=${PV}
+		)
+	fi
+
+	if use lua || use python; then
+		mycmakeargs+=(
+			-DDISABLE_LUA=$(usex !lua)
+			-DDISABLE_PYTHON=$(usex !python)
+			-DENABLE_SCRIPTING=yes
+		)
+	else
+		mycmakeargs+=( -DENABLE_SCRIPTING=no )
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# external plugins may need some things not installed by default, install them here
+	insinto /usr/include/obs/UI/obs-frontend-api
+	doins UI/obs-frontend-api/obs-frontend-api.h
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ! use alsa && ! use pulseaudio; then
+		elog
+		elog "For the audio capture features to be available,"
+		elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
+		elog "be enabled."
+		elog
+	fi
+
+	if use python; then
+		ewarn "This ebuild applies a patch that is not yet accepted upstream,"
+		ewarn "and while it fixes Python support at least to some extent, it"
+		ewarn "may cause other issues."
+		ewarn ""
+		ewarn "Please report any such issues to the Gentoo maintainer."
+	fi
+}