[gentoo-commits] repo/proj/guru:master commit in: app-backup/b2/

["Haelwenn Monnier" <contact@hacktivis.me>]

commit:     d65c26e51fdae04e7195077cb71f9eeaa1ce510d
Author:     Wolfgang E. Sanyer <ezzieyguywuf <AT> gmail <DOT> com>
AuthorDate: Fri Oct  1 20:23:14 2021 +0000
Commit:     Haelwenn Monnier <contact <AT> hacktivis <DOT> me>
CommitDate: Fri Oct  1 20:23:14 2021 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=d65c26e5

app-backup/b2: bump to 3.0.3

Signed-off-by: Wolfgang E. Sanyer <ezzieyguywuf <AT> gmail.com>

 app-backup/b2/Manifest        |  1 +
 app-backup/b2/b2-3.0.3.ebuild | 58 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/app-backup/b2/Manifest b/app-backup/b2/Manifest
index 79c31e99d..9e0338705 100644
--- a/app-backup/b2/Manifest
+++ b/app-backup/b2/Manifest
@@ -1 +1,2 @@
 DIST b2-2.5.0.tar.gz 72245 BLAKE2B 321114925d594af631a2d489b46a45d35113f561c19223ba62a2777c3c4d578a5ec494c86f35ea4574f81c569de18eba1622a0a8af83379a61ac1341f9050597 SHA512 f9377bd1bbc61d4297afc4080173695df7d3f8461ba0b3c47c408e5cdfd195542a81a4110316d132dab69a90ab6e0a9bf2b08b7b2e4317d29ce8e49d327819ca
+DIST b2-3.0.3.tar.gz 78692 BLAKE2B b216b40e7d3bb0a7b5564418ea463bf9e143a0f1a1408ebe2312869943e5bfbae175afa75aadbe203c05b71026f0fc8fa8f6031b7c3a636ba9b9b6017e2e17be SHA512 61ef1dd1d406f04b50b0d8bb3df921127d996465d53f00dc4cf77d5b6e63ce15fdb9a2d1fc5d7d1c01e734c93fe3e4fe316ca43f420aa6c31f7e3d88e134b659

diff --git a/app-backup/b2/b2-3.0.3.ebuild b/app-backup/b2/b2-3.0.3.ebuild
new file mode 100644
index 000000000..65ae71bbd
--- /dev/null
+++ b/app-backup/b2/b2-3.0.3.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1
+
+DESCRIPTION="Command-line tool for BackBlaze's B2 product"
+HOMEPAGE="https://github.com/Backblaze/B2_Command_Line_Tool"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.5.0-nameclash.patch"
+	"${FILESDIR}/${PN}-2.5.0-disable-pip-requirement-installs.patch"
+)
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/arrow-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/b2sdk-1.12.0[${PYTHON_USEDEP}]
+		>=dev-python/docutils-0.16[${PYTHON_USEDEP}]
+		>=dev-python/phx-class-registry-3.0.5[${PYTHON_USEDEP}]
+		>=dev-python/rst2ansi-0.1.5[${PYTHON_USEDEP}]
+	')
+	$(python_gen_cond_dep '
+		<dev-python/importlib_metadata-3.0.0[${PYTHON_USEDEP}]
+		' pypy3 python3_7)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-3.3.0[${PYTHON_USEDEP}]
+		' pypy3 python3_8)
+"
+
+distutils_enable_tests pytest
+
+# - integration tests require an application key and id (which is # reasonable)
+# - sync tests require network access
+# - Per https://github.com/Backblaze/B2_Command_Line_Tool/issues/687 , the
+#   parse_millis test is broken due to an upstream issue
+python_test() {
+	epytest \
+		--deselect test/integration/test_b2_command_line.py::test_integration \
+		--deselect test/unit/test_console_tool.py::TestConsoleTool::test_sync_exclude_if_modified_after_exact \
+		--deselect test/unit/test_console_tool.py::TestConsoleTool::test_sync_exclude_if_modified_after_in_range \
+		--deselect test/unit/test_arg_parser.py::TestCustomArgTypes::test_parse_millis_from_float_timestamp
+}
+
+pkg_postinst() {
+	elog "The b2 executable has been renamed to backblaze2 in order to"
+	elog "avoid a name clash with b2 from boost-build"
+}